!aus dem Forum von nixxn
!Schätzing, 26.10.2017

finish  $/clear
*abbr,nixxn,/input,nixxn,txt

breit1=5e-3   !Kupfer
dick1=0.02e-3
breit2=3e-3
dick2=0.01e-3
breit3=100e-3 	!Keramik
dick3=10e-3
lang=100e-3
kappa=56e6      !Kupfer
strom=20

mw=0.005e-3


/prep7
et,1,solid226,110
et,2,mesh200,7	!Hilfselement für Vernetzung

!---Kupfer---
mp,dens,1,8900	!
mp,kxx,1,400	!
mp,c,1,385	!
mp,rsvx,1,1/kappa

!---Keramik---
mp,dens,2,2500	!
mp,kxx,2,17.0	!
mp,c,2,80.0	!
!mp,rsvx,2,1/1


!----Geometrie------
rectng,-breit1,0,dick1+dick2,-dick3
rectng,-breit1,breit2,dick2,-dick3
rectng,-breit3/2,breit3/2,0,-dick3
btol,1e-9
aovlap,all
numcmp,area
!A2,6,7          A1,3,4,5


!---Flächenvernetzung-----
type,2
esize,mw
mshape,0
mshkey,1
lsel,s,loc,x,-breit1/2
lesize,all,,,6
lsel,s,loc,x,breit2/2
lesize,all,,,4
amesh,2
amesh,6,7

!-----Keramik------
mw2=1e-3
esize,mw2
amesh,1
amesh,5
amesh,3,4

!----Extrusion-------
type,1     !Kupfer
mat,1
esize,,1
vext,all,,,0,0,lang
aclear,all    !Hilfselemente löschen

nsel,s,loc,y,0,-dick3
esln
emodif,all,mat,2   !Keramik

!-----Randbedingung-elektrisch----
nsel,s,loc,z,lang   
nsel,r,loc,y,0,dick2
nsel,r,loc,x,-breit1,breit2
d,all,volt,0
allsel

!----Lasten-------
nsel,s,loc,z,0
nsel,r,loc,y,0,dick2
nsel,r,loc,x,-breit1,breit2

cp,1,volt,all
*get,n1,node,,num,min  
f,n1,amps,strom

!-----Randbedingung-thermisch----
allsel
ic,all,temp,20
!-----Konvektion-----
nsel,s,loc,y,dick1+dick2
sf,all,conv,10,20
nsel,s,loc,y,dick2
nsel,r,loc,x,0,breit2
sf,all,conv,10,20
nsel,s,loc,y,0
nsel,r,loc,x,breit2,breit3/2
sf,all,conv,10,20
nsel,s,loc,y,0
nsel,r,loc,x,-breit1,-breit3/2
sf,all,conv,10,20
nsel,s,loc,x,-breit3/2
nsel,a,loc,x,+breit3/2
sf,all,conv,10,20

!------Lösung------
allsel   
/solu
antype,trans
kbc,1
outres,all,all
endzeit=60
time,endzeit
autots,on
nsubst,20,200,10
solve

!-------Auswertung-------
/post1
!/triad,off
/plopts,minm,0
/plopts,info,1
/title,Strom: %strom%A Endzeit: %endzeit%s
plns,volt
plns,temp

/eof

*get,spannung,node,n1,volt
widerst=spannung/strom
Leist=spannung*strom    !5.1 W 

!----Zeitverlauf----
/post26
nsol,2,node(0,0,0),temp,,Kupfer
nsol,3,node(breit3/2,0,0),temp,,Rand
/xrange,0,60
plvar,2,3