!aus dem Forum von MurinSplint
!Werkzeugheizung
!Schätzing, 2.1.2014

finish   $/clear
*abbr,murinsplint4,/input,murinsplint4,txt

!Definieren des Berechnungsmodells
!----------------------------------------------------------------------------------------
!---aus Sicht Form-Trenn-Ebene-----
breit=0.4     !Breite in x-Richtung
hoch=0.2      !Höhe in y-Richtung
hochheiz=0.15 !Höhe Heizstäbe
lang=0.4      !Länge in z-Richtung 
tumg=20       !UmgebungsTemperatur

/prep7
et,1,solid226,11

!---Werte für Stahl-----
mp,dens,1,7800	
mp,kxx,1,48
mp,c,1,452
   
!----Geometrie----------
block,-breit/2,+breit/2,0,-hoch,    -lang/2,+lang/2
block,-breit/2,+breit/2,0,-hochheiz,-lang/2,+lang/2
block,       0,+breit/2,0,-hoch,    -lang/2,+lang/2
block,-breit/4,+breit/4,0,-hoch,    -lang/2,+lang/2

vovlap,all

/view,,1,1,1

!----Vernetzung----------
esize,0.01
esize,0.02
esize,0.05   !nur zur Programmtestung
vmesh,all

!/eof

!----Randbedingungen------
asel,s,loc,x,-breit/2
asel,a,loc,x,+breit/2
asel,a,loc,z,-lang/2
asel,a,loc,z,+lang/2

nsla,s,1
sf,all,conv,20,tumg

!-----Anfangswerte------
nsel,all
ic,all,temp,tumg

allsel  
!-------Lösung----------------
/solu
antype,trans
kbc,1
outres,all,all

*do,t,1,30   !Zeitschleife
!t=1  t=2 t=3
!------Sensor-Temperatur------
*get,T_sens,node,node(0,-hoch/2,0),temp  
schalt=78  !Schalt-Temperatur 
*if,T_sens,lt,schalt,then

!-----Lasten1-------
P_heiz=6000   !Heizleistung pro Heizstab
nsel,s,loc,y,-hochheiz
nsel,r,loc,x,-breit/4
*get,n_anz,node,,count
f,all,heat,P_heiz/n_anz
!----------------
nsel,s,loc,y,-hochheiz
nsel,r,loc,x,+breit/4
*get,n_anz,node,,count
f,all,heat,P_heiz/n_anz

*else

!-----Lasten2-------
P_heiz=0   !Heizleistung pro Heizstab
nsel,s,loc,y,-hochheiz
nsel,r,loc,x,-breit/4
*get,n_anz,node,,count
f,all,heat,P_heiz/n_anz
!----------------
nsel,s,loc,y,-hochheiz
nsel,r,loc,x,+breit/4
*get,n_anz,node,,count
f,all,heat,P_heiz/n_anz

*endif  
!---------------------
allsel
time,t*60
solve
*enddo  !Zeitschleife

!-------Auswertung------
/post1
/plopts,minm,0
plns,temp     
!------Sensor-Temperatur------
*get,T_sens,node,node(0,-hoch/2,0),temp  !

/eof

!----Blick auf Trennebene------
nsel,s,loc,y,0,
esln,s,0
plns,temp

!-----Sensor über der Zeit-----
/post26
nsol,2,node(0,-hoch/2,0),temp
plvar,2