!Magnetoelastischer-Sensor
!zweidimensional axialsysmmetrisch
!keine Symmetrienutzung
!keine Verformung
!Schätzing, 26.1.2008
!keine realistischen Werte

fini  $/clear
*abbr,magnetoela2,/input,magnetoela2.txt

zylrad=12e-3     !Zylinder-Radius
zylho=36e-3      !Zylinder-Höhe
wiradin=zylrad   !Wicklungs-Radius innen
widi=1e-3        !Wicklungs-Dicke
wiradau=wiradin+widi  !Wicklungs-Radius außen
wiho=30e-3       !Wicklungs-Höhe
beradin=180e-3   !Bereichs-Radius-Innen
beradau=200e-3   !Bereichs-Radius-Außen

kraft=10
!kraft=0
strom=1
wifl=(wiradau-wiradin)*wiho  !Wicklungsquerschnitt
strdi=strom/wifl   !Stromdichte
mw=wiho/4          !Maschenweite 
/prep7  
et,1,plane82,,,1   !für Zylinder
et,2,mesh200,7     !für Wicklung und Luft
et,3,mesh200,7     !für Rand
mp,ex,1,1e9        !Zylinder unrealistischer Wert
mp,nuxy,0.3

!----Geometrie------
pcirc,beradau,,-90,90
pcirc,beradin,,-90,90
rectng,0,zylrad,-zylho/2,zylho/2
rectng,wiradin,wiradau,-wiho/2,wiho/2
aovlap,all
!A4:Wicklung A6:Zylinder 
!A5:Bereich außen  A7:Bereich innen

!-------Vernetzung-Wicklung-------
esize,widi
type,2
mat,2
amesh,4
!-------Vernetzung--Zylinder------
type,1
mat,1
amesh,6
!----Vernetzung---Luft------
!----Rand------
csys,1
lsel,s,loc,x,(beradin+beradau)/2
lesize,all,,,1
esize,,18
type,3
mat,3
amesh,5
csys,0
!----innen---------------
type,2
mshkey,0
esize
amesh,7
!=========strukturmechanisch=======
!-------Randbedingung-------
esel,s,mat,,1    !Zylinder
nsle
nsel,r,loc,x,0
d,all,ux,0
!-----Lasten-------------
!----Zylinder-unten----
esel,s,mat,,1
nsle
nsel,r,loc,y,-zylho/2
d,all,uy,0
!-----Zylinder-oben----------------
nsle
nsel,r,loc,y,zylho/2
cp,1,uy,all   !Kopplung der Verschiebung
*get,n1,node,,num,min
f,n1,fy,kraft
!-------------
et,2,0     !für Wicklung und Luft
et,3,0     !für Rand
allsel
!--------
/solu
solve
!--------------
/post1
esel,s,mat,,1
plnsol,s,y
n_mess=node(0,0,0)
*get,sy,node,n_mess,s,y
!plnsol,s,x
!*get,sx,node,n_mess,s,x
!/eof
!==========elektrisch========
!---Ermittlung-myrel-aus-Spannung-----
!---völlig aus der Luft gegriffenene Werte
faktor=100/20000   !myrel/Spannung: Werkstoffeigenschaft
!myrel im Normalzustand
myrel_0=600
!myrel in Y-Richtung bei der Spannung sy
myrel_y_s=sy*faktor+myrel_0

/prep7
allsel
!-----------------------
et,1,plane53,,,1        !für Zylinder
et,2,plane53,,,1        !für Wicklung und Luft
et,3,infin110,,1,1      !für Rand
mp,murx,1,myrel_0       !Zylinder 
mp,mury,1,myrel_y_s
mp,murx,2,1             !Wicklung
mp,murx,3,1             !Luft 
!-------Rand-------
csys,1
nsel,s,loc,x,beradau
sf,all,inf
csys,0
!-----Stromdichtevorgabe-------------
esel,s,mat,,2
bfe,all,js,,,,strdi
allsel
!--------
/solu
solve
!--------------
/post1
plf2d


!-----Ermittlung der Induktivität-----
esel,all
etable,energie,sene
ssum
*get,sumenergie,ssum,,item,energie
induk=2*sumenergie/(strom*strom)
induk_nH=induk*1e9   !in NanoHenry
induk__0=78.78337013 !bei Kraft=0
rel=(induk_nh-induk__0)/induk__0*100
!konstruktiv ungünstige Anordnung: zu großer Luftweg
!Magnetkreis sollte mit Kernmaterial geschlossen werden