!Wärmestrom in nur jeweils einen Knoten
!auf einer Mäanderbahn
!aus dem Forum von hc85
!Schätzing, 29.11.2012

finish
/clear

*abbr,maeander1,/input,maeander1,txt


!-----Parameter-----
egx=1.51e-3      !Element-Größe in x
egy=1.49e-3      !Element-Größe in y
egz=1.5e-3      !Element-Größe in z
!-----bf: Bearbeitungsfläche-----------
bfla=30*egx	!bf-Länge: x-Richtung
bfbr=12*egy	!bf-Breite: y-Richtung

rand=5          !Anzahl Randelemente
plala=bfla+2*rand*egx	!Plattenlänge: x-Richtung
plabr=bfbr+2*rand*egy	!Plattenbreite: y-Richtung
pladi=4*egz	!Plattendicke: z-Richtung


vv=10e-3         !Vorschubgeschwindigkeit  1mm/s

!---Aufruf Preprozessor----

/prep7		
et,1,solid70	
mp,dens,1,7600	
mp,kxx,1,15
mp,c,1,400

!----Geometrie----
block,-rand*egx,-rand*egx+plala,-rand*egy,-rand*egy+plabr,0,pladi
/view,,-1,1,-1
/ang,,-120

!----Vernetzung----
lsel,s,loc,x,-rand*egx+plala/2
lesize,all,egx
lsel,s,loc,y,-rand*egy+plabr/2
lesize,all,egy
lsel,s,loc,z,pladi/2
lesize,all,egz
lsel,all
vmesh,all	

!----Lösung----
/solu		
antype,trans	
tunif,20
outres,all,last
leistung=400       !Strahlleistung Wärmestrom
sw=egz/vv          !Schrittweite der Zeit

!---Startschritt-----
time,1e-12      !Zeit nahe Null
solve

!------Spurdaten-------
nsel,s,loc,x,0,bfla
nsel,r,loc,y,0,bfbr
nsel,r,loc,z,0
*get,n_anz,node,,count
n_start=node(0,0,0)     !Startknoten
cm,spurknoten,node
n_arb=n_start

!-----Schritte-------
!n_anz=100       !nur für Testläufe
*do,i,1,n_anz
time,i*sw
fdele,all,all
f,n_arb,heat,leistung
cmsel,s,spurknoten
n_alt=n_arb
n_arb=nnear(n_arb)
nsel,u,,,n_alt
cm,spurknoten,node

allsel
solve

*enddo

!-----Auswertung-------
/post1
/plopts,minm,0
/cont,,9,20,,1500
plns,temp


/eof

!---Animation----------
ANDATA,0.1, ,2,1,n_anz+1,1,0,0