!aus dem Forum von jan385



finish
/clear
*abbr,jan385,/input,jan385,txt

! Parameter
breit=40e-3
hoch=40e-3
lang=40e-3
rad=60e-3
strom=1
freq=500

/prep7
et,1,solid117		! AZ		Luft
et,2,solid117,1		! AZ, VOLT	Leiter
et,3,mesh200,7          !Vernetzungshilfe
mp,murx,1,1
mp,murx,2,1
mp,rsvx,2,1/56e6

! Geometrie
pcirc,rad/8
pcirc,,rad,  0, 90
pcirc,,rad, 90,180
pcirc,,rad,180,270
pcirc,,rad,270,360
aovlap,all
numcmp,area
!A1-4:Leiter,  A5-8:Luft

type,3
mshkey,1
esize,rad/24
amesh,1,4
esize,rad/6
amesh,5,8

!/eof

!----Extrusion-------
/view,,1,2,3		! Blickwinkel

type,2
mat,2
esize,,6
vext,1,4,1,,,lang

type,1
mat,1
esize,,6
vext,5,8,1,,,lang
eplot

aclear,all

nummrg,kpoi
nummrg,node


! Randbedingungen
csys,1			! Zylinderkoordinaten
asel,s,loc,x,rad	! Umfangsflächen
da,all,az,0
csys,0
asel,s,loc,z,0		! Stirnfläche vorn
asel,a,loc,z,lang	! Stirnfläche hinten
da,all,az,0

! Last
esel,s,mat,,2
nsle
nsel,r,loc,z,0	! vorn
cp,1,volt,all	! Kopplung
*get,n1,node,,num,min
f,n1,amps,strom

esel,s,mat,,2		! Leiter
nsle
nsel,r,loc,z,lang	! hinten
d,all,volt,0


/solu
allsel
antype,harm
harfrq,freq
solve

/post1
/plopt,minm,off
set,1,1			! real
plns,b,sum

/eof

esel,s,mat,,2			! Leiter
etable,jtr,nmisc,15		! Stromdichtebetrag
pletab,jtr,avg			! Bildschirmausgabe