!Induktivität einer Flachspule
!Flachspule: einzelne Windungen eines flachen Drahtes
!axialsymmetrisch
!Schätzing,21.2.2006
finish  $/clear
*abbr,induk,/input,induktivitaet,txt
rad=1e-3             !Radius Draht
diiso=0.1e-3         !Dicke Isolation
wianz=8              !Windungszahl
abst=(rad+diiso)*2   !Abstand Wicklung
radau=abst*wianz*1.5
freq=100e3           !Frequenz
freq=10e3

strom=1       !Strom
pi=4*atan(1)
kappa=56e6
my0=4e-7*pi
ed=sqrt(1/(pi*freq*kappa*my0))  !Eindringtiefe

/prep7
et,1,plane53, ,,1    !Luft
et,2,plane53,1,,1    !Draht
et,3,infin110,,,1    !Rand
!-------Material-----
mp,murx,1,1    !Luft
mp,murx,2,1    !Draht
mp,rsvx,2,1/kappa

!--------Geometrie---------
!/color,outl,blac
cyl4,0,0,0,-90,radau,90
*do,i,1,wianz
!cyl4,abst*i,0,rad,0,,180
rectng,abst*i-rad,abst*i+rad,0,rad/4
*enddo
aovlap,all
aplot
numcmp,area
!A1 bis A(wianz): Drähte
!A(wianz+1):Fläche
!---------Vernetzung-Drähte----
!mshape,0,2d   $mshk,1
esize,rad/20
type,2  $mat,2
amesh,1,wianz
!-----Luft-----
esize,rad
type,1  $mat,1  
amesh,wianz+1
!-----Rand---------
csys,1
nsel,s,loc,x,radau
esln
emodif,all,type,3
sf,all,inf
csys,0
allsel
!---Symmetrieachse----
nsel,s,loc,x,0
d,all,az,0
nsel,all
!------Kopplung-in-Wicklung----
*do,i,1,wianz
asel,s,,,i
nsla,s,1
*get,nwi,node,,num,max
cp,i,volt,all
f,nwi,amps,strom
*enddo
allsel
!------------------
/solu
antype,harm
harfrq,freq
solve
!------------------
/post1
set,1,1
plf2d

/triad,off
/plopts,minm,0


!/eof
!esel,s,mat,,2
!ples,jt,sum

!/eof
!---------------------------
allsel
etable,energie,sene
ssum
*get,sumenergie,ssum,,item,energie
ind_H=2*sumenergie/strom/strom
ind_nH=ind_H*1e9