!aus dem Forum von freeway00
!Temperaturen einer transienten Rechnung in ein Array
!Schätzing, 18.3.2016

finish   $/clear

*abbr,freeway,/input,freeway,txt

!---------Parameter-----------
a=40e-3
endzeit=120
schritte=12
atemp=100    !HeizTemperatur

/prep7
et,1,solid226,10
mp,kxx,1,84
mp,c,1,460
mp,dens,1,7860

!------------Geometrie----------
block,0,a,0,a,0,a

!------------Vernetzung--------
esize,a/4
vmesh,all
*get,e_anz,elem,,count

!-----Lasten-------
nsel,s,loc,y,0
d,all,temp,20
nsel,s,loc,y,a
nsel,r,loc,x,0,a/2
nsel,r,loc,z,0,a/2
d,all,temp,atemp

allsel
!-----Lösung------
/solu
antype,trans
time,endzeit
deltim,endzeit/schritte
outres,,all
solve

!-----Auswertung-----
/post1
plns,temp

*dim,mitteltemp,array,schritte,2 

*do,i,1,schritte
  set,1,i
  temp_sum=0
  etable,tempera,temp
  *do,j,1,e_anz
    *get,te,elem,j,etab,tempera
     temp_sum=temp_sum+te
  *enddo
  temp_mittel=temp_sum/e_anz
  mitteltemp(i,1)=temp_mittel
  mitteltemp(i,2)=i*endzeit/schritte
*enddo


/eof





/post26
nsol,2,node(a/2,a/2,a/2),temp
plvar,2
aaa=temp(node(a/2,a/2,a/2))