!aus dem Forum von femmers
finish  $/clear
*abbr,femmers,/input,femmers,txt

!******************************************************
/PREP7
!******************************************************

!Festlegung der Materialeigenschaften

ET,1,SOLID45 		!Elemente
ET,2,30 		!Wandkontakt Fluid
ET,3,30,,1 		!Kein Wandkontakt Fluid
ET,4,130 		!Fluid am freien Ende

MP,EX,1,71000 		!Elastizitätsmodul
MP,PRXY,1,0.33 		!Poissonzahl
MP,DENS,1,2.77e-6 	!Dichte Alu

MP,DENS,2,1.204e-9 	!Dichte Fluid
MP,SONC,2,343.4e3 	!Schallgeschwindigkeit Fluid
MP,MU,2,0.001 		!Dämpfung...

!Erzeugung der Geometrie des Tisches und Fluids

K,1,0,0,0
K,2,19,0,0
K,3,19,50,0
K,4,0,50,0
K,5,0,0,5
K,6,19,0,5
K,7,19,50,5
K,8,0,50,5

K,9,0,0,50
K,10,19,0,50
K,11,19,50,50
K,12,0,50,50


V,1,2,3,4,5,6,7,8 	!Erzeuge Volumen durch Keypoints
V,5,6,7,8,9,10,11,12

!VMESH,All 		!Erzeuge Netz

VSEL,S,VOLU,,1 		!Wähle Festkörper aus
VATT,1,,1 		!Wähle Materialeigenschaft 1 aus und Elementtyp 1
VMESH,ALL 		!Vernetze Volumen

VSEL,S,VOLU,,2 		!Wähle Fluid aus
VATT,2,,3 		!Weise Materialeigenschaft 2 zu und Elementtyp 2
ESIZE,,10
VMESH,ALL 		!Vernetze Volumen


NSEL,S,LOC,Z,5 		!Wähle Knoten aus an Verbindungsstelle
ESLN,S,0 		!Wähle alle Elemente (3D), die an Berührungsfläche sind
esel,u,type,,1

EMODIF,ALL,TYPE,2 	!Setze dort Elementeigenschaft 2
SF,ALL,FSI 		!Weise Verbindung zwischen Fluid und Struktur zu

!VSEL,S,VOLU,,1 	!Wähle Festkörper aus
!ESLV,S
!EMODIF,ALL,TYPE,1

NSEL,All 		!Wähle alle Knoten aus
ESEL,All 		!Wähle alle Elemente aus


!******************************************************
/SOLU
!******************************************************
ANTYPE,Harmic 		!Wähle harmonische Analyse
HROPT,FULL 		!Wähle Lösungsmethode FULL

ESEL,S,ELEM,,11,14,3 	!Wähle Elemente aus, auf denen Kraft wirkt. Element 11 und 14. 
SFE,ALL,,PRES,0,100 	!Definiere Flächenkraft auf Elemente
ALLSEL 			!Wähle wieder alles aus


HARFRQ,100,1000	!10000 	!Frequenzband definieren
!NSUBST,100 		!Anzahl Diskreter Messpunkte
nsubst,2
KBC,1 			!lineare Verteilung der Last über Frequenz

SOLVE 			!Löse Frequenzganganalyse

!------Auswertung-----
/post1
/dscale,1,1
set,1,2
plns,pres