!Versuch Elektrokalorischer Effekt
!eindimensionales Modell mit Volumenelementen
!Schätzing, 31.1.2015

finish  $/clear
*abbr,ekal2,/input,ekal2,inp

dikri=1e-3    	!Dicke Kristall
diku=12e-3     	!Dicke Kupfer
breit=12e-3    	!Breite Anordnung x-Richtung
tief=dikri 	!Tiefe Anordnung


/prep7

et,1,solid90

!----Eigenschaften--Kristall---
mp,kxx,1,4
mp,dens,1,2000
mp,c,1,500
!----Eigenschaften--Kupfer---
mp,kxx,2,200
mp,dens,2,8900
mp,c,2,380

!-----Geometrie------
block,0,breit,0,dikri,0,tief !Kristall
block,0,breit,dikri,dikri+diku,0,tief
block,0,breit,0,-diku/2,0,tief
vglue,all
numcmp,volu

!-----Vernetzung---
esize,dikri*2
vsel,s,loc,y,0,dikri
mat,1
vmesh,all

mat,2
vsel,inve
vmesh,all

!----Randbedingungen------
Tumg=20   	!Umgebungstemperatur
tunif,Tumg
nsel,s,loc,y,dikri+diku
nsel,a,loc,y,-diku/2
d,all,temp,Tumg


allsel
!----Lösung------
/solu
antype,trans
tend=10   !Zeit Ende
schritte=12 
sw=tend/schritte

time,1e-12      !Startzeitpunkt
!----Lasten--Feld-anlegen-
esel,s,mat,,1
bfe,all,hgen,1,-1e8
allsel
solve 
time,sw
solve
!----Lasten--keine-Feldänderung-mehr---
esel,s,mat,,1
bfe,all,hgen,1,0
allsel

*do,i,2,schritte
time,i*sw
solve
*enddo

!-----Auswertung-----
/post1
/plopts,minm,0
plns,temp

/eof

!-----Animation------
/post1
allsel
/cont,,9,18.5,,20
/seg,multi,ekal1,0.5
plns,temp
andata,0.5,5,1,0,30,1

!nach der Ausführung der Animation
/seg,delet
/seg,off



/eof

!----Zeitprozessor----
/post26
nsol,2,node(0,0,0),temp
nsol,3,node(breit/2,diku/2,0),temp
plvar,2,3