!Widerstand eines Drahtes
!Schätzing, 18.3.2016

finish  $/clear
*abbr,dehnung3,/input,dehnung3,txt

rad=0.5e-3
lang=20e-3
Dehn=0.02   !Dehnung 

strom=1

/prep7  
!-----Geometrie-----
cylind,,rad,0,lang,  0, 90
cylind,,rad,0,lang, 90,180
cylind,,rad,0,lang,180,270
cylind,,rad,0,lang,270,360
vglue,all

!----Material------
gamma=56e6

et,1,solid226,101
mp,ex,1,1.17e11
mp,nuxy,1,0.3
mp,dens,1,8900
mp,murx,1,1
mp,rsvx,1,1/gamma

!---Vernetzung----
lsel,s,loc,z,lang/2
lesize,all,,,8
vmesh,all
allsel

!---Randbedingungen-mechanisch----
nsel,s,loc,z,0
d,all,uz,0
nsel,s,loc,x,0
nsel,r,loc,y,0
d,all,ux,0
d,all,uy,0

!---Randbedingungen-elektrisch----
nsel,s,loc,z,0
*get,n_ein,node,,num,min
cp,1,volt,all
f,n_ein,amps,strom
nsel,s,loc,z,lang
d,all,volt,0
!---------------------

allsel
!----1.Lösung----
/solu
solve
!-------------------------
/post1
widerst1=volt(n_ein)/strom  !0.4547e-3

!------Dehnung------------------
/solu
!---Randbedingungen-mechanisch----
nsel,s,loc,z,lang
d,all,uz,lang*dehn

allsel
!----2.Lösung----
/solu
solve

/prep7
upcoord,1

!---Randbedingungen-elektrisch----
nsel,s,loc,z,lang*(1+dehn)
d,all,volt,0

allsel
!----3.Lösung----
/solu
solve
!---------------------------
/post1
pldi,1
widerst2=volt(n_ein)/strom !0.4694e-3