!Kraft auf Werkstück bei Stromfluss
!bei Gleichstrom

fini
/clear
*abbr,broiler4,/input,broiler4,txt

strom=5000       !Stromstärke in A
zeit=1e-3           !Dauer des Stromflusses in Sekunden
zeitschritte=10 !Anzahl der Zeitschritte
!Aussenumrisse des Körpers

breite=5e-3
hoehe=18e-3
hoehe=5e-3   !gekürzt für schnellere Lösung
tiefe=4e-3
radius=8e-3   !Radius für umgebende Luft

/prep7


et,1,solid97,1   !für Leiter
et,2,solid97     !für Luft

!Werkstoffeigenschaften für irgendeinen Stahltyp
!***********************************************
mp,ALPX,1.2e-5    !thermische Dehnung
mp,ex,1,210e9     !E-Modul
mp,nuxy,1,0.3     !Querkontraktionszahl
mp,rsvx,1,1/10e6  !el. Leitwert
mp,kxx,1,52       !Wärmeleitwert
mp,c,1,420        !spez. Wärmekapazität
mp,dens,1,7860    !Dichte
mp,murx,1,200     !Permeabilität
!mp,murx,1,1

mp,murx,2,1       !Luft

!es fehlen weitere Eigenschaften in Bezug auf das Magnetfeld-Verhalten



!Geometrieerzeugung
!***********************************************
!--wegen Symmetrie nur ein achtel----
block,0,breite/2,0,tiefe/2,0,hoehe/2
cylind,radius,,0,hoehe/2,0,90
vovlap,all
!V1:Leiter  V3:Luft

!Vernetzung der Geometrie
!***********************************************
esize,breite/10
type,1
mat,1
vmesh,1
!-----------------------
accat,4,6,
esize,breite/2
type,2
mat,2
vmesh,3


!elektrische Anfangswerte festsetzen
!***********************************
esel,s,type,,1
nsle
nsel,r,loc,z,hoehe/2
cp,1,volt,all      !Kopplung des Potentials "unten"
*get,node1,node,,num,min
f,node1,amps,strom   !Festlegung des Stromeingangs
nsle
nsel,r,loc,z,0
d,all,volt,0         !Festlegung der gegenüberliegeneden Seite auf Bezugspotential

!---Randbedingungen---
csys,1
nsel,s,loc,x,radius
d,all,az,0
csys,0

!----Symmetriebedingungen-----
allsel
nsel,s,loc,x,0
dsym,symm,x,0
nsel,s,loc,y,0
dsym,symm,y,0

nsel,s,loc,z,hoehe/2
dsym,asym,z,0
nsel,a,loc,z,0
dsym,asym,z,0


alls
!Lösung
!****************************************
/solu
antype,harm
harfre,0.1  !sehr kleine Frequenz für nahezu Gleichstrom

solve

!---------------Auswertung----------------
/post1
set,1,1    !Realteil
ples,jt,sum
/show,,,1
plve,fmag
/show

!-----Modell für Strukturberechnung---
/prep7
allsel
et,1,solid45
et,2,0
allsel

!-------Lösung--------
/solu
fdele,all,amps
ldread,forc   !Übernahme der Kräfte aus der vorigen Rechnung
!flist  !zur Kontrolle
antype,stat

!Randbedingungen
esel,s,type,,1
nsle
nsel,r,loc,z,0
d,all,uz,0
nsle
nsel,r,loc,x,0
d,all,ux,0
nsle
nsel,r,loc,y,0
d,all,uy,0

allsel
solve

/post1
pldi,1