!Piezo_Aktor
!15.11.2011
!bearbeitet Schätzing, 16.11.2011

finish  $/clear
*abbr,brinkley2,/input,brinkley2,txt

!Parameter
ax=10  !Abmessung in x
ay=20  !Abmessung in y
az=2   !Abmessung in z


/PREP7

!Elementtyp:
et,1,solid5,3

!Material: Piezokeramik (PIC255):

tb,piez,1		      !Material-Tabelle Piezoeigenschaften
tbdata,3,-7.15		!e13
tbdata,6,-7.15		!e23
tbdata,9,13.70		!e33
tbdata,14,11.90		!e52
tbdata,16,11.90		!e61

EMUNIT,epzro,8.85e-12 	!define free-space permittivity
mp,perx,1,930		        !eps11Sr
mp,pery,1,930
mp,perz,1,857		        !eps33Sr

!Material-Tabelle anisotrop-elastische Eigenschaften: Steifigkeit c
tb,anel,1		
tbdata,1,12.3e10,7.67e10,7.025e10
tbdata,7,12.3e10,7.025e10		
tbdata,12,9.711e10
tbdata,16,2.315e10
tbdata,19,2.226e10
tbdata,21,2.226e10

!---------Geometrie:--------------
block,-ax/2,ax/2,-ay/2,ay/2,-az/2,az/2,

!---------Vernetzung---------------
esize,az
vmesh,1

!-------Lasten---------
nsel,s,loc,z,az/2
cp,1,volt,all
*get,Aktor,node,0,num,min     !Definiere Knoten fuer Signaleingang

nsel,s,loc,z,-az/2
d,all,volt,0

!-----Randbedingungen------------
nsel,s,loc,z,-az/2
d,all,uz,0
nsel,r,loc,y,-ay/2
d,all,uy,0
nsel,r,loc,x,-ax/2
d,all,ux,0

allsel
!-------Lösung-------------
/solu

antype,trans

trnopt,full           !transient analysis option: full method
alpha=0.25
delta=0.5
theta=0.5
tintp,,alpha,delta,theta  !Transient integration parameters (notw. bei Piezos)

!Belastung aufbringen:
om=30.        !Kreisfrequenz
pi=4*atan(1)
f=om/(2*pi)   !Frequenz

!Elektrische Spannung (Stellgroesse)
vmax=0.5e-3            !Betrag Volt (max.)

tend=1/f              !Endzeit [s]
schritte=100          !Anzahl der Zeitinkremente
dt=tend/schritte      !Zeitdelta (1 Inkrement)

*do,s,1,schritte
  time,dt*s+1e-12
  arg=sin(2*pi*s/schritte)
  d,Aktor,volt,vmax*arg
  allsel
  solve
*enddo

allsel

!-----Auswertung-------
/post26
nsol,10,Aktor,volt,z,Spannung [V]
plva,10

nsol,2,Aktor,u,y,uy          !Verschiebungen
nsol,3,Aktor,u,x,ux
plva,2,3


/eof

realvar,4,2,,,uyr           !Realteil von der Verschiebung 
realvar,5,3,,,uxr
prod,6,4,4,,uyr_2           !Quadrat des Realteils der Verschiebung
prod,7,5,5,,uxr_2
add,8,6,7,,uyr_2+uxr_2      !Addiere die Quadrate
sqrt,9,8,,,Verschiebung [m] !Wurzel ziehen

nsol,10,Aktor,volt,z,Spannung [V]

/gropt,ascal,on
/grtyp,2                    !2-y-Achsen
/gthk,curve,1               !duenne Kurvenlinien

/axlab,x,Zeit [s]                           !Bezeichnung x-Achse
/axlab,y,Auslenkung [m] & el Spannung [V]   !Bezeichnung y-Achse

plvar,9,10