!Bolzenlast auf Zylinderwandung
!aus dem Forum von pfph1011
!schätzing, 28.1.2013

finish  $/clear
*abbr,Lastfaktor,*stat,lastfak
*abbr,bolzen,/input,bolzen,txt

rad=50e-3
wand=10e-3
pi=4*atan(1)

/prep7

et,1,plane182

!---------------------------
mp,ex,1,210e9
mp,dens,1,7800
mp,nuxy,1,0.3

!-----Geometrie----------------------
pcirc,rad,rad+wand,  0, 90
pcirc,rad,rad+wand, 90,180
pcirc,rad,rad+wand,180,270
pcirc,rad,rad+wand,270,360
aglue,all

!----Vernetzung-------
esize,wand/2
mshkey,1
amesh,all

!----Lasten------
!---Hilfsknoten im Mittelpunkt---
n,,0,0,0
n_hilf=node(0,0,0)

!---Knoten heraussuchen------
csys,1
nsel,s,loc,x,rad
csys,0
nsel,r,loc,x,-rad,0
*get,n_anz,node,,count
*get,n_min,node,,num,min
n_mitte=node(-rad,0,0)

!/eof

!----Array für Lastfaktor--------
*dim,lastfak,array,n_anz,2

n_arb=n_min
*do,i,1,n_anz
!---Winkel ermitteln------
winkel=anglen(n_hilf,n_mitte,n_arb)
lastfak(i,1)=n_arb
lastfak(i,2)=cos(winkel)
n_arb=ndnext(n_arb)
*enddo

!----Summe aller Lastfaktoren-------
summe=0
*do,i,1,n_anz
summe=summe+lastfak(i,2)
*enddo
summe=summe

!---Lastaufbringung----
allsel
ges_last=1000

*do,i,1,n_anz
f,lastfak(i,1),fx,-lastfak(i,2)*ges_Last/summe
*enddo