!aus dem Forum von bokaj
!unrunder Außenleiter

finish  $/clear
*abbr, bokaj4,/input,bokaj4,txt


/PREP7
!/TITLE, 2016-06-11, Konzentrische Leiter, Wirbelstromverluste, AZ=0 / SF=INF
ET,1,PLANE233,1       ! PLANE233, AZ VOLT DOF, 8-node quadrilateral, (INNER CONDUCTOR)
ET,2,PLANE233         ! PLANE233, AZ DOF, 8-node quadrilateral, (FOR AIR)
ET,3,PLANE233,1       ! PLANE233, AZ VOLT DOF, 8-node quadrilateral, (INNER CONDUCTOR)
ET,4,PLANE233         ! PLANE233, AZ DOF, (FOR AIR)
ET,5,INFIN110,0,1     ! INFIN110, AZ DOF, 8-node quadrilateral

!-------Parameter--------
rc 	= 3e-3 		! outer radius of axial conductor
ri	=16.33e-3	! inner radius of coaxial conductor
ro	=19.33e-3	! outer radius of coaxial conductor
Ipeak	=100.0		! current of axial conductor
f	=50		! frequency (Hz)
sigma	=1.0e6		! material conductivity
mur	=1		! material permeability

MP,MURX,1,1		! INNER CONDUCTOR - permeability
MP,RSVZ,1,1/sigma	! INNER CONDUCTOR - resistivity
MP,MURX,2,1		! AIR - permeability
MP,MURX,3,1		! OUTER CONDUCTOR - permeability
MP,RSVZ,3,1/sigma	! OUTER CONDUCTOR - resistivity

!----Geometrie-------
cyl4,,,0,,rc	!A1
cyl4,,,0,,ri	!A2
cyl4,,,0,,ro	!A3
arscale,2,3,1,,1.5,,,,1

cyl4,,,0,,ro*2-rc
cyl4,,,0,  0,ro*2, 90
cyl4,,,0, 90,ro*2,180
cyl4,,,0,180,ro*2,270
cyl4,,,0,270,ro*2,360

aovlap,all
numcmp,area
!A1-4:Leiter  A5-8:Isolation
!A9-12:Rohr  A13-16:Lufthülle  A17-20:Rand

!-------Vernetzung------
mshkey,1
!----Seele-----
type,1  $mat,1
esize,rc/4
amesh,1,4
!----Isolation------
type,2   $mat,2
esize,rc
amesh,5,8
!-----Rohr-ungespeist----
type,1  $mat,3
esize,rc/8
amesh,9,12
!-----Lufthülle-----
type,1  $mat,2
esize,rc
amesh,13,16
!-----Rand-------
type,5  $mat,2
amesh,17,20

!-----Randbedingungen---
NSEL,S,EXT
sf,all,inf           					! set infinite surface flag

!------Lasten------
ESEL,S,MAT,,1                       	! SELECT ALL NODES IN CONDUCTOR
NSLE,S  
CP,1,VOLT,ALL                       	! COUPLE ALL NODES IN VOLT
*GET,N1,NODE,,NUM,MIN               	! SELECT A NODE IN THE CONDUCTOR
F,N1,AMPS,Ipeak

ESEL,S,MAT,,3                       	! SELECT ALL NODES IN CONDUCTOR
NSLE,S  
CP,2,VOLT,ALL                       	! COUPLE ALL NODES IN VOLT

allsel
!-------Lösung-----
/SOLU    
ANTYPE,HARMIC                       	! HARMONIC ANALYSIS
HARFRQ,f
SOLVE

!------Auswertung------
/POST1
SET,1,1                           	! RETRIEVE REAL SOLUTION
plns,b,sum
ples,jt,sum

ETABLE,JT,NMISC,1                   	! STORE TOTAL CURRENT DENSITY
ESEL,MAT,3                          	! SELECT COPPER ONLY
PLETAB,JT,1                         	! DISPLAY TOTAL CURRENT DENSITY

powerh