!Erwärmung von Beton durch Temperatur an Bewehrung
!Schätzing, 26.2.05
!Ein Betonklotz enthält einen Bewehrungsstab
!die Temperatur an der Stirnseite des Bewehrungsstabes wird konstant gehalten
!die Erwärmung soll untersucht werden
!aus Symmetriegründen wird nur eine Hälfte berechnet 
finish  $/clear
*abbr,bewehrung,/input,bewehrung_3D,txt

breit=200e-3        !Breite des Betonklotz
rad=5e-3            !Radius des Bewehrungsstabes
tiefstab=40e-3      !Tiefe des Bewehrungsstabes
tief=200e-3         !Tiefe des Betonklotz
lang=200e-3         !Länge des Betonklotz
tumg=-0             !Umgebungstemperatur
t_heiz=90           !Heiz-Temperaur
zeitende=60*60      !60 Minuten

/prep7
et,1,solid69
!-------Beton----------------
mp,dens,1,2200        !Dichte
mp,kxx,1,2.1          !Wärmeleitfähigkeit
mp,c,1,920            !spez. Wärmekapazität
!------Bewehrung-Eisen-------------
mp,dens,2,7800        !Dichte
mp,kxx,2,52           !Wärmeleitfähigkeit
mp,c,2,420            !spez. Wärmekapazität


!------Geometrie------------
block,0,breit/2,0,-tief,0,lang     !Beton
local,11,0,0,-tiefstab             !lokales Koordinatesytem
wpcsys,,11                         !aktivieren
cylind,0,rad,0,lang,-90, 0         !Bewehrung
cylind,0,rad,0,lang,  0,90         !Bewehrung
vovl,all
csys,0                             !globales Koordinatenstem
!V2,4:Bewehrung  V5:Beton  
!/eof
!-------Vernetzung-Bewehrung-------
type,1
mat,2          !Bewehrung
vmesh,2,4,2
!--------Vernetzung-Beton-----------
type,1
mat,1
esize,abst/16
vsweep,5
!-------Lasten-thermisch---------
allsel
tunif,tumg
esel,s,mat,,2    !Bewehrung
nsle
nsel,r,loc,z,0
d,all,temp,t_heiz
!-------------
allsel
/solu
antype,trans
kbc,1
outres,all,all
time,1e-12
solve
nsubst,100,200,20
!nsubst,100
autots,on
time,zeitende
solve
!------------------
/post1
/cont,,9,tumg,,t_heiz
/plopts,minm,0
plnsol,temp

/eof

!---Animation--------

/cont,,9,tumg,,t_heiz
schritte=20
*do,i,0,schritte
set,,,,,zeitende/schritte*i+1e-12
plnsol,temp
/wait,1
*enddo