!aus dem Forum von BauingStud
!Auslesen von Koordinaten und Ergebniswerten


finish
/clear
*abbr,bauingstud,/input,bauingstud,txt
*abbr,Erg,*stat,ergebnis

!Program zur Erzeugung einer Fläche mit Temperaturwerten
a1=50e-3
a2=70e-3
/prep7
et,1,plane55
mp,kxx,1,52
mp,c,1,420
mp,dens,1,7680
rectng,0,a1,0,a2
esize,a1/5
amesh,all
n_ein=node(0,0,0)
d,n_ein,temp,100
allsel
tunif,20
!-----------Lösung--------
/solu
antype,trans
endzeit=600
schritte=10
sw=endzeit/schritte
*do,i,0,schritte
time,i*sw+1e-12
solve
*enddo
!--------Auswertung---
/post1
plns,temp

/eof

!================Abspeichern der Knotenwerte========
*get,n_anz,node,,count       !Knotenanzahl
*get,n_min,node,,num,min     !niedrigste Knotennummer
*get,loes,active,,set,nset   !Anzahl der Lösungen
*dim,ergebnis,array,n_anz,loes+4
!--------Koordinaten--------
n_arb=n_min
*do,i,1,n_anz
ergebnis(i,1)=n_arb
ergebnis(i,2)=nx(n_arb)
ergebnis(i,3)=ny(n_arb)
ergebnis(i,4)=nz(n_arb)
n_arb=ndnext(n_arb)
*enddo
!--------Temperaturen----------
*do,j,1,loes
set,j
n_arb=n_min
*do,i,1,n_anz
ergebnis(i,4+j)=temp(n_arb)
n_arb=ndnext(n_arb)
*enddo  !i
*enddo  !j
!-------Abspeichern-------
*create,ausgabe  !Makro generieren
/output,ergeb,dat
*stat,ergebnis
/output
*end  !create

*use,ausgabe    !Makro ausführen