!*********************************************
!** Berechnung von B-Feld einen             **
!** Vierkanten-Induktor                     **
!** mit Ferrotronkern                       **
!**					    **
!** Segbeaya 16.06.2006			    **
!*********************************************

fini 
/clear
*abbr,bassa3,/input,bassa3,txt
!/BATCH  
!/COM,ANSYS RELEASE  5.7.1  UP20010418       12:06:56    06/16/2006
!/input,menust,tmp     ,'',,,,,,,,,,,,,,,,1  
!/GRA,POWER
!/GST,ON
!/PLO,INFO,3
!/COL,PBAK,ON,1,BLUE 



!!
!!**Parameter deklarieren**
!!

!hs: hoehe  der spule
!bs: breite der spule
!ds: dicke  der spule
!hm: hoehe  der Magnetkern
!bm: breite der magnetkern
!bl: breite luft
!win: Anzahl windungen
!ff: fuellfaktor
!ed: eindringtief f?r stromfluss
!bk: breite leiter kupfer zum extr
!hk: hoehe  leiter kupfer
!gap:Anschlu??ffnung
!tm: tiefe magnetkern
!mw: maschenweite

!!
!!Variablen definieren
!!

!Geometrie der Induktor (stirn seite)

*SET,bs,0.07 !alt 0.10
*SET,hs,0.03
*SET,hm,0.05
*SET,bm,bs  
*SET,ds,0.01
*SET,bl,0.33
*SET,ed,0.001
*SET,hk,0.005
*SET,bk,0.005    !in zrichtung
*SET,tm,0.01
*SET,mw,0.001
*SET,Lspule,1000e-9 !2231e-11 !induktivit?t spule
*SET,Rspule,2e-6  !0.2*(hs+bs) !wiederstand spule
*SET,gap,0.001

!!Stromflussflaecheberechnung

flastr=hk*bk          !Flaeche durchstromende strom
lans=2*(bs+hs)-(2*gap)      !Lanege spule
!fla2=(hk-ed)*(bk-ed) !Flaeche Innen
!flastr=fla1-fla2    !Flaeche durchstromende strom


!Wechselstrom

*SET,strom,40e3 
*SET,freq,4e3

strdi=strom/flastr !stromdichte
!--------------------
!Knoten definieren

/PREP7  
K,1,bm/2,hm/2,, 
K,2,-bm/2,hm/2,,
K,3,-bm/2,-hm/2,,  
K,4,bm/2,-hm/2,,
K,5,bs/2,hs/2,, 
K,6,-bs/2,hs/2,,
K,7,-bs/2,-hs/2,,  
K,8,bs/2,-hs/2,,
K,9,bs/2-ds,hs/2-ds,,  
K,10,-bs/2+ds,hs/2-ds,, 
K,11,-bs/2+ds,-hs/2+ds,,
K,12,+bs/2-ds,-hs/2+ds,,


!!!Gap keypoint  

K,13,-gap,-hm/2,,  
K,14,-gap,-(hs)/2,,  
K,15,-gap,-hs/2+ds,,  

K,16,gap,-hm/2,,  
K,17,gap,-(hs)/2,,  
K,18,gap,-hs/2+ds,,  

!Linien defineren (Ferrotron559 aussen):1
LSTR,      1,      2  
LSTR,      2,      6  
LSTR,      6,      5  
LSTR,      5,      1  
LSTR,      8,      7  
LSTR,      7,      3  
LSTR,      3,      4  
LSTR,      4,      8  

!Linien defineren (spule):2

LSTR,      6,      7  
LSTR,      5,      8  
LSTR,      9,      10  
LSTR,      10,      11  
LSTR,      11,      12  
LSTR,      12,      9  
LSTR,      5,      9  
LSTR,      6,      10  
LSTR,      11,      7  
LSTR,      12,      8  

!Linien definieren gap

LSTR,      13,      14  
LSTR,      14,    15  
LSTR,      15,    18  
LSTR,      18,    17  
LSTR,      17,      14  
LSTR,      17,      16 
LSTR,      16,    13 
LSTR,      16,    14
LSTR,      14,    18
  
!-----------------
!Area definieren (Ferrotron559 aussen):1
al,1,2,3,4
al,5,6,7,8

!Area definieren (spule):2

al,15,3,16,11
al,16,9,17,12
al,13,17,5,18
al,18,10,15,14

!Area definieren (ferrotron559 innen):3
al,14,11,12,13

!Area definieren (luft):4 und overlap 


!Area definieren (gap)
  
AL,20,21,22,23 

AL,19,23,24,25


allsel,all
aovlap,all
!aglue,all

allsel,all
/pnum,area,1 
aplot
!/eof

!!spule
voffst,4,bk,,  

voffst,3,bk,, 
voffst,6,-bk,, 
voffst,13,bk,, 
voffst,12,bk,, 


!!Volume gap

voffst,8,bk,, 
voffst,9,bk,, 

allsel,all
!!!Volume magnet
BLC5,,,bm,hm,-tm  
ALLSEL,ALL


!Volum Luft 
CYLIND,0,bl/6,0,-bl/12,0,360, 
vovlap,all
allsel,all
/pnum,volu,1 
vplot


!---------
!!
!!Elemente definieren
!!
ET,1,SOLID97 !Ferrotron aussen

ET,2,SOLID97 !spule
KEYOPT,2,1,4    !massive conductor
R,2,flastr      !bei care

ET,3,SOLID97 !Luft

ET,4,INFIN111  !Randelment
KEYOPT,4,1,1

!/eof
!---Matreialeigenschaften definieren

!Ferrotron559 1
MPTEMP,1,0  
MPDATA,MURX,1,,20    !rel. Permeabilit?t:20  
MPDATA,RSVX,1,,10e3  !spez.wiederstand: 10e3

!Spulen(kupfer):2
MPTEMP,1,0  
MPDATA,MURX,2,,1      !rel. Permeabilit?t:1  
MPDATA,RSVX,2,,1/56e6 !spez.wiederstand:1/56e6 


!Luft herum:3
MPTEMP,1,0  
MPDATA,MURX,3,,1    !rel. Permeabilit?t:1  
!MPDATA,RSVX,3,,1e9  !spez.wiederstand: 1e9


!/eof
!-----------
!!Vernetzung und 
!!
!!Zuweisen von Elementen und Materialien auf:
!!
!--------------Spule--------------------
esize,mw*3
mshkey,1  
mshape,0,3d    !tetraeder
vsel,s,,,10,11,1
vsel,a,,,1
vsel,a,,,14
vsel,a,,,15
!allsel
type,2  $mat,2  $real,2
vmesh,all

!!Ferrotron magnetkern V17
vsel,all
esize,mw*3
mshkey,0  
mshape,1,3d !tetraeder
type,1  $mat,1  
vmesh,17


!allsel,all

!!gap luft (frei flaeche fuer stromanschluss)

esize,mw*2
mshkey,0  
mshape,1,3d !tetraeder
vsel,s,,,12,13,1
type,3  $mat,3  
vmesh,all

!!Luft V16

csys,1
asel,s,loc,x,bl/6
aesize,all,mw*6
allsel
type,3  $mat,3  
mshkey,0
mshape,1,3d
vmesh,16


!!
!!Randelemente
!!

csys,1                    !zylinderkoordinaten
type,4                    !infini
esize,,1                  !ndivision
asel,s,loc,x,bl/6
*get,anr1,area,,num,min
*get,anr2,area,,num,max
vext,anr1,anr2,,mw        !extrusion
nsel,s,loc,x,bl/6+mw/2,bl/6+mw
sf,all,inf                !flag setzen

csys,0                      !zuruckschalten
allsel

!!
!!
!!Randbedingungen
!!
!!
!linker anschluss (Leiterqueschnittsflaeche spule)
esel,s,mat,,2
nsle
nsel,r,loc,x,-gap

cp,1,curr,all
cp,2,volt,all

!stromfluss in diese flaeche hinein (-1)
sf,all,mci,-1
*get,knr1,node,0,num,max
allsel


!-----rechter Anschluss (Leiterquerschnittsflaeche spule)--
esel,s,mat,,2
nsle
nsel,r,loc,x,gap

cp,3,curr,all
cp,4,volt,all

!stromfluss aus dieser stirnflaeche heraus(+1)
sf,all,mci,+1
d,all,volt,0
*get,knr2,node,0,num,max

allsel
f,knr1,amps,strom
f,knr2,amps,-strom

!-------------------------------
/solu
allsel
antyp,harm
harfre,freq
solve

!-----------------------------
/post1
set,1,1
ples,jt,sum
/eof
plns,b,sum