!aus dem Forum von UglyJoe
!Zweibandleitung
!Schätzing, 21.1.2012
!einfache Variante
!Ausnutzun der Symmetrie
!Kapazität über Energie


finish
/clear
*abbr,uglyjoe4,/input,uglyjoe4,txt

!-----Parameter aus der Aufgabenstellung-----
h=20e-3     !BasisPlattenDicke
w=4e-3      !BandBreite
s=12e-3     !Bänderabstand
t=0.1e-3    !BandDicke
pot2=+1     !Potenzial rechter Leiter
pot1=-1     !Potenzial linker Leiter
epsr2=9.8   !Dielektrizitätszahl
tand=1e3    !Verlustfaktor

!-----Parameter gewählt-------
b=(2*w+s)*4          !BasisPlattenBreite
b=b*2
radin=b/2+10e-3      !Radius innen für Berechnungsbereich
radau=radin+60e-3    !Radius außen für Berechnungsbereich

!------------------------------
/prep7
et,1,plane121
mp,perx,1,1      !Permittivität Luft
mp,perx,2,epsr2  !Permittivität Basisplatte
mp,lsst,2,tand

!----Geometrie--------
pcirc,0,radin,-90, 90 !Berechnungsfläche

rectng,0,b/2,0,-h  !Basisplatte

rectng,+s/2,+s/2+w,0,t  !rechter Bandleiter

aovlap,all
numcmp,area
!A1: Leiter,    A2:Basisplatte  
!A3: Luft
!/eof
!-----Vernetzung-----
type,1
mat,1
!esize,t
esize,w/4
amesh,1   !Vernetzung Leiter, später löschen

type,1
mat,2
esize,h/10
amesh,2   !Basisplatte

type,1
mat,1
esize,h/2
amesh,3   !Vernetzung Luft

!-----Potenzialzuweisung-----
asel,s,,,1  !rechter Leiter
nsla,s,1
d,all,volt,pot2

!-----Symmetrierandbedingung---------
nsel,s,loc,x,0
d,all,volt,0

!-----Elemente in Leiter löschen-------------

asel,s,,,1
aclear,all

!----Lösung-----
allsel
/solu
solve
!-----Auswertung-------
/post1
plnsol,volt

!-----Kapazität über Energie-------
!W=C/2*U*U   !Gesamtanordnung
etable,energie,sene
pletab,energie,avg
ssum
*get,sumenergie,ssum,,item,energie
!--das ist die Energie einer Hälfte
kapazi=2*2*sumenergie/((pot2-pot1)*(pot2-pot1))
!kapazität=53,43 pF/m  (53,31)