!aus dem Forum von budn-nrg
!Abkühlung T-Profil
!Schätzing, 19.12.2013

finish  $/clear
*abbr,T-Profil,/input,T-Profil,txt

!----Parameter-------------
dick=10e-3
hoch=100e-3
breit=70e-3
lang=300e-3

/prep7
et,1,solid226,11
!----Stahl------
mp,ex,1,2.1e11
mp,nuxy,1,0.33
mp,alpx,1,1.2e-5
mp,dens,1,7800
mp,kxx,1,52
mp,c,1,420

!---------Geometrie----------
/view,,1,1,1
BLOCK,-dick/2,+dick/2,0,hoch,0,lang
BLOCK,-breit/2,+breit/2,0,dick,0,lang
vovlap,all

!----------Vernetzung-------------
lsel,s,loc,z,lang/2
lesize,all,,,10
esize,dick/3
!/ang,,0.5
!/dist,,1.1
vmesh,all

!/eof
!---Randbedingungen mechanisch-----
nsel,s,loc,x,0
nsel,r,loc,y,0
nsel,r,loc,z,0
d,all,ux,0
d,all,uy,0
d,all,uz,0

nsel,s,loc,x,0
nsel,r,loc,y,0
nsel,r,loc,z,lang
d,all,ux,0
d,all,uy,0

!---Randbedingungen thermisch-----
nsel,all
ic,all,temp,300   !Anfangsbedingung
			
asel,s,ext
asel,u,loc,z,0
asel,u,loc,z,lang
nsla,,1		
SF,all,conv,10,20  !Konvektion alle Seiten

nsel,s,loc,y,0
SF,all,conv,1000,20 !Konvektion nur unten

!=======================
allsel
/solu
antype,trans
kbc,1
time,120
nsubst,5,10,5
outres,all,all
autots,on
solve
!-------------------
/post1
/plopts,minm,0
plns,temp
plns,s,eqv

/eof

/dscale,,1   !wahre Verformung
/dscale,,10  !Überhöhung der Verformung

antime,10,0.5,,1   !Animation