finish  $/clear

*abbr,SarahFEM2,/input,SarahFEM2.txt

radwst=15e-3    !Radius Werkstück
radwiin=18e-3  !Rad-Wicklung-innen
radwiau=20e-3  !Radius-Wicklung-außen
radbe=30e-3    !Radius-Bereich
hoch=1e-3      !Modelldicke in y
freq=100000      !Frequenz
strom=150    !Strom pro hoch
pi=4*atan(1)
kappa=5e6
my0=4e-7*pi
ed=sqrt(1/(pi*freq*kappa*my0))  !Eindringtiefe
endzeit=5  !Endzeit
sw=0.1      !Zeitschritt für transiente Analyse
!sw=sw/2
zeit=0 !1e-9
!-----------------------------------
/prep7
et,1,plane13,,,1    !Luft
et,2,plane13,,,1    !Werkstück
et,3,plane13,6,,1  !Wicklung
!-------Material-----
mp,murx,1,1    !Luft
mp,murx,2,1    !Werkstück
mp,rsvx,2,1/kappa
mp,kxx,2,58
mp,c,2,460
mp,dens,2,7860
mp,murx,3,1    !Wicklung
mp,rsvx,3,1/56e6
mp,kxx,3,60  !zur Demonstration
mp,c,3,380    
mp,dens,3,8900
!--------Geometrie---------
!/color,outl,blac
rectng,0,radwst,0,hoch
!rectng,radwst,radwiin,0,hoch
rectng,radwiin,radwiau,0,hoch
rectng,0,radbe,0,hoch
aovlap,all
aplot    


!A1:Werkstück A2:Wicklung A4,5:Luft
!---------Vernetzung-Werkstück----
ksel,s,loc,x,radwst
ksel,a,loc,x,radwiin
kesize,all,ed/2
ksel,s,loc,x,0
kesize,all,10*ed
lsel,s,loc,y,hoch/2
lesize,all,,,1
lsel,all
!mshape,0,2d  $mshk,1
type,2  $mat,2
amesh,1
!---Wicklung----
type,3  $mat,3
amesh,2
!-----Luft-----
ksel,s,loc,x,radbe
kesize,all,6*ed
type,1  
mat,1  
amesh,5

lsel,s,loc,x,(radwst+radwiin)/2
lesize,all,,,4
amesh,4


!---Symmetrieachse----
nsel,s,loc,x,0
d,all,az,0
nsel,all
!------Kopplung-in-Wicklung----
esel,s,mat,,3
nsle
*get,nwi,node,,num,max
cp,1,volt,all
f,nwi,amps,strom
allsel
!------------------
/solu
antype,harm
harfrq,freq
solve
!------------------
/post1
esel,s,mat,,2,3
ples,jheat

esel,all


!1.Schritt

/prep7
lsclear,all
et,1,0  !Nullelement
et,2,13,2,,1
et,3,13,2,,1
!---Kühlung---
nsel,s,loc,x,radwiau
d,all,temp,20
nsel,all
!-------------
/solu
antype,trans
tunif,20
esel,s,mat,,2,3
ldread,hgen,,,,2,,rst
esel,all
!outres,all,all
*do,i,0,endzeit/sw,1
zeit=zeit+sw
time,zeit
solve
*enddo

/post1
plnsol,temp

!/eof

!2.Schritt

/prep7  
lsclear,all
et,1,0  !Nullelement
et,2,13,2,,1
et,3,13,2,,1
!---Kühlung---
nsel,s,loc,x,radwiau
d,all,temp,20
nsel,all
!-------------
/solu
antype,trans,restart


tunif,20
esel,s,mat,,2,3
ldread,hgen,,,,2,,rst
!ldread,temp,last,,,,,rth
esel,all
!outres,all,all
zeit2=sw
*do,i,0,endzeit/sw,1
zeit2=zeit2+sw
time,endzeit+zeit2            !
solve
*enddo

/post1
plnsol,temp