!Versuch Varistor
!Bauform: Scheibe
!homogene Feldstärkeverteilung
!Betrieb an Spannungsquelle mit Vorwiderstand
!14.10.08
!Schätzing
!-----------------------------------------

finish
/clear

*abbr,R_vari,/input,R_vari.txt  

pi=4*atan(1)
radpil=2.5e-3      !Radius Pille  													
dipil=2e-3         !Dicke Pille
Apil=pi*radpil**2  !Fläche Pille
!Kennlinie:i=(U/B) hoch n
B=12    !12 V
n=16
		
!-------------------
/prep7                              	 	 
et,1,plane67,,,1  !Rotationssysmmetrisch															

!-----Keramik-Material--------
mp,kxx,1,2.2   !	             
mp,dens,1,2400														 
mp,c,1,550     !
!mp,rsvx,1,1.2    !willkürlicher Wert


!-----Geometrie-----
rectng,0,radpil,0,dipil

!-----Vernetzung-----
esize,,3
amesh,1

!-----Randbedingungen-elektrisch-----
nsel,s,loc,y,dipil
cp,1,volt,all   		
n_ein=node(0,dipil,0)   !Einspeiseknoten
nsel,s,loc,y,0
d,all,volt,0

!-----Randbedingungen-thermisch-----
nsel,s,loc,x,radpil
nsel,a,loc,y,0
nsel,a,loc,y,dipil
sf,all,conv,10,20
allsel
!ic,all,temp,20	
tunif,20

!-----Speisung mit Spannungsquelle------
u1=14                 !Versorgungsspannung
r1=1                  !Vorwiderstand
et,3,circu124,0       !Widerstand
r,3,r1
abst=2e-3             !für Knotendarstellung
*get,n_max,node,,num,max
n,n_max+1,0,dipil+abst
type,3  $real,3
e,n_max+1,n_ein       !Vorwiderstand
*get,e_max,elem,,num,max
!-------------------


!-----Lösung-----
allsel
/solu
zeitende=10e-3
schritte=50
antype,trans
outres,all,last
kbc,1

!----Startwert für Zeit=0----
time,1e-12
d,n_max+1,volt,0
spannung=0
!----Spannungsabhängigkeit-----
*if,spannung,eq,0,then 
spannung=1e-12
*endif
rho=abs(apil/dipil*B**n/(spannung**(n-1)))
/prep7
mp,rsvx,1,rho
!------Materialumstellung-----
emodif,all,mat,1
/solu
!nsubst,3,5,2
solve


!-------Schleife--------
*do,z,1,schritte
/solu
time,zeitende/schritte*z+1e-12
arg=sin(2*pi*z/schritte)
d,n_max+1,volt,u1*arg     !Einspeisung

!----Spannungsabhängigkeit-----
spannung=u1*arg
*if,spannung,eq,0,then 
spannung=1e-12
*endif
rho=abs(apil/dipil*B**n/(spannung**(n-1)))
/prep7
mp,rsvx,1,rho
!------Materialumstellung-----

emodif,all,mat,1
/solu
antype,trans,rest
!nsubst,3,5,2
!---Ende Nichtlinearität-----

time,zeitende/schritte*z+1e-12
arg=sin(2*pi*z/schritte)
d,n_max+1,volt,u1*arg     !Einspeisung

solve	
																		!Lösung anfordern
*enddo

!-----Auswertung-----
/post1
esel,s,type,,1
plnsol,temp


!/eof

/post26
allsel
nsol,2,n_ein,temp,,Temperatur
esol,3,e_max,,smisc,2,Strom
nsol,4,n_ein,volt,,Potential    !Spannung


/grtyp,2
/yrange,20,24,1     !Temperatur
/yrange,-10,10,2    !Strom
/yrange,-20,20,3    !Spannung
/gmarker,2,1        !Strom mit Dreiecken
/axlab,x,Zeit in s
plvar,2,3,4