!KreisPfad mit Interpolation
!aus dem Forum 
!Schätzing, 12.12.2014

finish
/clear

*abbr,Kreispfad2,/input,KreisPfad2,inp

rad=100e-3
lang=2*rad

/prep7
et,1,plane223,1
mp,ex,1,210e9
mp,nuxy,1,0.3

rectng,-lang,lang,-lang,lang
rectng,0,lang,-lang,lang
rectng,-lang,lang,0,lang
pcirc,rad
aovlap,all

!----------------------
asel,s,loc,x,-rad,rad
adele,all
asel,all

!----Vernetzung------
esize,rad/12
esize,rad/8
amesh,all

!----Randbedingung---
nsel,s,loc,y,-lang
d,all,all

!---Lasten-----
nsel,s,loc,y,lang
d,all,uy,-rad/10

allsel
!---Lösung---
/solu
solve

!-----Auswertung----
/post1
/plopts,minm,0
plns,s,eqv

!/eof

!----Pfad-----
CSYS,1
! Knoten auf dem Innenradius auswählen
nsel,s,loc,x,rad
*GET,Anz_K,NODE,0,Count   !Anzahl der ausgewählten Knoten
*get,n_min,node,,num,min  !niedrigste Knotennummer
csys,0
! Liste der Knotennummern anlegen
!-----mit Sortierung-------
*dim,K_Num,array,Anz_K,1  !Array anlegen
n_arb=n_min     !ArbeitsKnoten

*do,i,1,Anz_K
K_Num(i)=n_arb
n_2=nnear(n_arb)
nsel,u,,,n_arb  !Knoten aus der Liste löschen
n_arb=n_2
*enddo
!---Ende Sortierung--------
nsel,all

path,Innen,Anz_K/1    !Pfadvereinbarung
*do,i,1,anz_k/1
ppath,i,K_Num(i)
*enddo

/pbc,path,1  !Grafische Kontrolle des Pfades
plns,s,eqv

PDEF,Stress,S,eqv
plpath,Stress