!Wie kocht ein Hühnerei?
finish
/clear
*abbr,Ei,/input,Ei_2,txt !Startbutton

hoch=100e-3
rad=25e-3
radgelb=12e-3
/prep7  
!-----Geometrie-----
k,1,0,-rad
k,2,rad,0
k,3,0,hoch/2
bsplin,1,2,3,,,,-1,0,,-1,0
l,3,1
al,1,2
cyl4,0,0,radgelb,-90,,90
aovlap,all
!A2:Eigelb    A3:Eiweiß

!----Material------
et,1,13,2,,1
mp,kxx,1,.2      !Wärmeleitfähigkeit Eiweiß
mp,c,1,600       !Wärmekapazität
mp,dens,1,1000   !Dichte
mp,kxx,2,.1      !Wärmeleitfähigkeit Eigelb
mp,c,2,900       !Wärmekapazität
mp,dens,2,1000   !Dichte

!---Vernetzung----
esize,radgelb/4
mat,2
amesh,2
mat,1
amesh,3

!---Randbedingungen-----
tunif,20
lsel,s,,,1
nsll,s,1
d,all,temp,100
allsel

!----Lösung----
/solu
antype,trans
kbc,1
outres,all,all
!-----erster Teil Aufheizung-------
time,60*8
nsubst,20
solve
!-----zweiter Teil-Ruhe-------------------
ddele,all,all
time,60*9
allsel
solve
!-----dritter Teil-Abschreckung----------------
time,60*12
lsel,s,,,1
nsll,s,1
d,all,temp,10
allsel
solve

!------Auswertung--------------
/post1
/cont,1,9,10,,100
plns,temp
/triad,off
/plopts,minm,0
/expand,2,polar,half,,90
!plns,temp
!---Animation-----
set,first
*do,i,1,22
plns,temp
set,next
*enddo
!-----
plve,tf