finish
/clear,start

/Title,Einzelentladungskrater bei der Mikrofunkenerosion

/prep7

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Parameter

we=60e-6 	![J]
d=20e-6		![m]
te=1
te1=0.4e-6	![s]
te2=10


Qq=0.12*we/(3.1416*(d/2)*(d/2)*te1)	!Wärmestromdichte [W/m²]

Tu=20					!Umgebungstemperatur
n=50

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Definition des Elemtetyps

ET,1,PLANE77    !55

!!!!!!!!!!!!!!!!!

MPTEMP,1,20,90,200,315,425,500
mpdata,kxx,1,1,7.2,7.5,8.5,9.8,11.0,12.1  !Thermische Leitfähigkeit [W/(m²K)]
mpdata,c,1,1,560,570,600,650,700,740      !Thermische Kapazität [J/(kg K)]
mp,dens,1,4450		                  !Dichte [kg/m³]


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Geometrie

rectng,-2*d,6*d,0,3*d
rectng,,4*d,0,d
AOVLAP,1,2

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Meshing Parameter

LESIZE,5,,,4*n
LESIZE,8,,,n

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Meshing

MSHAPE,0,2D 
MSHKEY,1
AMESH,2

MSHAPE,1,2D 
MSHKEY,0
AMESH,3

finish

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Lastschritte...

/SOLU

ANTYPE,TRANS,NEW	!Berechnung wird transient durchgeführt
TINTP,,,,1		!Zeit-Integrationsparameter (Methode nach Euler Rückwärtseinsetzen)
OUTRES,all,all
autots,on

lsel,s,,,9
lsel,a,,,4
lsel,a,,,3
lsel,a,,,2
lsel,a,,,10
nsll,s,1
d,all,temp,TU
alls


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Lastschritt 1 (Zimmertemp)

TIMINT,OFF		!Ausstellen der transienten Efffekte

time,te	
NSUB,5	        !Zeit am Ende dieses Lastfalls		
D,ALL,TEMP,TU		!Zimmertemp
alls

solve

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!2.Lastschritt-Aufwärmen

TIMINT,on
TIME,te+te1

ddel,all,temp
NSEL,S,LOC,Y,0  
NSEL,r,LOC,X,d+d/2,2*d+d/2
SF,all,hflux,Qq

neqit,200
deltim,te1/10,te1/20,te1/5
kbc,1
alls

Solve
   

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!3.Lastschritt-Abkühlen

/solu


time,te+te1+te2

NSEL,S,LOC,Y,0  
NSEL,r,LOC,X,d+d/2,2*d+d/2
SFDEL,all,HFLUX
alls

NSEL,S,LOC,Y,0  
NSEL,r,LOC,X,d+d/2,2*d+d/2
SF,all,conv,1500,20
alls

neqit,200
deltime,te2/10,/te2/20,te2/5
kbc,1
alls
solve

finish

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Strukturanalyse

/prep7

ET,2,PLANE82    !42

etchg,tts   !Elementtyp von tehrm. auf Strukturanalyse umschaltenplane55
etlist

!!!!!!!!!!!!!Materialdaten für Strukturanalyse

MPTEMP,1,20,90,200,315,425,500
mpdata,alpx,1,1,8.8e-6,9.0e-6,9.3e-6,9.6e-6,9.8e-6,10e-6
mpdata,ex,1,1,113e+9,107.35e+9,101.7e+9,92.66e+9,84.75e+9,70.06e+9
mp,prxy,1,0.361

!!!!!plastische Verformungsoption!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

tb,BKIN,1,6,,1     ! Bilinear Kinematic Hardening für 6 Temp.
           
TBTEMP,20
TBDATA,1,900e+6,11.0e+9   !0.2 Streckgrenze und Tangentenmodul 1/10
TBTEMP,90
TBDATA,1,810e+6,10.2e+9
TBTEMP,200
TBDATA,1,630e+6,9.4e+9
TBTEMP,315
TBDATA,1,580e+6,9.0e+9
TBTEMP,425
TBDATA,1,540e+6,8.3e+9
TBTEMP,500
TBDATA,1,500e+6,7.8e+9

TBLIST,BKIN,1
/XRANGE,0,0.02
TBPLOT,BKIN,1

finish

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

/solu

antype,trans         !static    
outpr,all,all
nlgeom,on
autots,on

!!Einspannung
lsel,s,,,3
nsll,s,1
d,all,uy
d,all,ux
alls
eplot


!!!Daten der thermischen Berechnung auf das Modell transferieren!
!!!für jeden einzelnen SubStep der th.Sim. eine Strukturlösung berechnen!

!!!!!1.Lastschritt TU=20°C
S=0

*Do,p,1,1
    *Do,q,1,3

       ldread,temp,1,1,,,,rth
       S=S+1
       TIME,(te*S)/3
       kbc,0
       NSUB,5
       neqit,200
       solve
     *EndDo
*EndDo

!!!!!!!!!!!für Aufwärmvorgang
k=0

*Do,i,2,2
   *Do,j,1,9
   
       ldread,temp,i,j,,,,rth  
       !NSEL,S,LOC,Y,0  
       !NSEL,r,LOC,X,d+d/2,2*d+d/2
       !SF,all,pres,1000
       k=k+1
       TIME,te+(te1*k)/9
       neqit,200
       kbc,0
       NSUB,5
       solve

    *EndDo
*EndDo

!!!!!!!!!!!für Abkühlvorgang
R=0

*Do,l,3,3
   *Do,m,1,6
   
       ldread,temp,l,m,,,,rth  
       R=R+1
       TIME,te+te1+(te2*R)/6
       neqit,200
       kbc,0
       NSUB,5
       solve

    *EndDo
*EndDo

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

finish

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


/post26
!nsol,2,200,u,y ! Verschiebung in Y-Richtung
nsol,2,200,temp
lines,1000     ! Anzahl der max.Zeilen
prvar,2        ! Auflisten der Werte