fini
/cle
/title, Kontaktproblem
/filename, contact

!Einheiten:	!Weg/Länge	mm
		!Kraft		N
		!Moment		Nmm
		!E-Modul	N/mm²
		!Druck		MPa (N/mm²)

!-------------Geometriedaten
a=5		!breite
b=10		!höhe
c=20		!länge


!---Materialdaten---
e1=210000	!E-Modul [N/mm²]
e2=210000
v1=0.3		!Querkontraktionszahl definieren
v2=0.3

!--------------------PREP7----------------------
/prep7	!Preprocessor starten

!---Materialvereinbarung----
mp, ex, 1, e1	!E-Modul für Material1
mp, nuxy, 1, v1

mp, ex, 2, e2	!E-Modul für Material2
mp, nuxy, 2, v2

 !-----Contact-Reibungszahl
mp, mu, 3, 0.1

!---Elementvereinbarung---
et, 1, solid185
et, 2, targe170, ,1
et, 3, conta174
keyopt, 3, 10, 4

r, 1
r, 2

!---Geometrievereinbarung----   

!---Quader 1
blc4, 0, 0, a, b, c

!---Quader 2
blc4, 2, b, a/2, b, c


!---Volumen vernetzen
type, 1
mat, 1
real, 1
mshky, 1
esize, 1
vmesh, 1
eplo

type, 1
mat, 2
real, 1
mshky, 1
esize, 1
vmesh, 2
eplo

!---Kontakte erstellen
!---die Kontakte werden doppelt definiert, aber mit vertauschtem Contact und Target
!dies ist wichtig um eine Übertragung in beide Richtungen gleichmäßig zu haben
!dabei bekommt jedes Paar eine eigene realkonstante

asel, s, , , 4		!Quader 1 A4
nsla, s, 1 	
type, 2		!Target
mat, 3
real, 2
esurf
!
asel, s, , ,9		!Quader 2 A9
nsla, s, 1
type, 3		!Contact
esurf
allsel	

asel, s, , , 4		!Quader 1 A4
nsla, s, 1 	
type, 3		!Contact
mat, 3
real, 3
esurf
!
asel, s, , , 9		!Quader 2 A9
nsla, s, 1
type, 2		!Target
esurf
allsel	



!--------------------SOLU----------------------
/solu
!---nichtlineare Berechnung---
antype, static, new	!statische Analyse
eqslv, spar		!Specifies the type of equation solver
nlgeom, on		!nichtlineare Geometrie   
pred, -1		!Praediktor Method
			!chosen by Program for all DOFs

outres, nsol, last
nsub, 1, 10, 1

!---Randbedingungen---
asel, s, , ,3
nsla, s,1
d, all, all
allsel	


!------1.Lastfall - Ini-Lastfall
time, 1
asel, s, , , 10		!der kontakt wird initialisiert durch eine kleine Verschiebung
nsla, s, 1
d, all, uy, -0.05
allsel
solve

!------2.Lastfall
time, 2	
asel, s, , , 10		!nach der ini wird die verschiebung gelöscht
nsla, s, 1
ddele, all, all
allsel

asel, s, , , 10		!aufbringen von druck
nsla, s, 1
sf, all, pres, 500
/psf, pres, norm, 2, 0, 1
allsel

eplo

solve

fini

!--------------------POST1----------------------
/post1
plnsol, s,eqv