/com,
/com,>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
/com,>>>                  START - Platte druck(x,y) - START                  <<< 
/com,>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
/com,

fini
/cle
/filna,platte_druck

/input,platte_db,inp

!getting dimensions and define parameters
!-------------------------------------------------------------------------------
*get,max_x,node,,mxloc,x                 !maximum x location of nodes
*get,min_x,node,,mnloc,x                 !minimum x location of nodes
*get,max_z,node,,mxloc,z                 !maximum z location of nodes
*get,min_z,node,,mnloc,z                 !minimum z location of nodes

pi=acos(-1)
npoint_x=100                             !number of datapoints for tabular 
npoint_z=100                             !boundary condition per dimension =  
                                         !(resolution of function)
!building up table for pressure map
!-------------------------------------------------------------------------------
*dim,prestab,table,npoint_x,npoint_z,,x,z               !define table               
*vfill,prestab(1,0),ramp,,(max_x-min_x)/(npoint_x-1)    !filling x-dimension
*vfill,prestab(1,1),ramp,,(max_z-min_z)/(npoint_z-1)    !filling dummy z-dimension
*mfun,prestab(0,1),tran,prestab(1,1)                    !moving to z-dimension
!/eof
!filling table with pressure map
!-------------------------------------------------------------------------------
!*afun,deg
omeg_x=2*pi*(1/(max_x-min_x))
omeg_z=2*pi*(1/(max_z-min_z))
*do,i,1,npoint_x
   x_val=(max_x-min_x)/npoint_x*i
   *do,j,1,npoint_z
      z_val=(max_z-min_z)/npoint_z*j   
      prestab(i,j)=sin(omeg_x*x_val)+cos(omeg_z*z_val)
   *enddo   
*enddo

!applying pressure map as tabular boundary condition
!-------------------------------------------------------------------------------
alls
nsel,s,loc,y
sf,all,pres,%prestab%

!Solve
!-------------------------------------------------------------------------------
alls
/solu
solve

!plotting pressure map
!-------------------------------------------------------------------------------
/psf,pres,norm,2,on
/vscla,3
/color,elem,lgray
nsel,s,loc,y
esln
/view,1,1,1,1
/auto
/show,png
eplo
/show,close