! Parameter
t=0.02
pi=3.1416
rpm=33000			 !Drehzahl [1/min]
omega=2*pi*rpm/60
ms=6.238			 !Winkelgeschwindigkeit [1/s]

m_S=10				 !Masse Schaufeln [kg]
p_L=-ms*omega**2/(2*pi*t)	 !Druck Schaufeln [Pa]
	

! Festlegung des Titels der Sitzung
/title, Scheibe 		 

!----------------------------------------------------
/prep7		                 

TREF,873, 

!---Materialdaten

MP,DENS,1,4470  	         !Dichte

MPTEMP,1,873
MPDATA,EX,1,,122.5e9  
MPDATA,PRXY,1,,0.3
TB,BISO,1,1,2,  
TBTEMP,873  
TBDATA,,860e6,10.617e9,,,,    

!---Generierung der Geometrie

! Punkte
k,1,0.06,0,0	
k,2,0.06,t/2,0
k,3,0.2,t/2,0
k,4,0.2,0,0


! Linien
LSTR,1,2
LSTR,2,3
LSTR,3,4
LSTR,4,1

AL, all				 

!---Element Eigenschaften

!PLANE183 - 2-D 8-Node Structural Solid
ET,1,183 			 
KEYOPT,1,3,1			 
ESIZE,0.0015,0 		  	 
TYPE,1				 
MAT,1				 
SMRT,1				 
MSHKEY,0			 
MSHAPE,0,2d 		         
ASEL, , , ,all			 
AMESH,all			 


!----------------------------------------------------
!--Lösung

/SOLU

j=1
loops=10

*DIM,omegab,array,loops+1,
*DIM,time,array,loops+1,
*DIM,n,table,loops+1,2
*DIM,nr,table,loops+1,2

omegab(1)=omega
time(1)=0
n(0,1)=0
n(0,2)=rpm

*DO,i,1,loops,1
      
   /SOLU

   p_L=-ms*omegab(i)**2/(2*pi*t)	
   SFL,3,PRES,p_L,p_L			
   OMEGA,0,omegab(i),0,0		
  
   
   KBC,0		!Rampe

   ANTYPE,0		
   SOLCONTROL,1		
   		
   NLGEOM,1		
   NSUBST,20,,		
   ARCLEN,1,,		
   ARCTRM,L		
   AUTOTS,OFF		 

   DL,4,,UY,0		

   SOLVE
   FINISH

   /POST1

   *GET,time(i),ACTIVE,0,SET,TIME,,		

   n(i,1)=i
   n(i,2)=omegab(i)*60/(2*pi)*time(i)
   nr(i,2)=omegab(i)*60/(2*pi)
 
   omegab(i+1)=1/4*(time(i)*3+1)*omegab(i)

   *If,abs(time(i)-1),LE,1e-3,THEN
      *EXIT
   *ENDIF

   FINISH

*ENDDO