finish

/clear



!ABBRES,NEW,'Startersatz','inp',C:\Users\DaWink

/title,cyclic_Modell_Gechwindigkeit



*afun,DEG

!************Variablen



rD = 4             !Durchmesser Draht

rK = 0.3           !Durchmesser Kugel

ALP = 10           !Winkelabschnitt

VER = 19/20         !Verhältnis Mapped Oberseite zu free Drahtinnerese

vK = 60000          !Geschwindigkeit in mm/s

ANZ = 2             !Anzahl Kugeln



lD = rD*ALP*3.141/180            !Länge Drahtabschnitt



!***************Prepos



/prep7



etcon,set           ! allow ANSYS to choose best KEYOP's for 180x elements

et,1,solid186       !quadratische Hexader mit Mittelknoten

keyo,1,2,1          ! set full integration on SOLID186

et,2,solid187



MP,DENS,1,7.85e-09,	! tonne mm^-3

MP,EX,1,206000,	! tonne s^-2 mm^-1

MP,NUXY,1,0.3,





TB,PLAS,1,1,10,MISO

TBTEMP,20

TBPT,,0,1200

TBPT,,0.0077,1418

TBPT,,0.01479,1506

TBPT,,0.04626,1646

TBPT,,0.07442,1691

TBPT,,0.15025,1741

TBPT,,0.419,1804

TBPT,,1.475,1893

TBPT,,3.8682,1913

TBPT,,6,1914



MP,DENS,2,7.85e-09,	! tonne mm^-3

MP,EX,2,206000,	! tonne s^-2 mm^-1

MP,NUXY,2,0.3,



TB,BISO,2,1,

TBDATA,1,2305

TBDATA,2,2000



!Pseudomaterialien für Kontakt

MP,EX,20,206000,	! tonne s^-2 mm^-1

MP,NUXY,20,0.3,

MP,EX,21,206000,	! tonne s^-2 mm^-1

MP,NUXY,21,0.3,

!*************Geometrie und Vernetzung



cylind,,VER*rD,-lD/2,0,90-ALP/2,90

cylind,VER*rD,rD,-lD/2,0,90-ALP/2,90

wpoffs,,rD+rK

wprota,,90

sphere,rK,,270,360



vglue,1,2



!************Vernetzung



N1=3    !Anzahl Einteilungen Tiefe

NS1=5   !SpaceRation zu N1

N2=0.1    !Elementgröße Fläche



lesize,27,,,N1,1/NS1  !Oberes Drahtvolumen (Mapped Netz)

lesize,29,,,N1,1/NS1  !Oberes Drahtvolumen (Mapped Netz)

lesize,28,,,N1,1/NS1  !Oberes Drahtvolumen (Mapped Netz)

lesize,30,,,N1,1/NS1  !Oberes Drahtvolumen (Mapped Netz)

aesize,8,N2



type,1

mat,1

real,1

mshkey,2

vmesh,4



mshkey,0

smrtsize,8

mshape,1,3d

vmesh,1

tchg,186,187        !186 Tets in 187 Tets umwandeln.



type,2

smrtsize,5

mat,2

real,2

vmesh,3



!*******Komponenten und Kontaktdefinition



esel,s,mat,,2           !Kugel

nsle

cm,KUGEL,nodes

allsel



esel,s,mat,,1           !Low Seite radial

nsle

nsel,r,loc,y,90-ALP/2

cm,RLOW,nodes



esel,s,mat,,1           !High Seite radial

nsle

nsel,r,loc,y,90

cm,RHIGH,nodes



esel,s,mat,,1

nsle

nsel,r,loc,z,-lD/2

nsel,u,loc,y,90-ALP/2

nsel,u,loc,y,90

cm,BACK,nodes



esel,s,mat,,1

nsle

nsel,r,loc,z,0

nsel,u,loc,y,90-ALP/2

nsel,u,loc,y,90

cm,FRONT,nodes

allsel



cmsel,s,kugel

nsel,u,loc,x,0

nsel,u,loc,z,0

cm,KUGELi,nodes

allsel



*create,_KONTA,mac

r,tid

r,cid

et,tid,170

et,cid,174

real,cid

type,cid

mat,cid

cmsel,s,KONTAKT

esurf

allsel

type,tid

mat,tid

cmsel,s,ZIEL

esurf

keyo,cid,10,2    ! adjust contact stiffness each NR iteration

keyo,cid,12,0              ! standard contact

keyo,cid,2,1               ! penalty function only 

keyo,cid,9,1               ! ignore initial gaps/penetration

keyo,cid,5,1               ! auto CNOF adjustment to close geometric gap only

keyo,cid,7,0               ! No Prediction

rmod,tid,3,1.	! FKN

rmod,tid,5,0.	! ICONT

rmod,tid,6,0.	! PINB

rmod,tid,10,0.	! CNOF

rmod,tid,12,0.	! FKT

rmod,cid,3,1.	! FKN

rmod,cid,5,0.	! ICONT

rmod,cid,6,0.	! PINB

rmod,cid,10,0.	! CNOF

rmod,cid,12,0.	! FKT

allsel

*end



!***************Kontakt Kugel/Draht********************



*set,tid,20

*set,cid,21



local,11,2,,rD+rK       !KOS Spherisch in Kugelmitte

esel,s,mat,,2           !Element mit Mat 2 auswählen

nsle                    !alle Knoten aus selektierten Elementen

nsel,r,loc,x,rK         !Reselect Kugeloberfläche

csys,1                  

nsel,r,loc,x,rD,rD+rK   !Reselect 2/3 der Kugeloberfläche unten

cm,ZIEL,nodes



esel,s,mat,,1           !Kontaktoberfläche

nsle

nsel,r,loc,x,rD

cm,KONTAKT,nodes



_KONTA





!************Randbedingungen



csys,0

nsel,s,loc,z,0

dsym,symm,z,0



nsel,s,loc,z,-lD/2

dsym,symm,z,0



nsel,s,loc,x,0

dsym,symm,x,0





csys,1

nsel,s,loc,y,90-Alp/2

cskp,12,0,4,2,11

dsym,symm,z,12

allsel









/solu

antyp,4

outres,all,all

nlgeom,on

solcontrol,on,on

csys,0

rescontrol,,none

trnopt,full,,,,,hht        ! HHT time integration method

tintp,0.1	                ! Numerical Damping

cntr,print,1               ! print out contact info and also make no initial contact an error







*do,i,1,ANZ,1





    time,i                                      !Kugel 1 mm über Werkstückoberfläche Positionieren

    timint,off                                  !Trans Effekte aus

    nsubst,10,100,1

    d,KUGELI,uy,1

    solve



    time,i+1/vK

    timint,off

    d,KUGELI,uy,0

    solve





    time,i + 1/vK + 200e-6                      !Stoßdauer

    timint,on                                   !Trans Effekte an

    autots,on

    cmsel,s,KUGELI

    ddele,all,all

    deltim,1e-8,1e-10,1e-3

    allsel

    solve



*enddo