!Homogenes Magnetfeld
!isoliert

finish  
/clear

/filname,test
/title,3-D Feld
!-----------------Variablen----------
abx=0.1			
aby=0.2
abz=0.1

Bx=0
By=0
Bz=0.001

versatz=0

prfrad=0.07
prfdi=0.005
prfho=0.005
iso=0.001

kappa=56e6

!-----------Modell-------
/prep7
emunit,mks
et,1,solid97
et,2,solid97,1

		
!-----Material------
mp,murx,1,1      	!Luft
mp,murx,2,1		!Leiter
mp,rsvx,2,1/kappa	!Leiter
mp,murx,3,1		!Isolierung
mp,rsvx,3,1e6		!Isolierung

!------Geometrie Luft--------------
/view,,1,2,3

!-------Püfling---------------

cylind,prfrad-prfdi/2,prfrad+prfdi/2,-prfho/2,prfho/2,5,355

!---------Isolierung-------

cylind,prfrad-prfdi/2-iso,prfrad+prfdi/2+iso,-prfho/2-iso,prfho/2+iso,5,355


!-------Luft------------------
cylind,0,abx,-(versatz+abz)/2,(abz+versatz)/2,  0, 90
cylind,0,abx,-(versatz+abz)/2,(abz+versatz)/2, 90,180
cylind,0,abx,-(versatz+abz)/2,(abz+versatz)/2,180,270
cylind,0,abx,-(versatz+abz)/2,(abz+versatz)/2,270,360
bopt,numb,off
vovlap,all
numcmp,volu


!------Vernetzung-----------------
!---Pruef
type,2
mat,2
vmesh,1,4

!---isolierung
type,2
mat,3
mshkey,0
mshape,1,3d
smrtsize,2
vmesh,5,8

!---Luft
type,1
mat,1
mshkey,0
mshape,1,3d
esize,abx/4
vmesh,9,12
eplot



!------Randbedingung--------
csys,1
nsel,s,loc,x,abx
csys,0
*get,nanz,node,,count
*get,nmin,node,,num,min
narb=nmin
*do,i,1,nanz
d,narb,ax,-bz/2*ny(narb)
d,narb,ay,bz/2*nx(narb)
d,narb,az,0
narb=ndnext(narb)
*enddo
nsel,s,loc,z,-(versatz+abz)/2
nsel,a,loc,z,(versatz+abz)/2
d,all,az,0

allsel

!-----Loesung----------
/solu
antype,3
harfreq,50

solve

/post1
set,1,1
plns,b,sum
/wait,5
plve,b