!##########################################################
!#                                                        #
!#       Robert Scherzer                                  #
!#       TU Chemnitz - Professur Festkoerpermechanik      #
!#                                                        #
!#       Vergleich zwischen:                              #
!#       1 shell-Elementen (hart, hart, hart)             #
!#       2 shell-Elementen (hart, weich, hart)            #
!#                                                        #
!##########################################################


!__________________________________________________________
!
!                    Einstellungen
!__________________________________________________________

! Projektname/-titel
FINISH
/CLEAR,    START
/FILENAME, shell_layered_hwh, db
/TITLE,    shell_layered_hwh 

!__________________________________________________________
! 
!                       Parameter
!__________________________________________________________

! Toleranz fuer Auswahlen
SEL_TOL   = 0.001

! Abmessungen
Blech_l   = 20
Blech_b   = 5
hart_d1   = 1.5
hart_d2   = 0.8
weich_d   = 0.6

Blech_d   = hart_d1+weich_d+hart_d2
Abstand   = Blech_b+1

! Belastung
SW_UZ     = 2

! Globale Netzfeinheit
elem      = 5

! Materialparameter
Mat1_EX   = 70000
Mat1_PRXY = 0.31
Mat2_EX   = 10
Mat2_PRXY = 0.31

! Zeitbereich
t1        = 30
nSteps1   = 30


!__________________________________________________________
! 
!                Geometrie
!__________________________________________________________

/PREP7

/PNUM, VOLU, 1
/PNUM, AREA, 1
/PNUM, LINE, 1
/PNUM, KP  , 1 
/PNUM, NODE, 1
/NUMBER, 0

! Geometrie #1
*GET, KP_max, KP,, NUM, MAX
K, KP_max+1, 0,       0,       0
K, KP_max+2, Blech_l, 0,       0
K, KP_max+3, Blech_l, Blech_b, 0
K, KP_max+4, 0,       Blech_b, 0
A, KP_max+1, KP_max+2, KP_max+3, KP_max+4
Blech_A = _RETURN


! Geometrie #2
*GET, KP_max, KP,, NUM, MAX
K, KP_max+1, 0,       Abstand,         0
K, KP_max+2, Blech_l, Abstand,         0
K, KP_max+3, Blech_l, Abstand+Blech_b, 0
K, KP_max+4, 0,       Abstand+Blech_b, 0
A, KP_max+1, KP_max+2, KP_max+3, KP_max+4
Blech_A2 = _RETURN

ALLSEL

!__________________________________________________________
! 
!                Vernetzung
!__________________________________________________________

MPTEMP, 1, 0          

! Materialien
MPDATA, EX  , 1,, Mat1_EX
MPDATA, PRXY, 1,, Mat1_PRXY
MPDATA, EX  , 2,, Mat2_EX
MPDATA, PRXY, 2,, Mat2_PRXY

! Element-Auswahl
ET,      1, SHELL181
KEYOPT,  1, 1, 0
KEYOPT,  1, 3, 2
KEYOPT,  1, 8, 1

! Section #1 (hart, hart, hart)
SECTYPE, 1, SHELL
SECOFFSET, MID
SECDATA, hart_d1, 1,,9
SECDATA, weich_d,   1,,9
SECDATA, hart_d2, 1,,9

! Section #2 (hart, weich, hart)
SECTYPE, 2, SHELL
SECOFFSET, MID
SECDATA, hart_d1, 1,,9
SECDATA, weich_d,   2,,9
SECDATA, hart_d2, 1,,9

! Strukturierte Vernetzung
MSHKEY, 1
ESIZE, elem

! Vernetzung #1
TYPE,   1
SECNUM, 1
AMESH, Blech_A

! Vernetzung #2
TYPE,   1
SECNUM, 2
AMESH, Blech_A2

! Farbige Darstellung der Materialien
ALLSEL
/ESHAPE, 1, 0
/PNUM, MAT, 1
EPLOT

ALLSEL
FINISH

!__________________________________________________________
! 
!                Loesungsteil
!__________________________________________________________

/SOLU  

ANTYPE, 0
NLGEOM, ON

OUTRES, ALL , LAST
OUTRES, SVAR, LAST

! Randbedingungen #1
ESEL, S, SEC,, 1

NSLE
NSEL, R, LOC, X, -SEL_TOL, SEL_TOL
D, ALL, UX,   0
D, ALL, UZ,   0
D, ALL, ROTY, 0
NSEL, R, LOC, Y, -SEL_TOL, SEL_TOL
D, ALL, UY, 0

NSLE
NSEL, R, LOC, X, Blech_l-SEL_TOL, Blech_l+SEL_TOL
D, ALL, UZ, SW_UZ

! Randbedingungen #2
ESEL, S, SEC,, 2

NSLE
NSEL, R, LOC, X, -SEL_TOL, SEL_TOL
D, ALL, UX,   0
D, ALL, UZ,   0
D, ALL, ROTY, 0
NSEL, R, LOC, Y, Abstand-SEL_TOL, Abstand+SEL_TOL
D, ALL, UY, 0

NSLE
NSEL, R, LOC, X, Blech_l-SEL_TOL, Blech_l+SEL_TOL
D, ALL, UZ, SW_UZ

! gemeinsame Symmetrie bei x=0 in x-Richtung
ALLSEL
NSEL, R, LOC, X, -SEL_TOL, SEL_TOL
DSYM, SYMM, X, 0

ALLSEL

! Loesen
*GET, SW_t_Start, ACTIVE, 0, TIME, WALL
TIME,   t1
NSUBST, nSteps1,nSteps1*10, nSteps1*0.1
SOLVE
*GET, SW_t_Ende, ACTIVE, 0, TIME, WALL

FINISH

!__________________________________________________________
! 
!                Postprozessor
!__________________________________________________________

/POST1

! Rechenzeit
SW_t_Solve = (SW_t_Ende - SW_t_Start)*3600

! Anzahl der Farb-Konturen
/CONTOUR, 1, 256

! Elementdicke plotten
/ESHAPE, 1, 0

! Darstellung der Spannungen
SHELL, TOP
PLESOL, S, EQV, 0
PLESOL, S, X,   0