/CLEAR,START
/FILNAM,ROLLERPAIR_PP6HHZ
/OUTPUT,ROLLERPAIR_PP6HHZ_OUTPUT,TXT
/PREP7
/TITLE,CONTACT ANALYSIS OF SML-ROLLERPAIR-PP6HHZ
/NERR,1000,1000,OFF
SELTOL,1E-6
DOF,UX,UY,UZ,ROTX,ROTY,ROTZ		!DEFINE DOFS
*AFUN,DEG				!SWITCH TO DEGREES

!*******************************************************
!*****************DEFINE PARAMETERS*********************
!*******************************************************
------------------SML ROLLER PARAMETER------------------
WB=1250					!SML-LENGTH PARAMETER
FZYL=4700				!PNEUMATIC ZYLINDER FORCE [N]
--------------------------------------------------------
YM1=210000				!YOUNGS MODULUS [MPA]
NUE1=0.3				!POISSON RATIO [\]
MUE=0.2					!COEF OF FRIC-> RUBBER-RUBBER
YMFOIL=1450				!POLYPROPYLEN
NUEFOIL=0.35				!POLYPROPYLEN
MUEFOIL=0.3				!COEF OF FRIC-> RUBBER-FOIL
C10=-1.16798327782			!DEFINE MOONEY-RIVLIN CONSTANTS
C01=2.14108839544			!FOR RUBBER SURFACE LAYER
C20=0.279350869317			!PP6HHZ ELASTOMER
C11=-0.785705598077
C02=1.22480723143
D=0
LENGTHSIZE=20				!ESIZE ALONG CONTACT LINE (WB+150)
SHAFTSIZE=16				!ESIZE - STEEL SHAFTS
ACS=20					!ANGLE OF CONTACT SECTOR [°DEG]
LDIVFINE=5!10				!LINE DIVISION "FINE" - VERTICAL
LRATIOFINE=1!/10			!LINE DIVISION RATIO "FINE" - TOWARDS CONT
ROTDIVFINE=20				!ROTATIONAL DIVISION "FINE"
ROTDIVCONT=10				!ROTATIONAL DIVISION CONTINUED ROLLER MESH
ROTDIVSHAFT=16				!ROTATIONAL DIVISION SHAFT MESH
FOILTHIKN=1				!FOIL THICKNESS
FOILVERTDIV=3				!VERTICAL MESH DIVISION- FOIL
FOILEXTDIV=40				!FOIL ESIZE FOR EXTRUDING
ROLLERDIST=FOILTHIKN			!DISTANCE BETWEEN ROLLERS - CONTACT AREA

!*******************************************************
!***************DEFINE ELEMENTS+PROPERTIES**************
!*******************************************************

ET,1,PLANE183
ET,2,SOLID186
ET,3,TARGE170
ET,4,CONTA174
ET,5,MPC184
ET,6,CONTA174				!FOR BONDED CONTACT - SHAFT CONNECTION
					!MATERIAL NR.1
MP,EX,1,YM1				!YOUNGS MODULUS- STEEL
MP,NUXY,1,NUE1				!POISSON RATIO- STEEL
					!MATERIAL NR.2
TB,HYPER,2,,5,MOONEY			!DEFINE NONLINEAR MATERIAL PROPERTIES
TBDATA,1,C10				!MOONEY-RIVLIN CONSTANTS
TBDATA,2,C01
TBDATA,3,C20
TBDATA,4,C11
TBDATA,5,C02
TBDATA,6,D	
					!MATERIAL NR.3 - FRICTION FOR ROLLER CONT
TB,FRIC,3,,,ISO				!ISOTROPIC CONTACT FRICTION
TBDATA,1,MUE				!DEFINE COEFFICIENT FO FRICTION

MP,EX,4,YMFOIL				!YOUNGS MODULUS- FOIL MATERIAL
MP,NUXY,4,NUEFOIL			!POISSON RATIO- FOIL MATERIAL
					!MATERIAL NR.5 - FRICTION FOR ROLLER CONT
TB,FRIC,5,,,ISO				!ISOTROPIC CONTACT FRICTION
TBDATA,1,MUEFOIL			!DEFINE COEFFICIENT FO FRICTION
					!KEYOPTS FOR BONDED CONTACT
KEYOPT,6,2,1
KEYOPT,6,6,0
KEYOPT,6,7,0
KEYOPT,6,8,1
KEYOPT,6,9,1
KEYOPT,6,11,0
KEYOPT,6,12,5
					!KEYOPTS FOR CONTACT BETWEEN ROLLERS
KEYOPT,4,5,1				!CLOSE GAP
KEYOPT,4,10,2				!CONTACT STIFFNESS UPDATE	
					!REAL CONSTANTS FOR CONTACTS
R,1,,,1,,1E-10				!FKT,ICONT
R,2					!BONDED CONTACT NR.1 - UPPER RIGHT
R,3					!BONDED CONTACT NR.1 - UPPER LEFT
R,4					!BONDED CONTACT NR.1 - LOWER RIGHT
R,5					!BONDED CONTACT NR.1 - LOWER LEFT
R,6,,,1,,1E-10				!CONTACT-> FOIL-LOWER ROLL
R,7,,,1,,1E-10				!CONTACT-> FOIL-UPPER ROLL

!*******************************************************
!********************DEFINE KEYPOINTS*******************
!*******************************************************

K,1,((WB+630)/2),100+ROLLERDIST		!UPPER ROLL
K,2,((WB+630)/2),(100-30)+ROLLERDIST
K,3,((WB+630)/2-90),(100-30)+ROLLERDIST
K,4,((WB+630)/2-240),(100-40.489)+ROLLERDIST
K,5,((WB+630)/2-240),(100-75)+ROLLERDIST
K,6,((WB+630)/2-240),(100-90)+ROLLERDIST
K,7,((WB+630)/2-320),(100-90)+ROLLERDIST
K,8,((WB+630)/2-240),ROLLERDIST
K,9,((WB+630)/2-320),ROLLERDIST
K,10,-((WB+630)/2-320),ROLLERDIST
K,11,-((WB+630)/2-240),ROLLERDIST
K,12,-((WB+630)/2-240),(100-90)+ROLLERDIST
K,13,-((WB+630)/2-320),(100-90)+ROLLERDIST
K,14,-((WB+630)/2-240),(100-75)+ROLLERDIST
K,15,-((WB+630)/2-240),(100-40.489)+ROLLERDIST
K,16,-((WB+630)/2-90),(100-30)+ROLLERDIST
K,17,-((WB+630)/2),(100-30)+ROLLERDIST
K,18,-((WB+630)/2),100+ROLLERDIST
K,19,-((WB+630)/2-320),100+ROLLERDIST
K,20,-((WB+630)/2-320),(100-75)+ROLLERDIST
K,21,((WB+630)/2-320),(100-75)+ROLLERDIST
K,22,((WB+630)/2-320),100+ROLLERDIST

					!LOWER ROLL
K,23,-((WB+150)/2-80+345),-100
K,24,-((WB+150)/2-80+345),(-100+30)
K,25,-((WB+150)/2-80+250),(-100+30)
K,26,-((WB+150)/2),(-100+38.909)
K,27,-((WB+150)/2),(-100+75)
K,28,-((WB+150)/2),(-100+90)
K,29,-((WB+150)/2-80),(-100+90)
K,30,-((WB+150)/2)
K,31,-((WB+150)/2-80)
K,32,((WB+150)/2-80)
K,33,((WB+150)/2)
K,34,((WB+150)/2),(-100+90)
K,35,((WB+150)/2-80),(-100+90)
K,36,((WB+150)/2),(-100+75)
K,37,((WB+150)/2),(-100+39.433)
K,38,((WB+150)/2-80+260),(-100+30)
K,39,((WB+150)/2-80+360),(-100+30)
K,40,((WB+150)/2-80+360),(-100+55/2)
K,41,((WB+150)/2-80+415),(-100+55/2)
K,42,((WB+150)/2-80+415),(-100+50/2)
K,43,((WB+150)/2-80+660),(-100+50/2)
K,44,((WB+150)/2-80+660),-100
K,45,((WB+150)/2-80),-100
K,46,((WB+150)/2-80),(-100+75)
K,47,-((WB+150)/2-80),(-100+75)
K,48,-((WB+150)/2-80),-100

					!FOIL- STRAIGHT
K,49,WB/2
K,50,-WB/2
K,51,-WB/2,FOILTHIKN
K,52,WB/2,FOILTHIKN

!*******************************************************
!*******DEFINE MASTER NODES FOR MPC CONNECTIONS*********
!*******************************************************

N,1,((WB+150)/2)-80+265,100+ROLLERDIST
N,2,-(((WB+150)/2)-80+265),100+ROLLERDIST
N,3,((WB+150)/2)-80+279,-100
N,4,-(((WB+150)/2)-80+279),-100

!*******************************************************
!**********************DEFINE LINES*********************
!*******************************************************

L,1,2					!UPPER ROLL
L,2,3
L,3,4
L,4,5
L,5,6
L,6,8
L,8,9
L,9,10
L,10,11
L,12,11
L,12,14
L,14,15
L,15,16
L,16,17
L,17,18
L,18,19
L,19,20
L,20,21
L,21,22
L,22,1
L,5,21
L,6,7
L,21,7
L,7,9
L,7,13
L,12,13
L,14,20
L,20,13
L,13,10
					!LOWER ROLL
L,23,24
L,24,25
L,25,26
L,26,27
L,27,28
L,28,30
L,30,31
L,31,32
L,32,33
L,34,33
L,34,36
L,36,37
L,37,38
L,38,39
L,39,40
L,40,41
L,41,42
L,42,43
L,43,44
L,44,45
L,45,46
L,46,47
L,47,48
L,48,23
L,27,47
L,28,29
L,47,29
L,29,31
L,29,35
L,36,46
L,34,35
L,46,35
L,35,32
					!FOIL
L,49,50
L,50,51
L,51,52
L,52,49

!*******************************************************
!**********************DEFINE AREAS*********************
!*******************************************************

					!UPPER ROLL
AL,1,20,19,21,4,3,2
AL,5,21,23,22
AL,23,18,28,25
AL,28,27,11,26
AL,17,16,15,14,13,12,27
AL,6,22,24,7
AL,24,25,29,8
AL,29,26,10,9
					!LOWER ROLL
AL,52,54,33,32,31,30,53
AL,56,55,34,54
AL,61,58,56,51
AL,59,40,60,61
LSEL,S,LINE,,41,50
LSEL,A,LINE,,59
AL,ALL	
ALLSEL
AL,57,36,35,55
AL,62,37,57,58
AL,39,38,62,60
					!FOIL
AL,63,64,65,66

!*******************************************************
!*************************MESHING***********************
!*******************************************************

!***********************PLANE MESHING*******************

MSHKEY,1				!MAPPED MESHING
TYPE,1					!ET NR.1 - PLANE
LSEL,S,LINE,,6	
LSEL,A,LINE,,24
LSEL,A,LINE,,29
LSEL,A,LINE,,10
LESIZE,ALL,,,LDIVFINE,LRATIOFINE	!FINER MESH TOWARDS CONTACT
LSEL,S,LINE,,7,9			!-UPPER ROLL
LESIZE,ALL,LENGTHSIZE			!ESIZE ALONG CONTACT LINE
LSEL,S,LINE,,35
LSEL,A,LINE,,57
LSEL,A,LINE,,62
LSEL,A,LINE,,39
LESIZE,ALL,,,LDIVFINE,LRATIOFINE	!FINER MESH TOWARDS CONTACT
LSEL,S,LINE,,36,38			!-LOWER ROLL
LESIZE,ALL,LENGTHSIZE			!ESIZE ALONG CONTACT LINE
ALLSEL

MAT,2					!MESH- CONTACT AREAS (RUBBER LAYER)
AMESH,6,8				!CONTACT AREAS- UPPER ROLL
AMESH,14,16				!CONTACT AREAS - LOWER ROLL
LSEL,S,LINE,,5
LSEL,A,LINE,,23
LSEL,A,LINE,,28
LSEL,A,LINE,,11
LSEL,A,LINE,,40
LSEL,A,LINE,,61
LSEL,A,LINE,,34
LSEL,A,LINE,,56
LESIZE,ALL,,,3				!VERTICAL LINE DIVISION OF STEEL
LSEL,S,LINE,,21				!PIPE BENEATH RUBBER LAYER
LSEL,A,LINE,,18
LSEL,A,LINE,,27
LSEL,A,LINE,,54
LSEL,A,LINE,,51
LSEL,A,LINE,,59
LESIZE,ALL,LENGTHSIZE			!ESIZE ALONG CONTACT LINE- RUBBER-RUBBER
ALLSEL

MAT,1					!MESH- STEEL PIPE
AMESH,2,4				!UPPER ROLL STEEL PIPE
AMESH,10,12				!LOWER ROLL STEEL PIPE

					!FOIL MESH
LSEL,S,LINE,,64
LSEL,A,LINE,,66
LESIZE,ALL,,,FOILVERTDIV		!VERTICAL LINE DIVISIONS FOR FOIL MESH
LSEL,S,LINE,,63
LSEL,A,LINE,,65
LESIZE,ALL,LENGTHSIZE/2			!ESIZE ALONG CONTACT LINE- RUBBER-FOIL
MAT,4
AMESH,17

!*****************SOLID/ROTATIONAL MESHING**************

TYPE,2					!ET NR.2 - SOLID
ESIZE,,ROTDIVFINE			!FINE CONTACT VOLUME SECTION
MAT,2					!RUBBER PP6HHZ MATERIAL
VROTAT,6,7,8,,,,1,18,-ACS,1		!SMALL CONTACT SECTION- UPPER ROLL
VROTAT,14,15,16,,,,23,44,-ACS,1		!SMALL CONTACT SECTION- LOWER ROLL
MAT,1					!STEEL MATERIAL/BENEATH RUBBER LAYER
VROTAT,2,3,4,,,,1,18,-ACS,1		!SMALL SECTION- UPPER ROLL
VROTAT,10,11,12,,,,23,44,-ACS,1		!SMALL SECTION- LOWER ROLL

ESIZE,,ROTDIVCONT			!CONTINUED MESH OF ROLLERS- TO 180°
LOCAL,11,1,,100+ROLLERDIST,,,,90	!LOCAL CSYS- ON ROT AXE OF UPPER ROLL
VSEL,S,MAT,,2
ASLV,R
ASEL,R,LOC,Y,-(90-ACS)
MAT,2
VROTAT,ALL,,,,,,1,18,-(180-ACS),1	!CONTINUING SECTION - UPPER ROLL
ALLSEL					!-RUBBER LAYER
VSEL,S,MAT,,1
ASLV,R
ASEL,R,LOC,Y,-(90-ACS)
MAT,1
VROTAT,ALL,,,,,,1,18,-(180-ACS),1	!CONTINUING SECTION - UPPER ROLL
ALLSEL					!-STEEL PIPE
LOCAL,12,1,,-100,,,,90
VSEL,S,MAT,,2
ASLV,R
ASEL,R,LOC,Y,(90-ACS)
MAT,2
VROTAT,ALL,,,,,,23,44,-(180-ACS),1	!CONTINUING SECTION - LOWER ROLL
ALLSEL					!-RUBBER LAYER
VSEL,S,MAT,,1
ASLV,R
ASEL,R,LOC,Y,(90-ACS)
MAT,1
VROTAT,ALL,,,,,,23,44,-(180-ACS),1	!CONTINUING SECTION - LOWER ROLL
ALLSEL					!-STEEL PIPE
CSYS,0

!*****************SOLID MESHING - FOIL******************

TYPE,2
MAT,4
ESIZE,,FOILEXTDIV
VEXT,17,,,,,-100

!*******************************************************
!********************MERGE ENTITIES*********************
!*******************************************************

CSYS,11
ASEL,S,LOC,X,75
ASEL,A,LOC,X,100
VSLA,R,0
NSLV,R,1
CM,UPPERROLLNODES,NODE			!MERGE NODES- STEEL PIPE + RUBBER LAYER
NUMMRG,NODE				!UPPER ROLL
ALLSEL
CSYS,12
ASEL,S,LOC,X,75
ASEL,A,LOC,X,100
VSLA,R,0
NSLV,R,1
CM,LOWERROLLNODES,NODE			!MERGE NODES- STEEL PIPE + RUBBER LAYER
NUMMRG,NODE				!LOWER ROLL
ALLSEL

!*****************SOLID/ROTATIONAL MESHING**************
!********************OF STEEL SHAFT*********************

TYPE,1					!ET NR.1 - PLANE
MSHKEY,0				!FREE MESHING
ESIZE,SHAFTSIZE				!PLANE MESH- SHAFT
MAT,1					!STEEL MATERIAL
AMESH,1
AMESH,5
AMESH,9
AMESH,13
TYPE,2					!ET NR.2 - SOLID
ESIZE,,ROTDIVSHAFT			!ROTATIONAL DIVISIONS- SHAFT
VROTAT,1,5,,,,,1,18,-180,1		!UPPER SHAFTS
VROTAT,9,13,,,,,23,44,-180,1		!LOWER SHAFTS

ASEL,S,TYPE,,1				!DELETE PLANE ELEMENTS
ACLEAR,ALL				!-ET NR.1 - PLANE ELEMENTS
ALLSEL

!*******************************************************
!********************CONTACT PAIRS**********************
!*******************************************************
!*************NORMAL CONTACT BETWEEN ROLLERS************

ASEL,S,AREA,,6,8			!DEFINE CONTACT
VSLA,R,0
NSLV,R,1
CSYS,11
NSEL,R,LOC,X,100
NSEL,R,LOC,Y,-(90-ACS),-90
REAL,1					!REAL CONST SET NR.1
TYPE,4					!CONTACT ELEMENT- ET NR.4
MAT,3					!DEFINITION OF FRICTION
ESURF					!GENERATE CONTACT ELEMENTS
ALLSEL
ASEL,S,AREA,,14,16			!DEFINE TARGET
VSLA,R,0
NSLV,R,1
CSYS,12
NSEL,R,LOC,X,100
NSEL,R,LOC,Y,(90-ACS),90
REAL,1					!REAL CONST SET NR.1
TYPE,3					!TARGET ELEMENT- ET NR.3
MAT,3					!DEFINITION OF FRICTION
ESURF					!GENERATE CONTACT ELEMENTS
ALLSEL

!***********NORMAL CONTACT BETWEEN FOIL-ROLL**********

ASEL,S,AREA,,14,16			!DEFINE CONTACT- LOWER ROLL
VSLA,R,0
NSLV,R,1
CSYS,12
NSEL,R,LOC,X,100
NSEL,R,LOC,Y,(90-ACS),90
NSEL,R,LOC,Z,-(WB/2)-20,(WB/2)+20
REAL,6					!REAL CONST SET NR.6
TYPE,4					!CONTACT ELEMENT- ET NR.4
MAT,5					!DEFINITION OF FRICTION
ESURF					!GENERATE CONTACT ELEMENTS
ALLSEL
VSEL,S,MAT,,4				!DEFINE TARGET- FOIL- LOW
NSLV,R,1
CSYS,0
NSEL,R,LOC,Z,-30,0
NSEL,R,LOC,Y,0
REAL,6					!REAL CONST SET NR.6
TYPE,3					!TARGET ELEMENT- ET NR.4
MAT,5					!DEFINITION OF FRICTION
ESURF					!GENERATE CONTACT ELEMENTS
ALLSEL

ASEL,S,AREA,,6,8			!DEFINE CONTACT
VSLA,R,0
NSLV,R,1
CSYS,11
NSEL,R,LOC,X,100
NSEL,R,LOC,Y,-(90-ACS),-90
NSEL,R,LOC,Z,-(WB/2)-20,(WB/2)+20
REAL,7					!REAL CONST SET NR.1
TYPE,4					!CONTACT ELEMENT- ET NR.4
MAT,5					!DEFINITION OF FRICTION
ESURF					!GENERATE CONTACT ELEMENTS
ALLSEL
VSEL,S,MAT,,4				!DEFINE TARGET- FOIL- LOW
NSLV,R,1
CSYS,0
NSEL,R,LOC,Z,-30,0
NSEL,R,LOC,Y,FOILTHIKN
REAL,7					!REAL CONST SET NR.6
TYPE,3					!TARGET ELEMENT- ET NR.4
MAT,5					!DEFINITION OF FRICTION
ESURF					!GENERATE CONTACT ELEMENTS
ALLSEL

!********************BONDED CONTACT********************

CSYS,11					!TARGET NR.1 - UPPER RIGHT
CMSEL,S,UPPERROLLNODES,NODE
NSEL,R,LOC,X,75
NSEL,R,LOC,Z,((WB+630)/2-320),((WB+630)/2-240)
REAL,2
TYPE,3
ESURF
ALLSEL
ASEL,S,AREA,,1				!CONTACT NR.1 - UPPER RIGHT
VSLA,R,0
NSLV,R,1
NSEL,R,LOC,X,75
REAL,2
TYPE,6
ESURF
ALLSEL
CMSEL,S,UPPERROLLNODES,NODE		!TARGET NR.2 - UPPER LEFT
NSEL,R,LOC,X,75
NSEL,R,LOC,Z,-((WB+630)/2-240),-((WB+630)/2-320)
REAL,3
TYPE,3
ESURF
ALLSEL
ASEL,S,AREA,,5				!CONTACT NR.2 - UPPER LEFT
VSLA,R,0
NSLV,R,1
NSEL,R,LOC,X,75
REAL,3
TYPE,6
ESURF
ALLSEL

CSYS,12					!TARGET NR.3 - LOWER RIGHT
CMSEL,S,LOWERROLLNODES,NODE
NSEL,R,LOC,X,75
NSEL,R,LOC,Z,((WB+630)/2-320),((WB+630)/2-240)
REAL,4
TYPE,3
ESURF
ALLSEL
ASEL,S,AREA,,13				!CONTACT NR.3 - LOWER RIGHT
VSLA,R,0
NSLV,R,1
NSEL,R,LOC,X,75
REAL,4
TYPE,6
ESURF
ALLSEL
CMSEL,S,LOWERROLLNODES,NODE		!TARGET NR.4 - LOWER LEFT
NSEL,R,LOC,X,75
NSEL,R,LOC,Z,-((WB+630)/2-240),-((WB+630)/2-320)
REAL,5
TYPE,3
ESURF
ALLSEL
ASEL,S,AREA,,9				!CONTACT NR.4 - LOWER LEFT
VSLA,R,0
NSLV,R,1
NSEL,R,LOC,X,75
REAL,5
TYPE,6
ESURF
ALLSEL
CSYS,0

!********************MPC- CONNECTIONS******************

ASEL,S,AREA,,1				!UPPER RIGHT
VSLA,R,0
NSLV,R,1
CSYS,11
NSEL,R,LOC,X,30
CSYS,0
NSEL,R,LOC,X,((WB+150)/2)-80+233.9,((WB+150)/2)-80+311.8
NODE_C1=
*GET,NODENUM1,NODE,0,COUNT
*DIM,NODE_C1,ARRAY,NODENUM1,1,1,,,,0
*DO,I,1,NODENUM1
*GET,NODEMIN1,NODE,0,NUM,MIN
NODE_C1(I,1)=NODEMIN1
NSEL,U,,,NODEMIN1
*ENDDO
*DO,I,1,NODENUM1
TYPE,5
E,1,NODE_C1(I,1)
*ENDDO
ALLSEL

ASEL,S,AREA,,5				!UPPER LEFT
VSLA,R,0
NSLV,R,1
CSYS,11
NSEL,R,LOC,X,30
CSYS,0
NSEL,R,LOC,X,-(((WB+150)/2)-80+233.9),-(((WB+150)/2)-80+311.8)
NODE_C2=
*GET,NODENUM2,NODE,0,COUNT
*DIM,NODE_C2,ARRAY,NODENUM2,1,1,,,,0
*DO,I,1,NODENUM2
*GET,NODEMIN2,NODE,0,NUM,MIN
NODE_C2(I,1)=NODEMIN2
NSEL,U,,,NODEMIN2
*ENDDO
*DO,I,1,NODENUM2
TYPE,5
E,2,NODE_C2(I,1)
*ENDDO
ALLSEL

ASEL,S,AREA,,13				!LOWER RIGHT
VSLA,R,0
NSLV,R,1
CSYS,12
NSEL,R,LOC,X,30
CSYS,0
NSEL,R,LOC,X,((WB+150)/2)-80+267,((WB+150)/2)-80+320.1
NODE_C3=
*GET,NODENUM3,NODE,0,COUNT
*DIM,NODE_C3,ARRAY,NODENUM3,1,1,,,,0
*DO,I,1,NODENUM3
*GET,NODEMIN3,NODE,0,NUM,MIN
NODE_C3(I,1)=NODEMIN3
NSEL,U,,,NODEMIN3
*ENDDO
*DO,I,1,NODENUM3
TYPE,5
E,3,NODE_C3(I,1)
*ENDDO
ALLSEL

ASEL,S,AREA,,9				!LOWER LEFT
VSLA,R,0
NSLV,R,1
CSYS,12
NSEL,R,LOC,X,30
CSYS,0
NSEL,R,LOC,X,-(((WB+150)/2)-80+265.5),-(((WB+150)/2)-80+318.6)
NODE_C4=
*GET,NODENUM4,NODE,0,COUNT
*DIM,NODE_C4,ARRAY,NODENUM4,1,1,,,,0
*DO,I,1,NODENUM4
*GET,NODEMIN4,NODE,0,NUM,MIN
NODE_C4(I,1)=NODEMIN4
NSEL,U,,,NODEMIN4
*ENDDO
*DO,I,1,NODENUM4
TYPE,5
E,4,NODE_C4(I,1)
*ENDDO
ALLSEL
FINISH

!*******************************************************
!***********************SOLUTION************************
!*******************************************************

/SOLU
/GST,ON					!TURNS GRAPHICAL SOLUTION TRACKING ON
EQSLV,PCG,1.0E-6			!PCG ITERATIVE SOLVER, CONVERGENCE TOL
MSAVE,1					!MSAVE OPTION- REDUCE NECESSARY MEMORY
ANTYPE,STATIC				!STATIC ANALYSIS
NLGEOM,ON				!NONLINEAR GEOMETRY ON
AUTOTS,ON				!AUTOMATIC TIME STEPPING
NEQIT,100				!USE MAXIMUM 100 EQUILIBRIUM ITERATIONS
KBC,0					!RAMP LOADING
LNSRCH,OFF				!SWITCH LINE SEARCH OFF

!***************************MACRO**********************
!*******************ROLLER PAIR CONSTRAINT*************
*CREATE,CONSTRAIN,MAC
ASEL,S,AREA,,13
VSLA,R,0
NSLV,R,1
CSYS,12
NSEL,R,LOC,X,25
CSYS,0
D,ALL,ALL				!FULLY CONSTRAIN THE LOWER RIGHT END
ALLSEL					!OF THE SHAFT - ELECTRIC MOTOR
D,1,UX,,,,,ROTX,ROTY			!CONSTRAIN ALL MASTER NODES
D,2,ROTX,,,,,ROTY			!-BEARING IDEALIZATION
D,3,UY,,,,,ROTX,ROTY			!...
D,4,UY,,,,,ROTX,ROTY			!...
NSEL,S,LOC,Z,0
DSYM,SYMM,Z				!HALF SYMMETRY
ALLSEL
VSEL,S,MAT,,4				!CONSTRAINT OF FOIL
NSLV,R,1
NSEL,R,LOC,Z,-100
D,ALL,ALL
ALLSEL
*END
!***********************END OF MACRO*******************

CONSTRAIN				!EXECUTE CONSTRAIN MACRO

NSEL,S,NODE,,1				!FIRST LOADSTEP TO ESTABLISH
NSEL,A,NODE,,2				!CONTACT - FOR CONVERGENCE
D,ALL,UY,-0.001-ROLLERDIST		!IMPROVEMENT
ALLSEL
LSWRITE,1

DDELE,ALL,ALL				!DELETE ALL DOF CONSTRAINTS
CONSTRAIN				!EXECUTE CONSTRAIN MACRO

NSEL,S,LOC,Z,0
NSEL,R,LOC,X,((WB+630)/2)-90,((WB+630)/2)
NSEL,R,LOC,Y,130+ROLLERDIST
*GET,FORCENODERIGHT,NODE,0,COUNT
F,ALL,FY,-(FZYL/2)/FORCENODERIGHT	!HALF ZYLINDER FORCE - HALF SYMM
NSEL,S,LOC,Z,0
NSEL,R,LOC,X,-((WB+630)/2),-((WB+630)/2)+90
NSEL,R,LOC,Y,130+ROLLERDIST
*GET,FORCENODELEFT,NODE,0,COUNT
F,ALL,FY,-(FZYL/2)/FORCENODELEFT	!HALF ZYLINDER FORCE - HALF SYMM
ALLSEL
LSWRITE,2
/EOF
LSSOLVE,2
SAVE
FINISH