/CLEAR,START
/FILNAM,HERTZGLO
/PREP7
/TITLE,CONTACT BETWEEN TWO CYLINDERS
				!DEFINE PARAMETERS
R1=100				!RADIUS OF CYLINDER 1
R2=100				!RADIUS OF CYLINDER 2
L=50				!LENGTH OF THE CYLINDER PAIR
YM1=210000			!YOUNGS MODULUS OF CYLINDER 1
NUE1=0.3			!POISSON RATIO OF CYLINDER 1
YM2=210000			!YOUNGS MODULUS OF CYLINDER 2
NUE2=0.3			!POISSON RATIO OF CYLINDER 2
MUE=0.1				!COEFFICIENT OF FRICTION
ESIZENORM=14			!ELEMENT SIZE OF CYLINDER

*AFUN,DEG			!SWITCH TO DREGREES
				!DEFINE ELEMENT TYPES
ET,1,PLANE42
ET,2,SOLID45
ET,3,TARGE170
ET,4,CONTA173			!173,174,175 TEST
MP,EX,1,YM1			!DEFINE YOUNGS MODULUS - MAT1
MP,NUXY,1,NUE1			!DEFINE POISSON RATIO - MAT1
TB,FRIC,1,,,ISO			!ISOTROPIC CONTACT FRICTION - MAT1
TBDATA,1,MUE			!DEFINE COEFFICIENT FO FRICTION - MAT1
MP,EX,2,YM2			!DEFINE YOUNGS MODULUS - MAT2
MP,NUXY,2,NUE2			!DEFINE POISSON RATIO - MAT2
TB,FRIC,2,,,ISO			!ISOTROPIC CONTACT FRICTION- MAT2
TBDATA,1,MUE			!DEFINE COEFFICIENT FO FRICTION - MAT2
KEYOPT,4,5,1			!CLOSE GAP
KEYOPT,4,10,2			!CONTACT STIFFNESS UPDATE
R,3,,,5,,1E-10			!FKT,ICONT(8)
				!DEFINE KEYPOINTS
CSYS,1	
K,1
K,2,R1
K,3,R1,90
LOCAL,11,1,,(R1+R2)
K,4
K,5,R2
K,6,R2,-90
				!DEFINE LINES
CSYS,1
L,1,2
L,2,3
L,3,1
CSYS,11
L,4,5
L,5,6
L,6,4
				!DEFINE AREAS
AL,1,2,3
AL,4,5,6
				!MESHING
KESIZE,3,1
KESIZE,6,1
MSHKEY,1
TYPE,1
MAT,1
ESIZE,ESIZENORM
AMESH,1
MAT,2
AMESH,2

CSYS,0
ARSYM,X,ALL

ASEL,S,MAT,,1
NSLA,S,1
NUMMRG,NODE
KSLN,S
NUMMRG,KP
ASEL,S,MAT,,2
NSLA,S,1
NUMMRG,NODE
KSLN,S
NUMMRG,KP
ALLSEL
				!EXTRUDE VOLUME
CSYS,0
TYPE,2
ESIZE,,10
MAT,1
ASEL,S,MAT,,1
VEXT,ALL,,,,,L
MAT,2
ASEL,S,MAT,,2
VEXT,ALL,,,,,L
ALLSEL
ASEL,S,TYPE,,1
ACLEAR,ALL
ALLSEL
				!DEFINE TARGET
CSYS,1
VSEL,S,MAT,,1
NSLV,R,1
NSEL,R,LOC,X,R1
NSEL,R,LOC,Y,80,100
REAL,3
TYPE,3
ESURF
ALLSEL
				!DEFINE CONTACT
CSYS,11
VSEL,S,MAT,,2
NSLV,R,1
NSEL,R,LOC,X,R2
NSEL,R,LOC,Y,-80,-100
REAL,3
TYPE,4
ESURF
ALLSEL
FINISH

/SOLU
ANTYPE,STATIC			!STATIC ANALYSIS
NLGEOM,OFF
SOLCONTROL,ON
AUTOTS,ON			!AUTOMATIC TIME STEPPING
NROPT,UNSYM			!UNSYMETRIC STIFFNESS MATRIX
NEQIT,100			!USE MAXIMUM 100 EQUILIBRIUM ITERATIONS
OUTRES,,1			!SAVE RESULTS FOR LAST SUBSTEP OF EACH LS
*CREATE,CONSTRAIN,MAC		!MACRO FOR MODEL-CONSTRAINING
CSYS,0
NSEL,S,LOC,Y,0
D,ALL,UY,0
D,ALL,UX,0
ALLSEL
NSEL,S,LOC,Z,0
NSEL,A,LOC,Z,L
D,ALL,UZ,0
ALLSEL
*END				!END OF MACRO
CONSTRAIN
NSEL,S,LOC,Y,(R1+R2)
D,ALL,UY,-0.0001
ALLSEL
LSWRITE,1
DDELE,ALL,ALL
CONSTRAIN
NSEL,S,LOC,Y,(R1+R2)
CP,1,UY,ALL
SF,ALL,PRES,0.03
ALLSEL
LSWRITE,2
LSSOLVE,1,2
SAVE
FINISH