/FILNAM,HERTZ
/PREP7
/TITLE,CONTACT BETWEEN TWO CYLINDERS

*AFUN,DEG			!SWITCH TO DREGREES
				!DEFINE PARAMETERS
R1=0.050			!RADIUS OF CYLINDER 1 [M]
R2=0.050			!RADIUS OF CYLINDER 2 [M]
L=0.100				!LENGTH OF THE CYLINDER PAIR [M]
YM1=2.1E11			!YOUNGS MODULUS OF CYLINDER 1 [N/M^2]
NUE1=0.3			!POISSON RATIO OF CYLINDER 1 [\]
YM2=2.1E11			!YOUNGS MODULUS OF CYLINDER 2 [N/M^2]
NUE2=0.3			!POISSON RATIO OF CYLINDER 2 [\]
ESIZEFINE=0.001			!ELEMENT SIZE OF SMALL CONTACT AREA
ESIZENORM=0.008			!ELEMENT SIZE OF CYLINDER

ET,1,PLANE42
ET,2,SOLID45
ET,3,TARGE170
ET,4,CONTA174
MP,EX,1,YM1
MP,NUXY,1,NUE1
MP,EX,2,YM2
MP,NUXY,2,NUE2
KEYOPT,4,5,1			!CLOSE GAP
KEYOPT,4,10,2			!CONTACT STIFFNESS UPDATE
R,3,,,0.1,,1E-8			!FKT,ICONT
				!DEFINE KEYPOINTS
CSYS,1	
K,1
K,2,R1
K,3,R1,80
K,4,R1,90
K,5,R1,100
K,6,R1,180
LOCAL,11,1,,(R1+R2)
K,7
K,8,R2,-180
K,9,R2,-100
K,10,R2,-90
K,11,R2,-80
K,12,R2
				!DEFINE LINES
CSYS,1
L,1,2				!Line: 1
L,2,3				!Line: 2
L,3,4				!Line: 3
L,4,5				!Line: 4
L,5,6				!Line: 5
L,6,1				!Line: 6
CSYS,11
L,7,8				!Line: 7
L,8,9				!Line: 8
L,9,10				!Line: 9
L,10,11				!Line: 10
L,11,12				!Line: 11
L,12,7				!Line: 12
LOCAL,12,1,,R1
L,3,5				!Line: 13
L,9,11				!Line: 14
				!DEFINE AREAS
AL,1,2,13,5,6
AL,3,4,13
AL,9,10,14
AL,7,8,14,11,12
LCCAT,1,6			!LINE CONCENTRATION FOR MAPPED MESH
LCCAT,7,12			!LINE CONCENTRATION FOR MAPPED MESH
				!MESHING
CSYS,0
MSHKEY,0
TYPE,1
MAT,1
ESIZE,ESIZEFINE
AMESH,2
MSHKEY,1
ESIZE,ESIZENORM
AMESH,1
MAT,2
MSHKEY,0
ESIZE,ESIZEFINE
AMESH,3
MSHKEY,1
ESIZE,ESIZENORM
AMESH,4
LDELE,15,16			!DELETE COMPRESSED LINES FOR EXTRUDING
				!EXTRUDE VOLUME
CSYS,0
TYPE,2
ESIZE,,20
MAT,1
ASEL,S,MAT,,1
VEXT,ALL,,,,,L
MAT,2
ASEL,S,MAT,,2
VEXT,ALL,,,,,L
ALLSEL
				!DEFINE TARGET
CSYS,1
VSEL,S,MAT,,1
NSLV,R,1
NSEL,R,LOC,X,R1
NSEL,R,LOC,Y,80,100
REAL,3
TYPE,3
ESURF
ALLSEL
CSYS,0
				!DEFINE CONTACT
CSYS,11
VSEL,S,MAT,,2
NSLV,R,1
NSEL,R,LOC,X,R2
NSEL,R,LOC,Y,-80,-100
REAL,3
TYPE,4
ESURF
ALLSEL
				!DELETE PLANE42 ELEMENTS
ASEL,S,TYPE,,1
ACLEAR,ALL
ALLSEL
CSYS,0
FINISH

/SOLU
ANTYPE,STATIC			!STATIC ANALYSIS
NLGEOM,OFF
SOLCONTROL,ON
NROPT,UNSYM			!UNSYMETRIC STIFFNESS MATRIX
AUTOTS,ON			!AUTOMATIC TIME STEPPING

*CREATE,CONSTRAIN,MAC		!MACRO FOR MODEL-CONSTRAINING
CSYS,0
NSEL,S,LOC,Y,0
D,ALL,UY,0
D,ALL,UX,0
ALLSEL
NSEL,S,LOC,Z,0
NSEL,A,LOC,Z,L
D,ALL,UZ,0
ALLSEL
*END				!END OF MACRO

CONSTRAIN			!EXECUTE MACRO
NSEL,S,LOC,Y,(R1+R2)
CP,1,UY,ALL
SF,ALL,PRES,1E5
ALLSEL
NSUBST,2
SOLVE
FINISH