!********************************* Vorbereitung *******************************************

FINISH  
/CLEAR,START

/config,nproc,1

/triad,ltop  					! Anzeigen des globelen KO-Systems im Display
/dev,font,2,times*new*roman,medium,r,14,,,,,   	! Manipulation der Anzeige im Fenster (z.B. Schrift)

/PNUM,LINE,1  					! Einschalten der Elementnummerierung und Farbkodierung im Plot (hier für Line)
/PNUM,KPOI,1  					! Einschalten der Elementnummerierung und Farbkodierung im Plot (hier für Keypoint)
/PNUM,area,1  					! Einschalten der Elementnummerierung und Farbkodierung im Plot (hier für Area)

/FILNAM,rad_halb,1
/TITLE,	Umlaufrad
/TRIAD,LTOP

*afun,deg

/prep7

et,1,plane42,,,2
et,2,solid45
et,3,conta175,,1,,,3,
  keyopt,3,5,3
  keyopt,3,9,0
  keyopt,3,10,2
  keyopt,3,12,0
et,4,targe170
et,5,link10

r,1,531,,
r,2,,,1e-1
r,3,1

! ================= Geometrieparameter ====================

d_aussen = 710
ds_innen = 630
db_innen = 265

breite = 70

winkel = 45
winkel_r1 = 50

d_steg_aussen = 600
stegdicke = 20

r_innen = 14
r1_aussen = 15
r2_aussen = 24

schieflauf = 0

d_seil = 26

!===========================================================
!                Materialparameter                         =
!===========================================================

mp,ex,1,210000
mp,prxy,1,0.3
mp,mu,1,0.15

!===========================================================
!                  Geometrie                               =
!===========================================================

! -------------------  Scheibe  ----------------------------
k,1,db_innen/2,0,0
k,2,ds_innen/2,0,0
k,3,ds_innen/2+r_innen-ABS(r_innen*SIN(-winkel/2)),ABS(r_innen*COS(-winkel/2)),0
k,4,d_aussen/2,ABS(r_innen*COS(-winkel/2))+(d_aussen/2-(ds_innen/2+r_innen-ABS(r_innen*SIN(-winkel/2))))*TAN(winkel/2),0
k,5,d_aussen/2,breite/2,0
k,6,ds_innen/2+r_innen-ABS(r2_aussen*SIN(-winkel/2))+(breite/2-ABS(r2_aussen*COS(-winkel/2)))*TAN(90-winkel/2),breite/2,0
k,7,ds_innen/2+r_innen-ABS(r2_aussen*SIN(-winkel/2)),ABS(r2_aussen*COS(-winkel/2)),0
k,8,d_steg_aussen/2+ABS(r1_aussen*SIN(winkel_r1)),stegdicke/2+r1_aussen-ABS(r1_aussen*COS(winkel_r1)),0
k,9,d_steg_aussen/2,stegdicke/2,0
k,10,db_innen/2,stegdicke/2,0

! Keypoints fuer die Radienmittelpunkte
k,11,d_steg_aussen/2,stegdicke/2+r1_aussen,0
k,12,ds_innen/2+r_innen,0,0

k,13,d_steg_aussen/2,0,0

! Spiegeln
ksymm,y,3,11,1,,,0

! ---------- Keypoints fuer die Rotationsachse ---------------
k,101,0,0,0
k,102,0,10,0

l,1,13,20
l,13,2,5
l,3,4,15
l,4,5,4
l,6,5,2
l,7,6,14
l,10,9,20
l,1,10,4
l,13,9,4

l,14,15,14
l,15,16,4
l,16,17,2
l,18,17,15
l,21,20,20
l,1,21,4
l,13,20,4

larc,2,3,12,14
larc,8,7,12,24
larc,9,8,11,15

larc,2,14,12,14
larc,19,18,12,24
larc,20,19,22,15

lesize,17,,,10
lesize,18,,,5
lesize,19,,,5

lesize,20,,,10
lesize,21,,,5
lesize,22,,,5

!----------------- Seil Bereich 1 0 - 90 Grad ---------------------

k,201,ds_innen/2,0,0

! ---------------- Flaechen -----------------
al,1,9,7,8
al,2,17,3,4,5,6,18,19,9

al,1,16,14,15
al,2,20,10,11,12,13,21,22,16

!---------- Extrusion des Scheibenkörpers -----------
type,1
mat,1
amesh,all

type,2
extopt,esize,30,0,
vrotat,1,2,3,4,,,101,102,180

esel,u,type,,1

asel,s,,,1,4,1
aclear,all
allsel

!---------- Rotation der Seillinie -----------------

type,5
extopt,esize,40,0
lrotat,201,,,,,,101,102,180
lesize,105,,,20
lesize,106,,,20
real,1
lmesh,105,106,1


! Spiegeln Halbrad
vsymm,z,1,8,1,,0,0

! Merging
vsel,s,,,1,8,1
vsel,a,,,11,18,1
eslv,s
nslv,s,1
nsel,r,loc,z,0
nummrg,node

allsel

!==============================================
!=              Kontaktbedingung              =
!==============================================

!-------------- Target Surface ---------------
allsel
asel,s,,,11
asel,a,,,23
asel,a,,,37
asel,a,,,49
nsla,s,1
esln,s
type,4
mat,1
real,2
esurf,

!-------------- Contact Nodes ---------------

allsel
lsel,s,,,105,106,1
nsll,s,1
esln,s,0
type,3
mat,1
real,2
esurf,

allsel
save

!=============================================
!=                Solution                   =
!=============================================

/solu

!---------- Constraints - Schweißung --------------
asel,s,,,8
asel,a,,,21
asel,a,,,34
asel,a,,,47
asel,a,,,75
asel,a,,,60
asel,a,,,103
asel,a,,,90
nsla,s,1
d,all,all

allsel

!---------- Constraints - Seil ----------------
lsel,s,,,105,106,1
nsll,s,1
d,all,ux,0

allsel

ksel,s,,,61
nslk,s,1
d,all,uz,0

allsel

!------------ Kraefte ------------------
ksel,s,,,201
nslk,s,1
F,all,FZ,138000
ksel,s,,,62
nslk,s,1
F,all,FZ,138000

allsel

!------------ Solutioneinstellungen --------------
antype,static,new
nlgeom,off
autots,on
nsubst,5,200,5
outres,all,all
save
SOLVE
save

fini