!********************************* Vorbereitung *******************************************

FINISH  
/CLEAR,START

Kraft = 0.675

/config,nproc,2

/triad,ltop  					! Anzeigen des globelen KO-Systems im Display
/dev,font,2,times*new*roman,medium,r,14,,,,,   	! Manipulation der Anzeige im Fenster (z.B. Schrift)

/PNUM,LINE,1  					! Einschalten der Elementnummerierung und Farbkodierung im Plot (hier für Line)
/PNUM,KPOI,1  					! Einschalten der Elementnummerierung und Farbkodierung im Plot (hier für Keypoint)
/PNUM,area,1  					! Einschalten der Elementnummerierung und Farbkodierung im Plot (hier für Area)

/FILNAM,3PB_kont3D_2,1
/TITLE,	3 - Punkt Biegung - Kraft = %2*Kraft% N (Probe 1)
/TRIAD,LTOP

!********************************* Pre-Processor ******************************************

/prep7

et,1,plane82,,,2
et,2,conta174,,1,,,3,
  keyopt,2,5,3
  keyopt,2,9,0
  keyopt,2,10,2
  keyopt,2,12,0

et,3,targe170
et,4,solid95
mp,ex,1,169204
mp,ey,1,169204
mp,ez,1,130208					! E-Modul von Silizium 130 - 180 GPa (Hier 169000 N/mm2)
mp,dens,1,2330e-12				! Dichte in t/mm3
mp,prxy,1,0.06255				! Querkontraktionszahl (Poisson-Konstante)
mp,pryz,1,0.36129
mp,prxz,1,0.36129
mp,Gxy,1,50950
mp,Gyz,1,79600
mp,Gxz,1,79600
acel,,,-9810					! 9810 mm/s2

mp,mu,2,0

! ---- Geometrie ----

hoehe   = 0.250
laenge  = 35
l_auf	= 32
breite	= 4

r_auf = 1
r_last = 1

! ---- Knotenpunkte ----

! Balken
k,1,0,0,0
k,2,laenge/2-l_auf/2,0,0
k,3,laenge/2,0,0
k,4,laenge/2,breite,0
k,5,laenge/2-l_auf/2,breite,0
k,6,0,breite,0

! ---- Linien ----

! Balken
l,1,2,15
l,2,3,150
l,3,4,10
l,5,4,150
l,6,5,15
l,1,6,10
l,2,5,10

! ---- Flächen ----

al,1,7,5,6		! Balken
al,2,3,4,7

type,1
mat,1
amesh,1,2,1

type,4
mat,1
extopt,esize,3,0,
vext,1,2,1,,,hoehe

esel,u,type,,1

asel,s,,,1,2,1
aclear,all
allsel

numcmp,all
allsel

!asel,s,,,8,9,1
!asel,a,,,2
!cm,flaeche,area

!*ULIB,AnsCares80,lib
!*USE,SURF80,1,'flaeche'

allsel

! ---- Kontaktpaar Auflage links - Balken

*get,nodenum,node,,num,max
auflager_li_start = nodenum + 1
auflager_li_end  = nodenum + 2

n,auflager_li_start,laenge/2-l_auf/2,0,-r_auf
n,auflager_li_end,laenge/2-l_auf/2,breite,-r_auf
tshape,cyli
r,1,1,,1e-5
type,3
mat,2
real,1
e,auflager_li_start,auflager_li_end

*get,nodenum,node,,num,max
pilot_aufl_1 = nodenum + 1

n,pilot_aufl_1,laenge/2-l_auf/2,0,-r_auf
type,3
real,1
mat,2
tshape,pilo
e,pilot_aufl_1

asel,s,,,1
asel,a,,,2
nsla,s,1
nsel,r,loc,x,0,laenge/2-l_auf/2+2*r_last
type,2
mat,2
real,1
esurf,

allsel

! ---- Kontaktpaar Last - Balken

*get,nodenum,node,,num,max
last_li_start = nodenum + 1
last_li_end = nodenum + 2

tshape,cyli
r,2,1,,1e-5
type,3
mat,2
real,2
n,last_li_start,laenge/2,0,hoehe+r_last
n,last_li_end,laenge/2,breite,hoehe+r_last
e,last_li_start,last_li_end

*get,nodenum,node,,num,max
pilot_last_1 = nodenum + 1

n,pilot_last_1,laenge/2,0,hoehe+r_last
type,3
real,2
mat,2
tshape,pilo
e,pilot_last_1

allsel
nsel,s,loc,z,hoehe
nsel,r,loc,x,laenge/2-2*r_last,laenge/2
type,2
mat,2
real,2
esurf,

allsel

! ************************************************ Solution *********************************************************

/solu

nsel,s,,,pilot_aufl_1
d,all,all

allsel

nsel,s,,,pilot_last_1
d,all,uy,0
d,all,ux,0

allsel

asel,s,,,10
nsla,s,1
d,all,ux,0

allsel

ksel,s,,,1
nslk,s
d,all,uy,0

allsel

F,pilot_last_1,FZ,-Kraft

allsel

! -- Für Statikanalyse --
antype,static,new
nlgeom,off

autots,on
nsubst,5,200,5
outres,all,all

SOLVE

fini