!*********************************************
!** Calcuation of selfind conductor         **
!**					    **
!** Peters 21.2.2006			    **
!*********************************************

fini 
/clear 

*abbr,sefind,/input,selfind,txt

!**Define constants

freq=50
strom=10e-3
kappa=56e6

!**Geometric parameters

luftx=10e-3
lufty=10e-3
luftz=2e-2
unend=50e-5


/prep7 
/view,,1,2,3

bloc,-50e-5,50e-5,-25e-5,25e-5,-0.75e-2,0.75e-2 !Leiter
bloc,-luftx/2,luftx/2,-lufty/2,lufty/2,-luftz/2,luftz/2 !Luft


vovl,all
!baue das unendliche
bloc,-luftx/2,luftx/2,-lufty/2,lufty/2,luftz/2,luftz/2+unend !frontside
bloc,-luftx/2,luftx/2,-lufty/2,lufty/2,-luftz/2,-(luftz/2+unend) !backside
bloc,-luftx/2,luftx/2,lufty/2,lufty/2+unend,-(luftz/2+unend),luftz/2+unend !top
bloc,-luftx/2,luftx/2,-lufty/2,-(lufty/2+unend),-(luftz/2+unend),luftz/2+unend !bottom
bloc,luftx/2,luftx/2+unend,-(lufty/2+unend),lufty/2+unend,-(luftz/2+unend),luftz/2+unend !right
bloc,-(luftx/2+unend),-luftx/2,-(lufty/2+unend),lufty/2+unend,-(luftz/2+unend),luftz/2+unend !left


numcmp,volu
!V1:Leiter  V2:front v3:luft V4:back V5:bottom v6:top v7:left v8:right 

!***********************
et,1,97     	!Luft 
et,2,97,1   	!Leiter
et,3,111,,	!unendliche

mp,murx,1,1 ! Mur Luft ist 1

mp,murx,2,1 ! Mur Leiter
mp,rsvx,2,1/kappa !widerstand 1/leitfähigkeit

mp,murx,3,1 ! Mur unendlich


!**Leiter
type,2
mat,2 ! 
vmesh,1 ! 

!*******Unendliche*******
type,3
mat,3
mshape,1,3D ! Tetraheder Netz

vmesh,2
vmesh,4
vmesh,5
vmesh,6
vmesh,7
vmesh,8


!**Luft*************
type,1
mat,1
esize,0.001
mshape,1,3D ! Tetraheder Netz
vmesh,3


!******RAND**********
nsel,all
nsel,s,loc,x,luftx/2+unend
nsel,a,loc,x,-luftx/2-unend
nsel,a,loc,y,lufty/2+unend
nsel,a,loc,y,-lufty/2-unend
nsel,a,loc,z,luftz/2+unend
nsel,a,loc,z,-luftz/2-unend

sf,all,inf
allsel


!----------------------------------
/solu


!--------Bounary conditions--------
esel,s,mat,,2
nsle
nsel,r,loc,z,-0.75e-2
cp,1,volt,all
*get,n1,node,,num,min
f,n1,amps,strom ! Strom in Leiter in z-Richtung
nsle
nsel,r,loc,z,0.75e-2
d,all,volt,0
allsel
antyp,harm
harfr,freq

solve

!----------------------------------------
/post1


set,1,1
allsel
etable,energie,sene
ssum
*get,sumenergie,ssum,,item,energie
ind_H=2*sumenergie/strom/strom
ind_nH=ind_H*1e9


/eof