!Aufgabe von Pawel
!thermisch elektrisch
finish  $/clear
*abbr,pawel2,/input,pawel2,txt
breit1=2e-3
hoch1=10e-3
breit2=20e-3
hoch2=5e-3

/PREP7  
rectng,-breit1/2,breit1/2,0,hoch1
rectng,-breit2/2,breit2/2,0,-hoch2
AGLUE,all
!A1:Stift  A3:Platte
ET,1,PLANE223,110   
!*  
MP,KXX,1,20
MP,C,1,120 
MP,DENS,1,5600 
MP,PERX,1,1
MP,RSVX,1,1.5e-8   
MP,SBKX,1,2e-6 
MP,KXX,2,1.5   
MP,C,2,75  
MP,DENS,2,8500 
MP,PERX,2,1
MP,RSVX,2,1.8e-5   
MP,SBKX,2,-200e-6 
 
AESIZE,ALL,0.001,   
TYPE,1   
MAT,1
AMESH,1 
mat,2
amesh,3

!---Randbedingungen-----
nsel,s,loc,y,hoch1
d,all,temp,290
!
nsel,s,loc,y,-hoch2
d,all,temp,290
!
nsel,s,loc,y,-hoch2
d,all,volt,0
! 
!--------------------------
/SOLU  
Toffst,273
ANTYPE,4
TRNOPT,FULL
LUMPM,0
OUTRES,ALL,ALL
AUTOTS,0
LNSRCH,1
CNVTOL,heat,1,1.e-3
CNVTOL,amps,1,1.e-3
ALLSEL,ALL,ALL
!
!**************************************************************
! Hinweise:
!**************************************************************
!
! Ausgehend von einer konstanten Temperatur
! wird die thermische Transiente fuer alle Knoten berechnet,
! wenn an der oberen Kante eine um 10 K hoehere Temp.
! angelegt wird.
! Der verwendete Elementtyp berechnet gleichzeitig
! die Potenzialverteilung (untere Kante auf Masse)
! ==> siehe Animation.
!
! - untere Kante stets auf 0 Volt
! - zuerst stationaeren Zustand berechnen
!   ==> timint,off berechnet stationaeren Zustand,
!       da an den Raendern die gleiche Temp. von 290 K angelegt wurde,
!       ist die Temperatur ueber gleich
! - nun Transiente berechnen:
!   ==> RB setzen
!       timint,on setzen
!       Endzeit und Schrittweite (NSUBST) festlegen
!       und Transiente berechnen.  
!**************************************************************
!
!------ Ausgangszustand 
timint,off
time,1e-5
allsel
SOLVE
!
!------ Transiente
steps=20
!
nsel,s,loc,y,hoch1
d,all,temp,300
!
timint,on
time,10
NSUB,steps
!
allsel
solve
FINISH
!
!--------------------------
/post1
!
!------ Animation volt (max. Spannung 1.2 mV)
/cont,1,9,0,,1.2e-3
plns,volt
ANTIME,steps,0.3,,0

/eof

!------ Animation temp 
/cont,1,9,290,,300
plns,temp
ANTIME,steps,0.3,,0