/CWD,'C:\Users\mantheyr\Desktop\SU819'  
/TITLE,SU819,Stress analysis
/GRA,Power
/GST,ON
/TRAID,OFF
/ESHAPE,1
/UNIT,SI

/PREP7  
ANTYPE,0                        ! STATIC ANALYSIS

ET,1,BEAM189			! 3-D 3-node beam element
!KEYOPT,1,2,1			! Section is assumed to be rigid (classical beam theory)

ET,2,BEAM189			! 3-D 3-node beam element
!KEYOPT,1,2,1

ET,3,CONTA176			! 3D LINE-TO-LINE CONTACT
KEYOPT,3,3,1			! Crossing Beams
KEYOPT,3,4,0			! Rigid surface constraint
KEYOPT,3,2,2			! MPC CONTACT ALGORITHM
KEYOPT,3,12,5			! BONDED ALWAYS TYPE CONTACT
KEYOPT,3,9,3			! include offset only

ET,4,TARGE170			! 3D TARGET SEGMENT
KEYOPT,4,1,1			! High order elements
KEYOPT,4,2,1			! BC specified by user
KEYOPT,4,4,0			! DOFS constraints rotz/y/x and uz/y/x
   
SECType,1,BEAM,I,HE120B		!Define beam section HE120B
SECdata,0.120,0.120,0.120,0.011,0.011,0.0065 

R,2,0.2,0.2,,,,0.7,,		! RADIUS ON THE TARGET AND CONTACT SIDES
RMODIF,2,3,10e4			! NORMAL CONTACT STIFFNESS-ABSOLUTE VALUE
RMODIF,2,12,10e4			! TANGENTIAL CONTACT STIFFNESS-ABSOLUTE VALUE
RMODIF,2,10,-0.28		! Contact surface offset

mp,ex,1,21e10			! E-modul
mp,nuxy,1,0.3			! Poissons ratio
!MP,MU,1,			! Coefficient of friction

!Define Keypoints
K,1 
K,2,0,0.5,0
K,3,0,0.62,0
K,4,0.12,0.56,-0.5
K,5,0.12,0.56,-0.06
K,6,0.12,0.56,0.06
K,7,0.12,0.56,0.5

!Keypoints for beam orientation
K,8,-1
K,9,-1,0.56

! Define lines
L,1,2
L,2,3   
L,4,5   
L,5,6
L,6,7

!Orientation of sections
LSEL,,,,1,2
LATT,,,,,8

LSEL,,,,3,5
LATT,,,,,9
ALLSEL

LSEL,,,,1,5
LESIZE,all,,,10
ALLSEL

!Assigning of the section to the lines
type,1				! Vertical beam
mat,1  
secnum,1
lmesh,1,2

type,2				! Horizontal Beam
mat,1  
secnum,1
lmesh,3,5

TYPE,3				! Contact on vertical beam
REAL,2
MAT,1
ESEL,s,Type,,1
NSLE
ESURF

TYPE,4				! Target on horizontal beam
REAL,2
MAT,1
ESEL,s,TYPE,,2
NSLE
ESURF

!Define boundary conditions
ALLSEL
DK,1,all			! Clamped base end of horizontal beam
FK,7,FX,-18000			! Define load on end of vertical beam
FINISH

/SOLUTION
NLGEOM,ON			! Large deformation is included
OUTRES,ALL,ALL
SOLVE
FINI
/POST1
!torsional moment Mt
etable,smis4,smisc,4
etable,smis17,smisc,17
pretab,smis4,smis17