{######
  Makro Aendere_schriftart_groesse von friedhelm at work mit eingebunden

  EVA_Batch_dwg <Ordner der umzuwandelnden mi-Dateien> <Ausgabeordner der dwg-Dateien> <neue Schiftart>
  (Makro vereinfacht ohne Directory, Anfang Ende)

  Beispiel: EVA_Batch_dwg 'd:\mi' 'd:\dwg' 'hp_i3098_v'

  Ordner 'd:\mi' und 'd:\dwg' müssen dann existieren

  Ordner 'c:\temp' muss auf jeden Fall existieren

  ###### Der Dateiname darf nicht länger als 40 Zeichen sein ######
######}

DEFINE EVA_Batch_dwg
  PARAMETER InVerzeichnis  { mi-Dateien }
  PARAMETER OutVerzeichnis { dwg-Dateien }
  PARAMETER Z_Schriftart

  LOCAL Dateiname
  LOCAL Zaehler

  LOCAL Schriftart
  LOCAL Groesse
  LOCAL Versi


  store all del_old ('c:/temp/eva_sbd.mi')
  CATALOG InVerzeichnis SELECT 'FILE_NAME' '*' DEL_OLD (OutVerzeichnis+'/'+'eva_sbd.txt')
  LET Zaehler 0
  OPEN_INFILE 1 (OutVerzeichnis+'/'+'eva_sbd.txt')
  READ_FILE 1 Dateiname READ_FILE 1 Dateiname READ_FILE 1 Dateiname READ_FILE 1 Dateiname
  LOOP
    LET Zaehler (Zaehler+1)
    READ_FILE 1 Dateiname
      IF (Dateiname<>'END-OF-FILE')
        LET Dateiname (SUBSTR Dateiname 1 40)
        LET Dateiname (TRIM Dateiname)
        EDIT_PART TOP
        DELETE ALL CONFIRM
        TRAP_ERROR
          LOAD (InVerzeichnis+'/'+Dateiname)
        IF (CHECK_ERROR)
          DISPLAY_NO_WAIT (Dateiname+' ... '+ERROR_STR)
        END_IF

{###### Makro von Friedhelm ######}
  INQ_ENV 0 
  LET Versi (INQ 2)
  
  INQ_SELECTED_ELEM SELECT GLOBAL TEXTS ALL CONFIRM
  
  IF (Versi < 16)
    WHILE (INQ 14)
      LET Schriftart (INQ 302)
      LET Groesse (INQ 6)
      CHANGE_TEXT_FONTNAME Z_schriftart GLOBAL POINTER (INQ 2) END
      IF ((Groesse > 0) AND (Groesse <= 2.5)) 
        CHANGE_TEXT_SIZE 2.5 GLOBAL POINTER (INQ 2) END
      ELSE_IF ((Groesse > 2.5) AND (Groesse <= 5))
        CHANGE_TEXT_SIZE 3.5 GLOBAL POINTER (INQ 2) END
      ELSE_IF ((Groesse > 5) AND (Groesse <= 10))
        CHANGE_TEXT_SIZE 8 GLOBAL POINTER (INQ 2) END 
      END_IF
      INQ_NEXT_ELEM
    END_WHILE
  ELSE
    WHILE (INQ 14)
      LET Schriftart (INQ 302)
      LET Groesse (INQ 6)
      CHANGE_TEXT_FONTNAME Z_schriftart GLOBAL POINTER (INQ 332) END
      IF ((Groesse > 0) AND (Groesse <= 2.5)) 
        CHANGE_TEXT_SIZE 2.5 GLOBAL POINTER (INQ 332) END
      ELSE_IF ((Groesse > 2.5) AND (Groesse <= 5))
        CHANGE_TEXT_SIZE 3.5 GLOBAL POINTER (INQ 332) END
      ELSE_IF ((Groesse > 5) AND (Groesse <= 10))
        CHANGE_TEXT_SIZE 8 GLOBAL POINTER (INQ 332) END 
      END_IF
      INQ_NEXT_ELEM
    END_WHILE
  END_IF	
{###### Ende Makro von Friedhelm ######}

        TRAP_ERROR
          STORE DWG V1012 ALL DEL_OLD (OutVerzeichnis+'/'+Dateiname+'.dwg') CONFIRM
        IF (CHECK_ERROR)
          DISPLAY_NO_WAIT (Dateiname+' ... '+ERROR_STR)
          WAIT 2
        END_IF
      END_IF {(Dateiname<>'END-OF-FILE')}
    EXIT_IF (Dateiname='END-OF-FILE')
  END_LOOP
  END
  CLOSE_FILE 1
  EDIT_PART TOP
  DELETE ALL CONFIRM
  load ('c:/temp/eva_sbd.mi')
END_DEFINE