FINISH
/CLEAR 
/PREP7  
/UNITS,MKS  
!******* Einheiten MKS Unit *******
!Length                 m
!Force                  N
!Time                   s
!Mass                   kg
!Pressure           	Pa
!Velocity           	m/s
!Acceleration           m/(s)2
!Density                kg/(m)3
!Stress                 Pa
!Young's  Modulus   	Pa
!Power                  W

! *** Elementtyp des Blocks und Materialparameter ***   
ET,1,SOLID45

!**************Matrerialeigenschaften***************************
!MP,C,1,460    	!Wärmekapazität 460 J/(kg°C)   
!MP,KXX,1,16   	!Wärmeleitfähigkeit 16 W/(m°C )
MP,DENS,1,7800  !Dichte 7800 kg/m³
MP,EX,1,200E9  	!E-Modul 200kN/mm² 
MP,PRXY,1,0.3   
!MP,ALPX,1,10.5e-6  !Wärmeausdehnung 10,5 


!***************************************************************

! ************* Geometrie für Standard KMD *********************   

! Maße immer in Meter!!  

A=0.48		!Gesamtlänge 
B=0.150   	!Breite   
C=0.075   	!Tiefe   
D=0.320  	!Abstand Löcher außen  
E=0.080  	!Loch außen bis Rand
F=0.045 	!Radius Löcher außen   
G=0.0375  	!Radius Loch Mitte   
H=0.035   	!Phase Rand  

F1=50000	!Kraft in N     10.000N ~ 1000kg


!**************************************************************

CYL4,E,(B/2),F  	! Loch außen
CM,L1,AREA
CYL4,(A/2),(B/2),G 	! Loch Mitte 
CM,L2,AREA
 


K, 100, H,0,0  		! Keypoints für Phase links 
K, 101, 0,H,0   
K, 102, 0,(B-H),0   
K, 103, H,B,0   

LSTR,100,101
LSTR,101,102
LSTR,102,103

K,110,E,(B/2),0
K,112,E,0,0
K,113,E,B,0
K,200,(A/2),B,0
K,201,(A/2),0,0
K,202,((D*0.25)+E),0,0
K,203,((D*0.25)+E),B,0
K,206,((D*0.25)+E),(B/2),0
LANG,4,202,90,
LANG,1,203,90,
LANG,6,203,90,
LANG,7,202,90,
LSTR,103,113
LSTR,113,203
LSTR,100,112
LSTR,112,202
LSTR,200,201
LSTR,203,200
LSTR,200,6
LSTR,201,8
LSTR,1,206
LSTR,206,7
LSTR,202,201
A,113,110,103
A,103,110,102
A,102,110,101
A,101,110,100
A,100,110,112
A,113,2,10,203
A,203,10,1,206
A,206,1,9,202
A,202,9,4,112
A,202,201,8,12
A,203,200,6,11
A,206,7,12,202
A,206,7,11,203
ALLS
ASEL,S,AREA,,3,7
CM,A,AREA
LSEL,S,LINE,,2,3
CM,B,LINE
ASBL,A,B
ASEL,S,AREA,,16,19
ASEL,A,AREA,,24
ADELE,ALL,,,1 
ALLS
VEXT,ALL,,,0,0,C			! ***Extrusion	
VSEL,S,VOLU,,1,2			! Löcher entfernen
VDELE,ALL,,,1
ALLS
VSEL,ALL
VGLUE,ALL
ACCAT,16,17				!Zwei flächen zusammenfügen
NUMMRG, ALL, 0, , , LOW  		! doppelte Keypoints entfernen
ESIZE,0.01,0, 				!Vernetzung  
MSHAPE,0,3D 
MSHKEY,1
VMESH,ALL
ALLS

! *********************** Randbedingungen ****************************************


! **********************	Lagerung      ****************************
NSEL,S,LOC,X,(A/2)
D, ALL, UX,0
ALLS
NSEL,S,LOC,X,(0.015),(0.018)
NSEL,R,LOC,Y,(0.48*B),(0.52*B)
NSEL,R,LOC,Z,(0.48*C),(0.52*C)
D,ALL,UZ,0
D,ALL,UY,0

! **********************	Kräfte        **************************
ASEL,S,AREA,,6,7
ASEL,A,AREA,,16,19
NSLA,S,1
*GET,NN,NODE,,COUNT
F, ALL, FX, (-F1/NN)
ALLS


! *********************** Lösungsteil ****************************************

/SOLUTION

ASEL,S,AREA,,49
ASEL,A,AREA,,53
DA,ALL,SYMM
ALLS
SOLVE