FINISH
/CLEAR,ALL
/PREP7

SCAL = 1e-3

ET,10,SHELL181				! Panel

ET,300,SOLID5,3				! Piezo

ET,500,CIRCU94,0,,,,,0

!-----------Material Piezo
TB,ANEL,300,,,1
TBDATA,1,1.683E-11,-5.656E-12,-7.107E-12    	! s11,s21,s31 - compliance, not piezo constants !!
TBDATA,7,1.5E-11,-5.1E-12             	! s22,s32
TBDATA,12,1.9E-11                    	! s33
TBDATA,16,5.096E-11                    	! s44
TBDATA,19,5.096E-11                    	! s55
TBDATA,21,4.497E-11                    	! s66

MP,DENS,300,7800          		! Density [kg/m^3], from: PIceramic

MP,PERX,300,1980     				! Absolute Permittivity, from: PIceramic
MP,PERY,300,1980     				! =1980*eps0  --"--
MP,PERZ,300,2400     				! =2400*eps0  --"--

TB,PIEZ,300,,,1           			! piezoelectrical constants [m/V], from: PIceramic
TBDATA,3,-210e-12       				! d31 --"--
TBDATA,6,-210e-12       				! d32 --"--
TBDATA,9,450e-12        				! d33 --"--
TBDATA,11,500e-12       				! d24 from: Preumont "Active Structures"
TBDATA,13,580e-12       				! d15 --"--

!------Material plate
MP,EX,100,71e9        				! Young's Modulus [N/m^2]
MP,NUXY,100,0.3         				! Poisson Ratio
MP,DENS,100,2660          			! Density [kg/m^3]
!--------
! GEOMETRY
! ---------------------------------------------------------
piezo_ob_length	=	50*SCAL
piezo_ob_width	=	30*SCAL

piezo_ob_xm =	855*SCAL			!von 25 bis 975
piezo_ob_ym =	55*SCAL			!von 15 bis 485

piezo_ob_x1 = (piezo_ob_xm)-(piezo_ob_length/2)
piezo_ob_x2	= (piezo_ob_xm)+(piezo_ob_length/2)
piezo_ob_y1	= (piezo_ob_ym)-(piezo_ob_width/2)
piezo_ob_y2	= (piezo_ob_ym)+(piezo_ob_width/2)

CSYS,0

OB_width	 =  500*SCAL
OB_length	 = 1000*SCAL
OB_thickness =   5*SCAL

R,100,0.025
R,200,1000
!R,200,0.1

SECTYPE,10,SHELL			! Plate layup
SECDATA,OB_thickness,100
SECOFFSET,TOP


!=== Optical Bench ===!
K,1,0        ,0       ,0
K,2,OB_length,0       ,0
K,3,OB_length,OB_width,0
K,4,0        ,OB_width,0
A,1,2,3,4
*GET,a_plate,AREA,,NUM,MIN

BLOCK,piezo_ob_x1,piezo_ob_x2,piezo_ob_y1,piezo_ob_y2,0,1*SCAL
BLOCK,piezo_ob_x1,piezo_ob_x2,piezo_ob_y1,piezo_ob_y2,1*SCAL,2*SCAL

NUMMRG,KP


ALLSEL

! MESH
! ---------------------------------------------------------
!------Platte
ASEL,S,LOC,Z,0			
ESIZE,10*SCAL
TYPE,10
MAT,100
SECNUM,10

AMESH,ALL


!---Piezo
VSEL,all
ESIZE,10*SCAL
TYPE,300
MAT,300
VMESH,ALL
alls
NUMMRG,KP
NUMMRG,NODE



!-----CIRCU94 Element
VSEL,all
nslv,s,1
nsel,r,loc,z,0
*get,circu1,node,,num,min

VSEL,all
nslv,s,1
nsel,r,loc,z,1*SCAL
nsel,r,loc,y,piezo_ob_y2
nsel,r,loc,x,piezo_ob_x2
*get,circu2,node,,num,min

TYPE,500
MAT,0
REAL,200
E,circu1,circu2
!
!!------Kopplung der elektrischen FHGs
VSEL,all
nslv,s,1
nsel,r,loc,z,0
CP,1,VOLT,all
D,all,VOLT,0

VSEL,all
nslv,s,1
nsel,r,loc,z,2*SCAL
CP,2,VOLT,all


!----BC
nsel,s,loc,x,0
D,all,all,0

NUMMRG,NODE
NUMMRG,KP
ALLS
FINISH


/SOLU

eqslv,sparse
F,5009,FZ,-100
	
ANTYPE,HARMONIC
!HROUT,OFF									
!D,14819,UZ,-0.1 
!OUTPR, ,LAST								 
HARFRQ,4.1,4.5								!erste Eigenfrequenz (1. Biegemode)
NSUBST,50								
outres,all,all									
outpr,all,all									
KBC,1									
!DMPRATE,0.001
mp,dmprat,100,0.001	
alls
SOLVE   
FINISH