/COM,ANSYS MEDIA REL. 11.0 (10/27/2006) REF. VERIF. MANUAL: REL. 11.0
/VERIFY,VM255
/TITLE,VM255,DELAMINATION OF DOUBLE CANTILEVER BEAM USING DEBONDING
/COM,   REF: ALFANO, G. AND CRISFIELD, M. A.,
/COM,   "FINITE ELEMENT INTERFACE MODELS FOR THE DELAMINATION ANALYSIS
/COM,   OF LAMINATED COMPOSITES: MECHANICAL AND COMPUTATIONAL ISSUES"
/COM,   INT. J. NUMER. METH. ENGNG 2001, 50:1701-1736.

!********************************************************************
!* GEOMETRIE
!********************************************************************

laenge=100
hoehe=1.5
ini_riss=15
dicke=2

GI=0.28
GII=GI
GIII=GII
RZ=1.7
RT1=RZ
RT2=RT1

eta_damp=1.0e-5
interface_steifigkeit=1e6


!********************************************************************
!* GEOMETRIE
!********************************************************************

/PREP7
ET,1,PLANE182              !* 2D 4-NODE STRUCTURAL SOLID ELEMENT
ET,2,PLANE182
ET,3,SOLID186
ET,4,SOLID186


ET,5,TARGE170              !* 2D TARGET ELEMENT
ET,6,CONTA174              !* 2D CONTACT ELEMENT
KEYOPT,6,12,5              !* BONDED ALWAYS CONTACT


!********************************************************************
!* MATERIAL
!********************************************************************

MP,EX,1,1.353E5            !* E11 = 135.3 GPA
MP,EY,1,9.0E3              !* E22 =   9.0 GPA
MP,EZ,1,9.0E3              !* E33 =   9.0 GPA
MP,GXY,1,5.2E3             !* G12 =   5.2 GPA
MP,GXZ,1,5.2E3             !* G12 =   5.2 GPA
MP,GYZ,1,5.2E3             !* G12 =   5.2 GPA

MP,PRXY,1,0.24
MP,PRXZ,1,0.24
MP,PRYZ,1,0.46
KOPEN  = interface_steifigkeit
TB,CZM,2,1,1,CBDE
TBDATA,1,RZ,GI,RT1,GII,eta_damp,1

MP,EX,3,210000
MP,PRXY,3,.3

!********************************************************************
!* GEOMETRIE ERZEUGEN
!********************************************************************

RECTNG,0,laenge,0,hoehe         !* DEFINE AREAS
RECTNG,0,laenge,0,-hoehe
LSEL,S,LINE,,2,8,2         !* DEFINE LINE DIVISION
LESIZE,ALL,0.75
LSEL,INVE
LESIZE,ALL, , ,100
ALLSEL,ALL

TYPE,1                     !* MESH AREA 2
MAT,1
LOCAL,11,0,0,0,0
ESYS,11
AMESH,2
CSYS,0
TYPE,2                     !* MESH AREA 1
ESYS,11
AMESH,1
CSYS,0

! Extrudieren
TYPE,3
EXTOPT,ACLEAR,1
EXTOPT,ESIZE,2
VEXT,2,,,,,dicke

TYPE,4
EXTOPT,ACLEAR,1
EXTOPT,ESIZE,2
VEXT,1,,,,,dicke


CSYS,0
NSEL,S,LOC,X,ini_riss,laenge
TYPE,5
MAT,2
REAL,3
ESEL,S,TYPE,,4
NSLE,S
NSEL,R,LOC,Y
ESURF                      !* TARGET ELEMENTS

TYPE,6
REAL,3
RMODIF,3,3,-KOPEN
RMODIF,3,12,-KOPEN
ESEL,S,TYPE,,3
NSLE,S
NSEL,R,LOC,Y
NSEL,R,LOC,X,ini_riss,laenge
ESURF                      !* CONTACT ELEMENTS
ALLSEL,ALL
NSEL,S,LOC,X,laenge           !* APPLY CONSTRAINTS
D,ALL,ALL
NSEL,ALL

ESEL,S,TYPE,,3
EMODIF,ALL,MAT,3
ALLSEL,ALL

FINISH
/SOLU
ESEL,S,TYPE,,4
NSLE,S
NSEL,R,LOC,X
NSEL,R,LOC,Y,hoehe           !* APPLY DISPLACEMENT LOADING ON TOP
D,ALL,UY,5
NSEL,ALL
ESEL,ALL
ESEL,S,TYPE,,3
NSLE,S
NSEL,R,LOC,X
NSEL,R,LOC,Y,-hoehe          !* APPLY DISPLACEMENT LOADING ON BOTTOM
D,ALL,UY,-5
NSEL,ALL
ESEL,ALL


NLGEOM,ON
AUTOTS,ON
TIME,1
NEQIT,50
NSUBST,400,400,400
OUTRES,ALL,ALL