finish
/clear 			!*Lösche alte Informationen
/prep7 			!*Trete in Preprocessor-Umgebung ein

ET,1,SHELL181		!*Schalenelement

! Parameter
!============================================================

E=210E9			!E-Modul [N/m^2]
nu=0.3			!Querkontraktionszahl [-]
g=9.81			!Grav. [m/s^2]
rho=7850		!Dichte [kg/m^3]

LX=20			!Länge [m]
LY=1.4			!Breite [m]
h=0.001			!Dicke [m]
BZ=52000		!Bandzug [N]

delta = LY/4		!*Netzgröße
NonlinSteps = 10

! Geometrie Platte
!============================================================

K,1,0,0,0,		!Keypoint 1
K,2,LX,0,0,		!Keypoint 2
K,3,LX,LY,0,	!Keypoint 3
K,4,0,LY,0,		!Keypoint 4

A,1,2,3,4		!*Rechteckfläche, definiert durch Keypoints

! Materialeigenschaft Stahl
!============================================================

MPTEMP,,,,,,,,  	!Temperaturabhängigkeit
MPTEMP,1,0  
MPDATA,EX,1,,E  	!E_Modul
MPDATA,PRXY,1,,nu  	!Querdehnzahl
MPDATA,DENS,1,,rho 	!Dichte

sect,1,shell,,  
secdata, h,1,0.0,3  	!*Thickness,MaterialID,Orientation,IntegrationPts
secoffset,MID   
seccontrol,0,0,0, 0, 1, 1, 1

! Vernetzung
!============================================================

! Mesh Definition
ASEL,S,LOC,Z,0		! Selektiere Gometrie
MAT,1				! Materialtyp
TYPE,1				! Elementtyp
MSHKEY,1			! Mesh Type: 1=mapped meshing, 0=free meshing
ESIZE,delta			! Elementgröße
AMESH,ALL			! Erstelle Netz

! Randbedingung: feste Einspannung bei x=0
!============================================================

NSEL,S,LOC,X,0		! Selektiere alle Knoten bei x=0
D,ALL,UX,0
D,ALL,UZ,0
D,ALL,ROTX,0
D,ALL,ROTY,0
D,ALL,ROTZ,0

NSEL,R,LOC,Y,LY/2-delta/2,LY/2+delta/2	!*Selektiere aus der letzten Auswahl den Knoten bei y=LY/2
D,ALL,UY,0

! Randbedingung: feste Einspannung bei x=LX
!============================================================

NSEL,S,LOC,X,LX		!*Selektiere alle Knoten bei x=LX
D,ALL,UZ,0
D,ALL,ROTX,0
D,ALL,ROTY,0
D,ALL,ROTZ,0

!*NSEL,S,LOC,X,0
NSEL,R,LOC,Y,LY/2-delta/2,LY/2+delta/2	!*Selektiere aus der letzten Auswahl den Knoten bei y=LY/2
D,ALL,UY,0

! Randbedingung: Bandzug bei x=L
!============================================================

NSEL,S,LOC,X,LX
*get,anz,node,0,count
forceXnode=BZ/anz
F,ALL,FX,forceXnode

! Schwerkraft
!============================================================

ACEL,g,0,0, !* Vorzeichen positiv, da es eine Beschleunigung und keine Gravitation ist


! Feder 1
!============================================================

LKH = 0.6/2	! [m]
LM1 = LX/2	! [m]
H0 =0.12	! [m]
CS=0.5 		! [N*m^3]

NSEL,S,LOC,X,LM1-LKH,LM1+LKH		!*Selektiere Knoten der Fläche (über gesamte Breite)
*get,nbr_nodes,node,0,count 		! Anzahl der Knoten bestimmen


! Erstellen einer Kraft Weg Tabelle
*DIM,displ_table,TABLE,20
*DIM,force_table_1,TABLE,20,1,1,Z, , ,   0 !*DIM, Par, Type, IMAX, JMAX, KMAX, Var1, Var2, Var3, CSYSID;    Var1, Var2, and Var3 are predefined keywords that are called Primary Variables.

*VFILL,displ_table(1,0),RAMP,1,1
*VFILL,displ_table(1),RAMP,-0.1,0.01

*VFILL,force_table_1(1,0),RAMP,-0.1,0.01 ! ...RAMP,Startpunkt,Inkrement
*DO,I,1,20,1
force_table_1(I)=CS*100/nbr_nodes*(1/(displ_table(I)+0.001+H0)**3-1/(H0-displ_table(I)-0.001)**3)
*ENDDO

F,ALL,FZ,%FORCE_TABLE_1%


ALLSEL

!*Lösen
!============================================================

FINISH  		!*Verlasse den Präprozessor
/SOL			!*Trete in Lösungsumgebung ein
ANTYPE,0
PSTRES,1		!*Berücksichtige Vorspannung in der Platte
NLGEOM,1		!*Nichtlineare Geometrie berücksichtigen
NSUBST,NonlinSteps,0,0  !*Anzahl der Iterationen

rescontrol,define,all,all,0   !*Speichere Information von stat Analyse mit Vorspannung

SOLVE			!*Finde die Knotenverschiebungen
FINISH