finish
/clear
/title, Kontaktproblem
/filename, contact

!Einheiten:	!Weg/Länge	mm
			!Kraft		N
			!Moment		Nmm
			!E-Modul	N/mm²

!----------Geometriedaten
L=600						!Gesamtlänge des Balkens
Lb=500						!Abstand der Lager
H=60						!Höhe des Balkens
w1=30			 			!Breite des oberen Gurtes
h1=3						!Dicke des oberen Gurtes
w3=30						!Breite des unteren Gurtes
h3=2.1						!Dicke des unteren Gurtes
w2=6						!Breite des Steges
h2=H-h1-h3					!Höhe des Steges
rzyl=15						!Radius der Zylinder

force=10000					!Kraft

!---------------PREP7---------------
/prep7						!Preprocessor starten

!----------Materialvereinbarung
!Materialdaten unterer Gurt
mp,ex,1,16604.6
mp,ey,1,13853.1
mp,ez,1,10031.1
mp,gyz,1,4744.3
mp,gxz,1,4653.2
mp,gxy,1,7334.1
mp,pryz,1,0.233
mp,prxz,1,0.211
mp,prxy,1,0.515

!Materialdaten Steg
mp,ex,2,13508.8
mp,ey,2,13508.8
mp,ez,2,10000
mp,gyz,2,4698.3
mp,gxz,2,4698.3
mp,gxy,2,7823.1
mp,pryz,2,0.199
mp,prxz,2,0.199
mp,prxy,2,0.535

!Materialdaten oberer Gurt
mp,ex,3,22131.3
mp,ey,3,13583.4
mp,ez,3,10056
mp,gyz,3,4829.3
mp,gxz,3,4574.3
mp,gxy,3,6453.8
mp,pryz,3,0.271
mp,prxz,3,0.233
mp,prxy,3,0.470

!Materialdaten Zylinder
mp,ex,5,210000
mp,ey,5,210000
mp,ez,5,210000
mp,gyz,5,79300
mp,gxz,5,79300
mp,gxy,5,79300
mp,pryz,5,0.3
mp,prxz,5,0.3
mp,prxy,5,0.3

!----------Contact-Reibungszahl
mp,mu,4,0.001

!----------Elementvereinbarung
et,1,solid185
et,2,targe170,,1
et,3,conta174
keyopt,3,10,4

r,1
r,2

!----------Geometrievereinbarung

!Profil des Balkens am Anfang
k,1,-L/2,0,-w3/2
k,2,-L/2,0,w3/2
k,3,-L/2,h3,-w3/2
k,4,-L/2,h3,w3/2
k,5,-L/2,h3,-w2/2
k,6,-L/2,h3,w2/2
k,7,-L/2,h3+h2,-w2/2
k,8,-L/2,h3+h2,w2/2
k,9,-L/2,h3+h2,-w1/2
k,10,-L/2,h3+h2,w1/2
k,11,-L/2,H,-w1/2
k,12,-L/2,H,w1/2

!Profil des Balkens am Ende
k,13,L/2,0,-w3/2
k,14,L/2,0,w3/2
k,15,L/2,h3,-w3/2
k,16,L/2,h3,w3/2
k,17,L/2,h3,-w2/2
k,18,L/2,h3,w2/2
k,19,L/2,h3+h2,-w2/2
k,20,L/2,h3+h2,w2/2
k,21,L/2,h3+h2,-w1/2
k,22,L/2,h3+h2,w1/2
k,23,L/2,H,-w1/2
k,24,L/2,H,w1/2

!Volumen des Balkens erzeugen
v,9,10,12,11,21,22,24,23		!unterer Gurt erhält Volumennummer 1
v,5,6,8,7,17,18,20,19			!Steg erhält Volumennummer 2
v,1,2,4,3,13,14,16,15			!oberer Gurt erhält Volumennummer 3

allsel
vglue,all						!Volumennummern: Steg=2, oberer Gurt=4 , unterer Gurt=5

!Zylinder erzeugen

numstr,volu,200					!Volumennummerzähler auf 200 setzen

!Zylinder oben
cyl4,0,H+rzyl,rzyl,,,,w1/2+10
cyl4,0,H+rzyl,rzyl,,,,-w1/2-10
vadd,200,201					!Zylinder der Lasteinführung mit Volumennummer 202 erzeugen

!Zylinder unten 1
cyl4,-Lb/2,-rzyl,rzyl,,,,w3/2+10
cyl4,-Lb/2,-rzyl,rzyl,,,,-w3/2-10
vadd,200,201					!Zylinder des ersten Lagers erzeugen mit Nummer 203

!Zylinder unten 2
cyl4,Lb/2,-rzyl,rzyl,,,,w3/2+10
cyl4,Lb/2,-rzyl,rzyl,,,,-w3/2-10
vadd,200,201					!Zylinder des zweiten Lagers erzeugen mit Nummer 204

!Volumen vernetzen
allsel							!unteren Gurt meshen
vsel,s,volu,,5
vatt,1,1,1
esize,5
vsweep,all
eplot
	
allsel							!Steg meshen
vsel,s,volu,,2
vatt,2,2,1
esize,5
vsweep,all
eplot

allsel							!oberen Gurt meshen
vsel,s,volu,,4
vatt,3,3,1
esize,5
vsweep,all
eplot

allsel							!Zylinder meshen
vsel,s,volu,,202,204
vatt,5,5,1
esize,3
vsweep,all
eplot

!----------Kontakte erstellen
allsel
vsel,s,,,202,204
aslv,s
nsla,s,1
type,2
mat,4
real,2
esurf

allsel
asel,s,,,4
asel,a,,,14
nsla,s,1
type,3
esurf

allsel
vsel,s,,,202,204
aslv,s
nsla,s,1
type,3
mat,4
real,3
esurf

allsel
asel,s,,,4
asel,a,,,14
nsla,s,1
type,2
esurf

allsel

!---------------SOLUTION---------------
/solu
!---nichtlineare Berechnung
antype,static,new			!statische Analyse
eqslv,spar					!bestimmt Solver
nlgeom,on					!nichtlineare Geometrie
pred,-1						!Prädiktor Methode

outres,all,all
nsub,1,10,1

!----------Randbedingungen
allsel
vsel,s,,,203,204
nslv,s,1
d,all,all

allsel
nsel,s,loc,x,-5,5
nsel,r,loc,z,-5,5
d,all,ux
d,all,uz

!---------1.Lastfall - Initialisierungslastfall
time,1
vsel,s,,,202
nsel,r,loc,y,H+rzyl-1,H+rzyl+1
d,all,uy,-10					!der Kontakt wird durch eine kleine Verschiebung initialisiert
allsel
solve
eplot

!----------2.Lastfall
time,2
vsel,s,volu,,202
nslv,s,1
nsel,r,loc,y,H+rzyl-1,H+rzyl+1
ddele,all,all
allsel

vsel,s,volu,,202
nslv,s,1
nsel,r,loc,y,H+rzyl
*get,anz_kn,node,0,count		!zählt Anzahl selektierter Knoten
f,all,fy,-force/anz_kn			!verteilt Last auf Knoten
allsel

eplot

solve

finish

!---------------POST1---------------
/post1
plnsol,s,eqv