finish  $ /clear
/NOPR

*abbr,R_U_N,/input,'..\Ansys_APDL-Skripte\magnet.txt'


! -----------------------------------------------------------------------------
! --------------- Variablen ---------------------------------------------------


! --------------- Schaltung ---------------------------------------------------
! ----- u0=36,9 und rvor=0,2 bei rCoil ca.1Ohm entspricht einer Stromdichte von 10A/mm²
u0=36.9
rvor=0.2

! --------------- Geometrie ---------------------------------------------------
NutBreite=15e-3
NutTiefe=26e-3
ZahnBreite=NutBreite*2.3
MagnetHohe=(240e-3)
TiefenVerkuerzung=0e-3
Luftspalt=1e-3
FuellFaktor=0.8
StromDichteFensterFlaecheSoll=10e6		! vorgegebene Stromdichte bei reiner Stromdichtevorgabe ohne Schaltung (Vorauslegung)
StromLeiter=30
Drahtstaerke=1.25e-3		!durchmesser
RohKupfer=1/(57e6)

MaschenWeite=4e-3
pi=acos(-1)


! --------------- (sich ergebende) (Außen)abmaße/Größen
ZahnLaenge=ZahnBreite+NutTiefe-TiefenVerkuerzung
MagnetBreite=(ZahnBreite*4+NutBreite*2)
MagnetTiefe=ZahnLaenge-TiefenVerkuerzung
RuckenHohe=ZahnBreite
AnkerDicke=ZahnBreite-TiefenVerkuerzung
AFensterFlaeche=NutBreite*NutTiefe
Windungen=nint((StromDichteFensterFlaecheSoll*AFensterFlaeche)/StromLeiter)		! Erforderliche Windungen zum erreichen der Stromdichte in der Kupferfläche bei maximalem Strom pro Leiter
DrahtflaecheLeiter=((Drahtstaerke/2)**2*pi)
BerechnungsEbeneLuft=ZahnBreite*4+2*NutBreite			!Radius der Berechnungsebene (umgebende Luft)
CoilWireLength=( (MagnetHohe*2) + (ZahnBreite*2+NutBreite) )	!berücksichtigt hin und rückweg
rCoil=RohKupfer*( (Windungen*CoilWireLength) / ((Drahtstaerke/2)**2*pi) )		!mit mittlerer länge des drahtes

!sich ergebende Stromdichte bei Schaltung
!StromDichteFensterFlaecheSoll=((u0/rvor)*Windungen)/(AFensterFlaeche)*1e-6
iStrdichtManuell=(StromDichteFensterFlaecheSoll*AFensterFlaeche)/Windungen
iCircuitManuell=u0/(rvor+rCoil)

/prep7
emunit,mks

! -----------------------------------------------------------------------------
! ---------- Elementtypen definieren ------------------------------------------
et,1,plane233		!
KEYOPT,1,7,1		!corner+midside=0,corner-condensed only=1 (more accurate, see ans_lof.pdf p. 20)
KEYOPT,1,8,0		!0=maxwell,1=lorentz
et,2,infin110		!
et,3,plane233		! Wicklung
KEYOPT,3,1,2		! volt,emf freischalten
et,6,circu124,4		! Spannungsquelle		--> hat ausgang welcher belegt werden muss --> siehe FEM4 S.448
et,7,circu124,0		! Vorwiderstand







! -----------------------------------------------------------------------------
! ---------- RealConst definieren ---------------------------------------------
! ---------- für plane233: r,No,THK,SC,NC,rMid,TZ,R,SYM --------------
r,2,1.0			! Höhe des Magneten
rMid=( ((ZahnBreite+NutBreite/2)*MagnetHohe) /pi)**0.5
r,3,1.0,AFensterFlaeche,Windungen,rMid,1,rCoil
! ---------- für circu124
r,6,u0
r,7,rvor


! -----------------------------------------------------------------------------
! ---------- Materialtypen definieren -----------------------------------------
mp,murx,2,1				! Luft

mp,murx,3,1				! Kupfer/Wicklung
mp,rsvx,3,RohKupfer		! rsvx^=Electrical resistivity, element x direction    !unit: Resistance*Area/Length

tb,bh,4,,16				!Magnetkörper/Anker
tbpt,,0.00,0.00			!vacuflux50
,,200.00,1.01
,,240.00,1.30
,,300.00,1.52
,,400.00,1.71
,,550.00,1.85
,,800.00,1.97
,,1000.00,2.02
,,1500.00,2.10
,,2500.00,2.18
,,4000.00,2.22
,,5500.00,2.24
,,7000.00,2.25
,,11000.00,2.28
,,24000.00,2.30
,,36900.00,2.32



! -----------------------------------------------------------------------------
! ---------- Geometrie zeichnen -----------------------------------------------
! Ggf. Knoten in anderer z-Ebene für Schaltung erstellen
abm=0.1			
n,1,-2*abm+BerechnungsEbeneLuft,0+BerechnungsEbeneLuft,1		!0v für spannungsquelle
n,2,-2*abm+BerechnungsEbeneLuft,abm+BerechnungsEbeneLuft,1		!positiver spannungsausgang
n,3,0+BerechnungsEbeneLuft,abm+1e-3+BerechnungsEbeneLuft,1		!für spannungsquelle extra-knoten
pcirc,0,BerechnungsEbeneLuft,-90,90		!für den luftgefüllten Raum
rectng,ZahnBreite,ZahnBreite+NutBreite,-ZahnLaenge/2,-(ZahnLaenge/2)+NutTiefe		!Wicklungsfläche
rectng,0,MagnetBreite/2,-ZahnLaenge/2,+ZahnLaenge/2
rectng,0,MagnetBreite/2,-ZahnLaenge/2-Luftspalt,-ZahnLaenge/2-(Luftspalt+AnkerDicke)	!Anker
rectng,0,MagnetBreite/2,-ZahnLaenge/2,-ZahnLaenge/2-(Luftspalt)				!Luftspalt
allsel
aovlap,all
NUMCMP,AREA

asel,s,,,1 $ cm,aWicklungR,area
asel,s,,,2 $ cm,aAnker,area
asel,s,,,3 $ cm,aLuftspalt,area
asel,s,,,5 $ cm,aMagnetkoerper,area
asel,s,,,4 $ cm,aLuftUmgebung,area
allsel

! -----------------------------------------------------------------------------
! ---------- Flächen Attribute zuweisen ---------------------------------------
cmsel,s,aWicklungR
/color,area,red,all
aatt,3,3,3				!schema aatt,MAT,REAL,TYPE

cmsel,s,aAnker
/color,area,dgra,all
aatt,4,2,1

cmsel,s,aLuftspalt
/color,area,whit,all
aatt,2,2,1

cmsel,s,aMagnetkoerper
/color,area,dgra,all
aatt,4,2,1

cmsel,s,aLuftUmgebung
/color,area,cblu,all
aatt,2,,1

allsel

! -----------------------------------------------------------------------------
! ---------- Flächen vernetzen ------------------------------------------------
esize,MaschenWeite 		$ amesh,1
esize,MaschenWeite 		$ amesh,2
esize,MaschenWeite		$ amesh,5
esize,MaschenWeite 		$ amesh,3
esize,MaschenWeite*5	$ amesh,4



! -----------------------------------------------------------------------------
! ---------- Lasten aufbringen ------------------------------------------------

! ---------- Rand INFIN110 und Flag setzen ------------------------------------
csys,1
nsel,s,loc,x,BerechnungsEbeneLuft		!Randknoten selektieren
nsel,r,loc,z,0
esln									!Elemente selektieren, die zu den zuvor gewählten Randknoten gehören
emodif,all,type,2						!Element modifizieren: Setze Type für ALL auf 2 (infin110)
sf,all,inf		!flag setzen			!Auf allen selektierten Knoten Oberflächen-Lasten definieren
csys,0
allsel

! ---------- Randbedingung wegen Symmetrie ------------------------------------
nsel,s,loc,x,0
nsel,r,loc,z,0
d,all,az,0                !In der Smmetrieachse wird das Vektorpotential Null gesetzt
allsel

! ------ Kopplung der Freiheitsgrade (Stromrichtung wird durch real-const berücksichtigt)
cmsel,s,aWicklungR $ nsla,s,1
cp,1,volt,all
cp,2,emf,all
allsel

! ------ Bezugspotential
nsel,s,node,,1
d,all,volt,0					!auf 0v setzen

! ------ Schaltung erstellen
type,6	$ real,6		! Spannungsquelle
e,2,1,3
type,7	$ real,7		! Vorwiderstand
cmsel,s,aWicklungR $ nsla $ *get,koppelNode,node,,num,min $	allsel
e,2,koppelNode

allsel


!----------------------------- SOLUTION ANFORDERN -------------------------------------
! -------- induktivität bestimmen
/solu
antype,static
solve

/post1
!aus vm207 von version 14.5!
*GET,iCircuitAuto,NODE,1,RF,AMPS   ! GET COIL CURRENT
ETABLE,_SENE,SENE        ! SUM UP MAGNETIC ENERGY STORED
SSUM
*GET,magnetischeEnergie,SSUM,,ITEM,_SENE
magnetischeEnergie=2*magnetischeEnergie ! SYMMETRY FACTOR 
LCOIL=2*magnetischeEnergie/iCircuitAuto**2          ! CALCULATE INDUCTANCE VIA MAGNETIC ENERGY



! ----- stromanstieg berechnen und plotten
/solu
CNVTOL,vltg,1e-10


ANTYPE,TRANS
OUTRES,ALL,ALL           ! STORE EVERY SUBSTEP
DELTIM,50e-3
TIME,500e-3
SOLVE


/post26
!prepare variables
rforce,2,1,AMPS           ! GET CURRENT IN COIL		!no 1 is reserved for time!

plvar,2		!var 2 is current



/eof