FINISH
/CLEAR,START

/FILNAME,fsi_2_5d,1

/DELETE,fsi_2_5d,rfl
/DELETE,fsi_2_5d,rst

/PREP7 


! Elemente
! ========

ET,1,142
ET,2,45
ET,3,141
ET,4,42

KEYOPT,1,4,1				! Include displacement DOFs!!!          
KEYOPT,3,4,1				! Include displacement DOFs!!!                  

! Material
! ========

! Fluid wird in Flotran definiert

MP,EX,2,2.1e11
MP,NUXY,2,0.3
MP,DENS,2,960

! Geometrie
! =========

mm = 1e-3

za = 4*mm				! Zylinderaussendurchmesser
zi = 3.5*mm				! Zylinderinnendurchmesser
zl = 10*mm				! Zylinderlänge

RECTNG,0,-zl,-zi/2,zi/2,
RECTNG,0,-zl,-za/2,-zi/2,   
RECTNG,0,-zl,zi/2,za/2, 


TYPE,3   
MAT,1   
ESYS,0   

LSEL,S,,,2
LSEL,A,,,4
LESIZE,ALL,,,30,-4,,,,1
 
ESIZE,0.5*mm,0, 
MSHAPE,0,2D 
MSHKEY,0

AMESH,1   


TYPE,4   
MAT,2   
ESYS,0 

LSEL,S,,,6
LSEL,A,,,8
LSEL,A,,,10
LSEL,A,,,12

LESIZE,ALL,,,4,,,,,1
 
ESIZE,0.8*mm,0,

AMESH,2
AMESH,3


TYPE,2   
EXTOPT,ESIZE,12,0,  
EXTOPT,ACLEAR,1   
EXTOPT,ATTR,0,0,0   
MAT,2   
REAL,_Z4
ESYS,0  

ASEL,S,,,2
ASEL,A,,,3  
VEXT,ALL,,,0,0,za


TYPE,1   
EXTOPT,ESIZE,20,0,  
EXTOPT,ACLEAR,1 
EXTOPT,ATTR,0,0,0   
MAT,1   
REAL,_Z4
ESYS,0  
 
ASEL,S,,,1  
VEXT,ALL,,,0,0,za,,,,

ALLSEL,ALL


! FSI-Flächen
! ===========

ASEL,S,,,7
ASEL,A,,,15
NSLA,S,1

SF,ALL,FSIN,1

ASEL,S,,,10
ASEL,A,,,17
NSLA,S,1

SF,ALL,FSIN,2

ALLSEL,ALL


! Randbedingungen
! ===============

ASEL,S,,,6					! Einspannung
ASEL,A,,,11
NSLA,S,1
D,ALL,UX,0
D,ALL,UY,0
D,ALL,UZ,0  

ASEL,S,,,5					! Bodenbefestigung
NSLA,S,1
D,ALL,UY,0
D,ALL,UZ,0

ASEL,S,,,16					! Fluidein- und Auslass
ASEL,A,,,18
NSLA,S,1
D,ALL,UX,0
D,ALL,UZ,0

ASEL,S,,,1					! Symmetrie Fluid
ASEL,A,,,14
NSLA,S,1
D,ALL,UZ,0
D,ALL,VZ,0

ASEL,S,,,2					! Symmetrie Mechanik
ASEL,A,,,3
ASEL,A,,,4
ASEL,A,,,9
DA,ALL,SYMM

ASEL,S,,,16					! Druck Fluidauslass
NSLA,S,1
D,ALL,PRES,0

ASEL,S,,,18					! Druck Fluideinlass
NSLA,S,1
D,ALL,PRES,2E4

ALLSEL,ALL


! Multi-Field SetUp
! =================

MFAN,ON,MFSC
 
MFEL,1,1 
MFFN,1,fluid1   
 
MFEL,2,2  
MFFN,2,solid2

MFOR,1,2 

MFCO,ALL,1e-3   
 
MFIN,CONS   
 
FLDATA1,SOLU,TRAN,0 
FLDATA1,SOLU,FLOW,1 
FLDATA1,SOLU,TURB,1 
FLDATA1,SOLU,ALE,1
FLDATA1,SOLU,RDSF,0 

FLDATA7,PROT,DENS,CONSTANT
FLDATA8,NOMI,DENS,1000, 
FLDATA7,PROT,VISC,CONSTANT
FLDATA8,NOMI,VISC,100,

FLDATA2,ITER,EXEC,20,

MORPH,ON

MFCM,1,fluid,


MFCLEAR,SOLU

ANTYPE,0
NLGEOM,1
MORPH,OFF

MFCM,2,solid,

MFTI,1
MFOU,1
MFDT,1

MFIT,30
 
MFRE,ALL,0.5,RELX  

MFSU,1,1,FORC,2
MFSU,1,2,DISP,1

MFSU,2,1,FORC,2
MFSU,2,2,DISP,1


! Lösen
! =====


FINISH  
/SOL

SOLVE