FINISH
/CLEAR,START

/FILNAME,fsi_2d,1

/DELETE,fsi_2d,rfl
/DELETE,fsi_2d,rst

/PREP7 


! Elemente
! ========

ET,1,141
ET,2,42

KEYOPT,1,4,1				! Include displacement DOFs!!!                        

! Material
! ========

! Fluid wird in Flotran definiert

MP,EX,2,2.1e11
MP,NUXY,2,0.3
MP,DENS,2,960

! Geometrie
! =========

mm = 1e-3

za = 4*mm				! Zylinderaussendurchmesser
zi = 3.5*mm				! Zylinderinnendurchmesser
zl = 10*mm				! Zylinderlänge

RECTNG,0,-zl,-zi/2,zi/2,
RECTNG,0,-zl,-za/2,-zi/2,   
RECTNG,0,-zl,zi/2,za/2, 


TYPE,1   
MAT,1   
ESYS,0   

LSEL,S,,,2
LSEL,A,,,4
LESIZE,ALL,,,40,-2,,,,1
 
ESIZE,0.5*mm,0, 
MSHAPE,0,2D 
MSHKEY,0

AMESH,1   


TYPE,2   
MAT,2   
ESYS,0 

LSEL,S,,,6
LSEL,A,,,8
LSEL,A,,,10
LSEL,A,,,12

LESIZE,ALL,,,4,,,,,1
 
ESIZE,1.2*mm,0,

AMESH,2
AMESH,3

! FSI-Linien
! ==========

LSEL,S,,,3
LSEL,A,,,9

NSLL,S,1

SF,ALL,FSIN,1,

LSEL,S,,,1
LSEL,A,,,7

NSLL,S,1

SF,ALL,FSIN,2

ALLSEL,ALL


! Randbedingungen
! ===============

LSEL,S,,,6					! Einspannung
LSEL,A,,,10
NSLL,S,1
D,ALL,UX,0
D,ALL,UY,0  

LSEL,S,,,5					! Bodenbefestigung					
NSLL,S,1
D,ALL,UY,0

LSEL,S,,,2					! Fluidein- und Auslass
LSEL,A,,,4
NSLL,S,1
D,ALL,UX,0

LSEL,S,,,2					! Druck Fluidauslass
NSLL,S,1
D,ALL,PRES,0

LSEL,S,,,4					! Druck Fluideinlass
NSLL,S,1
D,ALL,PRES,2E4

ALLSEL,ALL


! Multi-Field SetUp
! =================

MFAN,ON,MFSC
 
MFEL,1,1 
MFFN,1,fluid1   
 
MFEL,2,2  
MFFN,2,solid2

MFOR,1,2 

MFCO,ALL,1e-3   
 
MFIN,CONS   
 
FLDATA1,SOLU,TRAN,0 
FLDATA1,SOLU,FLOW,1 
FLDATA1,SOLU,TURB,1 
FLDATA1,SOLU,ALE,1 
FLDATA1,SOLU,RDSF,0 

FLDATA7,PROT,DENS,CONSTANT
FLDATA8,NOMI,DENS,1000, 
FLDATA7,PROT,VISC,CONSTANT
FLDATA8,NOMI,VISC,100,

FLDATA2,ITER,EXEC,20,

MORPH,ON

MFCM,1,fluid,


MFCLEAR,SOLU

ANTYPE,0
NLGEOM,1
MORPH,OFF

MFCM,2,solid,

MFTI,1
MFOU,1
MFDT,1

MFIT,30
 
MFRE,ALL,0.5,RELX  

MFSU,1,1,FORC,2
MFSU,1,2,DISP,1

MFSU,2,1,FORC,2
MFSU,2,2,DISP,1


! Lösen
! =====


FINISH  
/SOL

SOLVE