FINISH
/CLEAR,START

/FILNAME,fsi_3d,1

/DELETE,fsi_3d,rfl
/DELETE,fsi_3d,rst

/PREP7 


! Elemente
! ========

ET,1,142
ET,2,45
ET,3,141
ET,4,42

KEYOPT,1,4,1				! Include displacement DOFs!!!                       
KEYOPT,3,4,1				! Include displacement DOFs!!! 



! Geometrie
! =========

mm = 1e-3

za = 4*mm				! Zylinderaussendurchmesser
zi = 3.5*mm				! Zylinderinnendurchmesser
zr = 3*mm				! Zone feines Mesh
zl = 10*mm				! Zylinderlänge

CYL4,0,0,zi/2,0,za/2,180
CYL4,0,0,zr/2,0,zi/2,180
LSTR,7,8
AL,7,9


! Meshen
! ======

TYPE,4   
MAT,
REAL,   
ESYS,0   
SECNUM, 

LESIZE,1,,,20
LESIZE,2,,,4 
MSHAPE,0,2D 
MSHKEY,1
  
AMESH,1 


TYPE,3   
MAT,
REAL,   
ESYS,0   
SECNUM, 

LESIZE,5,,,32
LESIZE,6,,,4 
MSHAPE,0,2D 
MSHKEY,1
  
AMESH,2  


ESIZE,0.2*mm,0,
MSHKEY,0
 
AMESH,3


! Extrudieren
! ===========


TYPE,2   
EXTOPT,ESIZE,10,0,  
EXTOPT,ACLEAR,1  
EXTOPT,ATTR,0,0,0   
MAT,  
  
VEXT,1,,,0,0,-zl,,,,  


ASEL,S,,,2,3,1

TYPE,1
EXTOPT,ESIZE,17,0,  
EXTOPT,ACLEAR,1  
EXTOPT,ATTR,0,0,0   
MAT,   
  
VEXT,ALL,,,0,0,-zl,,,,  


ALLSEL,ALL



! Randbedingungen
! ===============
 
! structural

DA,4,UX,0
DA,4,UY,0
DA,4,UZ,0

ASEL,S,,,6
ASEL,A,,,8
DA,ALL,SYMM

! fluid
 
ASEL,S,,,9
ASEL,A,,,14 
DA,ALL,PRES,0,1 
DA,ALL,UZ,0,1

!ASEL,S,,,2
!ASEL,A,,,3
!DA,ALL,VX,0,1   
!DA,ALL,VY,0,1   
!DA,ALL,VZ,-2,1 

ASEL,S,,,2
ASEL,A,,,3
DA,ALL,PRES,2e5,1 

ASEL,S,,,11
ASEL,A,,,13
ASEL,A,,,15
DA,ALL,VY,0,1
DA,ALL,UY,0,1

ALLSEL,ALL


! FSI-Flächen
! ===========

VSEL,S,,,1 
ASLV,S
CSYS,1
ASEL,R,LOC,X,zi/2
CSYS,0
NSLA,S,1

SF,ALL,FSIN,1

VSEL,S,,,2 
ASLV,S
CSYS,1
ASEL,R,LOC,X,zi/2
CSYS,0
NSLA,S,1

SF,ALL,FSIN,1

ALLSEL,ALL



! Eigenschaften Fluid 
! ===================

FLDATA7,PROT,DENS,CONSTANT
FLDATA8,NOMI,DENS,1000, 
FLDATA7,PROT,VISC,CONSTANT
FLDATA8,NOMI,VISC,100,



! Eigenschaften Zylindermaterial
! ==============================

MP,EX,2,1e8
MP,NUXY,2,0.3
MP,DENS,2,960

VSEL,S,,,1 
ESLV,S  
EPLOT   
MPCHG,2,ALL,

ALLSEL,ALL



! Flotran
! =======


FLDATA1,SOLU,TRAN,0 
FLDATA1,SOLU,FLOW,1 
FLDATA1,SOLU,TURB,0 
FLDATA1,SOLU,ALE,1			 ! Activates Arbitrary Lagrangian-Eulerian formulation   
FLDATA1,SOLU,RDSF,0 

FLDATA2,ITER,EXEC,20,   
FLDATA3,TERM,VX,1e-004,   
FLDATA3,TERM,VY,1e-004,   
FLDATA3,TERM,VZ,1e-004,   
FLDATA3,TERM,PRES,1e-008,   
FLDATA3,TERM,TEMP,1e-008,



! ****************************************************************************************
! ****************************************************************************************

! FSI SetUp
! =========


FSAN,1  
FSOR,FLUID  
FSTR,FLUID,STAT 
FSTR,SOLID,STAT 
FSIN,CONS 

FSIT,10,
 
FSCO,ALL,1e-3,  

FSOU,1    

FSRE,ALL,0.75, 

! ****************************************************************************************
! ****************************************************************************************


! Lösen
! =====

FINISH  
/SOL


SOLVE


/EOF



! Postprocessing
! ==============


FINISH  
/POST1  
INRES,ALL   
FILE,'fsi_3d','rfl','.'
SET,LAST
VSEL,S,,,2
VSEL,A,,,3
ESLV,S  
  
PLNSOL, PRES,, 0
/DSCALE,ALL,50 
/REPLOT 


   
INRES,ALL   
FILE,'fsi_3d','rst','.' 
SET,LAST
VSEL,S,,,1 
VPLOT   
ESLV,S   

PLNSOL, U,X, 0,1.0    
/DSCALE,ALL,50 
/REPLOT