FINISH
/CLEAR,START

/FILNAME,fsi_2d,1

/DELETE,fsi_2d,rfl
/DELETE,fsi_2d,rst

/PREP7 


!!!	Elemente	!!!

ET,1,FLUID142
ET,2,SOLID185

KEYOPT,1,4,1

!!! 	Material	!!!

! Fluid wird in Flotran definiert

MP,EX,2,2.5e6				! isotropes Material mit Werten aus Halle-Zugversuchen
MP,NUXY,2,0.444
MP,DENS,2,1100


!!!	Geometrie	!!!

um = 1e-6							! Abmessungen
d_oeffnung = 500*um
d_auflage = 1000*um
h_oeffnung = 50*um
h_auflage = 38*um
r_kanal = 362.5*um
l_kanal = 2000*um
h_kanbal = 100*um


CYL4,0,0,d_auflage/2,0,,360,h_auflage				! Membran
WPOFFS,0,0,-h_oeffnung
CYL4, 0, 0, d_oeffnung/2,0,,360,h_oeffnung
VADD,1,2

WPROTA,,90							! Kanal
WPOFFS, 0,262.5*um, -l_kanal/2
CYL4,0,0,r_kanal,0,,360,l_kanal
BLOCK,-400*um,400*um,-262.5*um,400*um,0,l_kanal
VSBV,1,2,,DELETE,DELETE

NUMCMP,all							! Ordnen der Nummerierung

WPOFFS,,-262.5*um,l_kanal/2					! zweite FSI-Ebene			
WPROTA,,-90
CYL4,0,0,d_oeffnung/2,0,,360					


!!!	  Meshen	!!!

TYPE,1   							! Kanalbereich	
MAT,1   
ESYS,0   
MSHAPE,1,3D
MSHKEY,0
SMRTSIZE,2
VMESH,2,0.2

TYPE,2  							! Membranbereich
MAT,2   
ESYS,0 
MSHAPE,1,3D
MSHKEY,0
SMRTSIZE,4
VMESH,1


!!!	FSI-Linien 	!!!

ASEL,S,,,4
NSLA,S,1
SF,ALL,FSIN,1,

ASEL,S,,,12
NSLA,S,1
SF,ALL,FSIN,1,

ALLSEL,ALL


!!!	 Randbedingungen !!!	


ASEL,S,,,2,3,1					! Membranbefestigung					
ASEL,A,,,5,7,1
NSLA,S,1
D,ALL,UX,0
D,ALL,UY,0  

ASEL,S,,,10,12,1				! Fluidgrenze y-Richtung									
NSLA,S,1
D,ALL,VY,0
D,ALL,VX,0
D,ALL,UX,0
D,ALL,UY,0

ASEL,S,,,8					! Druck Fluidauslass
NSLA,S,1
D,ALL,PRES,0

ASEL,S,,,9					! Druck Fluideinlass
NSLA,S,1
D,ALL,PRES,2E4

ASEL,S,,,1					! Aktuationsdruck
NSLA,S,1
SFL,ALL,PRES,5E4
ALLSEL,ALL


!!!	Multi-Field SetUp		!!!

MFAN,ON,MFSC
 
MFEL,1,1 
MFFN,1,fluid1   
 
MFEL,2,2  
MFFN,2,solid2

MFOR,1,2 

MFCO,ALL,1e-3   
 
MFIN,CONS   
 
FLDATA1,SOLU,TRAN,0 
FLDATA1,SOLU,FLOW,1 
FLDATA1,SOLU,TURB,0 
FLDATA1,SOLU,ALE,1 
FLDATA1,SOLU,RDSF,0 

FLDATA7,PROT,DENS,CONSTANT
FLDATA8,NOMI,DENS,1000, 
FLDATA7,PROT,VISC,CONSTANT
FLDATA8,NOMI,VISC,100,

FLDATA2,ITER,EXEC,20,

MORPH,ON

MFCM,1,fluid,


MFCLEAR,SOLU

ANTYPE,0
NLGEOM,1
MORPH,OFF

MFCM,2,solid,

MFTI,5
MFDT,1,1,1
MFOU,1
MFDT,1

MFIT,450
 
MFRE,ALL,0.5,RELX  

MFSU,1,1,FORC,2
MFSU,1,2,DISP,1


!!!	 Lösen		!!!


FINISH 
 
/SOLU
SOLVE
SAVE