FINISH
/CLEAR,START

/FILNAME,fsi_2d,1

/DELETE,fsi_2d,rfl
/DELETE,fsi_2d,rst

/PREP7 


! Elemente
! ========

ET,1,FLUID141
ET,2,PLANE182

KEYOPT,1,4,1				! Include displacement DOFs!!!                        

! Material
! ========

! Fluid wird in Flotran definiert

MP,EX,2,2.5e6				! isotropes Material mit Werten aus Halle-Zugversuchen
MP,NUXY,2,0.444
MP,DENS,2,1100

! Geometrie
! =========

um = 1e-6

d_oeffnung = 500*um							! Membranabmessungen
d_auflage = 1000*um
h_oeffnung = 50*um
h_auflage = 40*um			
h_kanal = 100*um							! Kanalabmessungen
l_kanal = 1000*um
Abstand = 0

RECTNG,-d_oeffnung/2,d_oeffnung/2,0,h_oeffnung 				! Membrangeometrie
RECTNG,-d_auflage/2,d_auflage/2,h_oeffnung,h_auflage+h_oeffnung
AADD,1,2

K,9,-l_kanal/2,-h_kanal-Abstand						! Kanalgeometrie
K,10,l_kanal/2,-h_kanal-Abstand
K,11,l_kanal/2,-Abstand
K,12,d_oeffnung/2,-Abstand
K,13,-d_oeffnung/2,-Abstand
K,14,-l_kanal/2,-Abstand
A,9,10,11,12,13,14

!!!!! Meshen !!!!!

TYPE,1   								! Fluid
MAT,1   
ESYS,0   

								
LESIZE,1,,,40								! Meshen
LESIZE,5,,,10
LESIZE,7,,,20
LESIZE,13,,,10
LESIZE,3,,,4
LESIZE,14,,,4

MSHAPE,0,2D
MSHKEY,0
 
AMESH,1   


TYPE,2  								! Struktur 
MAT,2   
ESYS,0 

LESIZE,6,,,2								! Meshen
LESIZE,8,,,2
LESIZE,2,,,3
LESIZE,4,,,3
LESIZE,12,,,40
LESIZE,10,,,10
LESIZE,11,,,10
LESIZE,9,,,20

MSHAPE,0,2D
MSHKEY,0

AMESH,3

EPLOT

! FSI-Linien
! ==========

LSEL,S,,,9
NSLL,S,1
SF,ALL,FSIN,1,

LSEL,S,,,7
NSLL,S,1
SF,ALL,FSIN,1,

ALLSEL,ALL


! Randbedingungen
! ===============

LSEL,S,,,2					! Membranbefestigung
LSEL,A,,,4
LSEL,A,,,6
LSEL,A,,,8
LSEL,A,,,10
LSEL,A,,,11
NSLL,S,1
D,ALL,UX,0
D,ALL,UY,0  

LSEL,S,,,1					! Fluidgrenze y-Richtung
LSEL,A,,,5
LSEL,A,,,7
LSEL,A,,,13										
NSLL,S,1
D,ALL,VY,0
D,ALL,VX,0
D,ALL,UX,0
D,ALL,UY,0

LSEL,S,,,3					! Druck Fluidauslass
NSLL,S,1
D,ALL,PRES,0

LSEL,S,,,14					! Druck Fluideinlass
NSLL,S,1
D,ALL,PRES,2E4

LSEL,S,,,12					! Aktuationsdruck
NSLL,S,1
SFL,ALL,PRES,5E4
ALLSEL,ALL


! Multi-Field SetUp
! =================

MFAN,ON,MFSC
 
MFEL,1,1 
MFFN,1,fluid1   
 
MFEL,2,2  
MFFN,2,solid2

MFOR,1,2 

MFCO,ALL,1e-3   
 
MFIN,CONS   
 
FLDATA1,SOLU,TRAN,0 
FLDATA1,SOLU,FLOW,1 
FLDATA1,SOLU,TURB,0 
FLDATA1,SOLU,ALE,1 
FLDATA1,SOLU,RDSF,0 

FLDATA7,PROT,DENS,CONSTANT
FLDATA8,NOMI,DENS,1000, 
FLDATA7,PROT,VISC,CONSTANT
FLDATA8,NOMI,VISC,100,

FLDATA2,ITER,EXEC,20,

MORPH,ON

MFCM,1,fluid,


MFCLEAR,SOLU

ANTYPE,0
NLGEOM,1
MORPH,OFF

MFCM,2,solid,

MFTI,5
MFDT,1,1,1
MFOU,1
MFDT,1

MFIT,450
 
MFRE,ALL,0.5,RELX  

MFSU,1,1,FORC,2
MFSU,1,2,DISP,1


! Lösen
! =====

FINISH 
 
/SOLU
SOLVE
SAVE